9.23 树塔狂想曲 2744

题目

相信大家都在长训班学过树塔问题，题目很简单求最大化一个三角形数塔从上往下走的路径和。走的规则是：（i，j）号点只能走向（i+1，j）或者（i+1，j+1）。如下图是一个数塔，映射到该数塔上行走的规则为：从左上角的点开始，向下走或向右下走直到最底层结束。

1
3 8
2 5 0
1 4 3 8
1 4 2 5 0

路径最大和是1+8+5+4+4 = 22，1+8+5+3+5 = 22或者1+8+0+8+5 = 22。

小S觉得这个问题so easy。于是他提高了点难度，他每次ban掉一个点（即规定哪个点不能经过），然后询问你不走该点的最大路径和。
当然他上一个询问被ban掉的点过一个询问会恢复（即每次他在原图的基础上ban掉一个点，而不是永久化的修改）。

Sample Input

5 3
1
3 8
2 5 0
1 4 3 8
1 4 2 5 0
2 2
5 4
1 1

Sample Output

17
22
-1

Hint

【样例解释】

第一次是
1
3 X
2 5 0
1 4 3 8
1 4 2 5 0
1+3+5+4+4 = 17 或者 1+3+5+3+5=17
第二次：
1
3 8
2 5 0
1 4 3 8
1 4 2 X 0
1+8+5+4+4 = 22
第三次：你们都懂的！无法通行，-1！

【数据规模】

所有测试数据范围和特点如下：
对于所有数据，数塔中的数X的大小满足

题解

看题解写的，这种方法要学习。
f[i,j]表示从第一层走到第i行第j个点最大值，g[i,j]表示从最后一层走到第i行第j个点最大值，a[i,j]表示当前点的值。
对于每一个不能走的点，我们一定只能走同行的另一个点，所以要找到f[i,j]+g[i,j]-a[i,j]最大的点，若刚好是不能走的店，则输出次大的点。这些都应在预处理完成，使得每个询问的时间复杂度为O(1)

$O(3n^2+m)$

代码

var
  n,m,i,j,x,y:longint;
  a,f,g:array[0..1001,0..1001]of longint;
  b:array[0..1001,1..3]of longint;

function max(a,b:longint):longint;
begin
  if a>b then exit(a) else exit(b);
end;

begin
  readln(n,m);
  for i:=1 to n do
    begin
      for j:=1 to i do
        read(a[i,j]);
      readln;
    end;
  for i:=1 to n do
    for j:=1 to i do
      f[i,j]:=max(f[i-1,j],f[i-1,j-1])+a[i,j];
  for i:=n downto 1 do
    for j:=1 to i do
      g[i,j]:=max(g[i+1,j],g[i+1,j+1])+a[i,j];
  for i:=1 to n do
    begin
      b[i,1]:=-1;b[i,2]:=-1;
      for j:=1 to i do
        if f[i,j]+g[i,j]-a[i,j]>b[i,1] then
          begin
            b[i,2]:=b[i,1];
            b[i,1]:=f[i,j]+g[i,j]-a[i,j];
            b[i,3]:=j;
          end else
        if f[i,j]+g[i,j]-a[i,j]>b[i,2] then
          b[i,2]:=f[i,j]+g[i,j]-a[i,j];
    end;
  for i:=1 to m do
    begin
      readln(x,y);
      if b[x,3]<>y then writeln(b[x,1]) else writeln(b[x,2]);
    end;
end.