柱子屈曲

Eigenvalue Buckling
FINISH !这两行命令清除当前数据
/CLEAR
/TITLE,Eigenvalue Buckling Analysis
/PREP7 !进入前处理器
ET,1,BEAM3 !选择单元
R,1,100,833.333,10 !定义实常数
MP,EX,1,200000 !弹性模量
MP,PRXY,1,0.3 !泊松比
K,1,0,0 !创建梁实体模型
K,2,0,100
L,1,2 !创建直线
ESIZE,10 !单元边长为1mm
LMESH,ALL,ALL !划分网格
FINISH !退出前处理
/SOLU !进入求解
ANTYPE,STATIC !在进行屈服分析之前，ANSYS需要从静态分析提取数据
PSTRES,ON !屈服分析中采用预应力
DK,1,ALL !定义约束
FK,2,FY,-1 !顶部施加载荷
SOLVE !求解
FINISH !退出求解
/SOLU !重新进入求解模型进行屈服分析
ANTYPE,BUCKLE !屈服分析类型
BUCOPT,LANB,1 !1阶模态，子空间法
SOLVE !求解
FINISH !退出求解
/SOLU !重新进入求解展开模态
EXPASS,ON !模态展开打开
MXPAND,1 !定义需要展开的阶数
SOLVE !求解
FINISH !退出求解
/POST1 !进入通用后处理
SET,LIST !列出特征值求解结果
SET,LAST !读入感兴趣阶数模态结果
PLDISP !显示变形后图形
NonLinear Buckling !非线性分析部分
FINISH !这两行命令清除当前数据
/CLEAR
/TITLE, Nonlinear Buckling Analysis
/PREP7 !进入前处理
ET,1,BEAM3 !选择单元
MP,EX,1,200000 !弹性模量
MP,PRXY,1,0.3 !泊松比
R,1,100,833.333,10 !定义实常数
K,1,0,0,0 !底端节点
K,2,0,100,0 !顶点
L,1,2 !连成线
ESIZE,1 !网格尺寸参数设定
LMESH,ALL !划分网格
FINISH !退出前处理
/SOLU !进入求解
ANTYPE,STATIC !静态分析类型（非屈服分析）
NLGEOM,ON !打开非线性大变形设置
OUTRES,ALL,ALL !选择输出数据
NSUBST,20 !5个子步加载
NEQIT,1000 !20步迭代
AUTOTS,ON !自动时间步长
LNSRCH,ON !激活线搜索选项
/ESHAPE,1 !显示二维状态下变形图
DK,1,ALL,0 !约束底部节点
FK,2,FY,-50000 !顶部载荷稍微比特征值分析结果大
FK,2,FX,-250 ! 施加水平扰动载荷
SOLVE !求解
FINISH !退出求解
/POST26 !进入时间-历程后处理器
RFORCE,2,1,F,Y !2#变量表示力
NSOL,3,2,U,Y !3#变量表示y方向位移
XVAR,2 !将x轴显示2＃变量
PLVAR,3 !y轴显示3＃变量数据
/AXLAB,Y,DEFLECTION !修改y轴标签
/AXLAB,X,LOAD !修改x轴标签
/REPLOT !重新显示图形