《一个操作系统的实现》总结1——启动流程

注：文中的代码是在ORANGE源码（最后一个版本chapter10\e\kernel）的基础上所添加的注解，以 /*** ***/ 为标注，主要是一些重要文件和比较难理解的地方做了注解。

  由于回车或字符大小原因一些图在网页上的显示可能不是很准确，可以复制到本机看。

  另外，CSDN的编辑器有点shi，整篇发表有错误，因此拆成了三份，本意是一整篇文章。

  在操作系统正式开始之前我们先 make image ，这里做了一些重要的准备活动，在Makefile中可以看到：将boot.bin用dd写入软盘的第一个扇区，将loader.bin和kernel.bin（ELF格式，不能直接被执行）放入软盘根目录中，将shell命令程序打包并写入硬盘。

    一、启动流程  

S1、从软盘启动时，软盘的第一个扇区内容会被加载到内存0x7C00处，并从此处开始执行； 

S2、（boot.asm）在软盘的根目录寻找loader.bin，并读入内存，跳转到loader执行； 

S3、（loader.asm）在软盘的根目录寻找kernel.bin，并读入内存；  

S4、（loader.asm）跳入保护模式；  

S5、（loader.asm）建立页表机制；  

S6、（loader.asm）解析ELF格式的kernel.bin，根据其程序头信息和入口地址等将kernel载入到内存中的正确位置；  

S7、（loader.asm）跳到kernel的入口地址处，下面进入kernel执行；  

S8、（kernel.asm）初始化并使用新GDT、新IDT；  

S9、（kernel.asm）跳入kernel_main执行；

S10、最终，进入各进程交替运行、相互通信的状态，进程间的切换是时钟中断处理程序完成的。（中断处理程序、系统调用处理程序、系统任务、用户进程的初始化是在global.c和kernel/main.c中进行的，所有机制都初始化完成后，就进入了由时钟中断、键盘中断等中断驱动的如同一个生态系统的运行状态）

  这一部分涉及的文件有boot/boot.asm、boot/loader.asm、kernel/kernel.asm：

; ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;                               boot.asm
; ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;                                                     Forrest Yu, 2005
; ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++


;%define	_BOOT_DEBUG_	; 做 Boot Sector 时一定将此行注释掉!将此行打开后用 nasm Boot.asm -o Boot.com 做成一个.COM文件易于调试

%ifdef	_BOOT_DEBUG_
	org  0100h			; 调试状态, 做成 .COM 文件, 可调试
%else
	org  07c00h			; Boot 状态, Bios 将把 Boot Sector 加载到 0:7C00 处并开始执行
;/***告诉程序被加载到cs实际值的偏移7c00h处，保证程序中跳转正确***/
%endif

;================================================================================================
%ifdef	_BOOT_DEBUG_
BaseOfStack		equ	0100h	; 调试状态下堆栈基地址(栈底, 从这个位置向低地址生长)
%else
BaseOfStack		equ	07c00h	; Boot状态下堆栈基地址(栈底, 从这个位置向低地址生长)
%endif

%include	"load.inc"
;================================================================================================

	jmp short LABEL_START		; Start to boot.
	nop				; 这个 nop 不可少

; 下面是 FAT12 磁盘的头, 之所以包含它是因为下面用到了磁盘的一些信息
%include	"fat12hdr.inc"
;/***前三句共同构成了FAT12文件系统引导扇区头，其中fat12hdr.inc中的db、dw等声明是实际占用内存空间的，属于引导扇区的组成部分，而equ声明只是宏定义，不占用实际内存。只有有这个头，该软盘才能被识别为FAT12文件系统，另外注意该格式是软盘对应的格式。（见P104）***/

LABEL_START:	
	mov	ax, cs
	mov	ds, ax
	mov	es, ax
	mov	ss, ax
	mov	sp, BaseOfStack
;/***cs初始时为0，为了能正确使用声明的标签（相对于cs）、数据（相对ds）、以及堆栈（相对ss）等，需要将各个段寄存器初始化为与cs相同的值，因为实模式下使用的是逻辑地址，在实际寻址时会加上对应的10*段寄存器值。另外注意该处最后将BaseOfStack初始化为了7c00h，即boot的起始处，这样做在使用栈时会覆盖7c00h前面的数据，由于500h-7c00h之间是未使用空间，因此可以随便覆盖（见P141图）***/

	; 清屏
	mov	ax, 0600h		; AH = 6,  AL = 0h
	mov	bx, 0700h		; 黑底白字(BL = 07h)
	mov	cx, 0			; 左上角: (0, 0)
	mov	dx, 0184fh		; 右下角: (80, 50)
	int	10h			; int 10h

	mov	dh, 0			; "Booting  "
	call	DispStr			; 显示字符串
	
	xor	ah, ah	; ┓
	xor	dl, dl	; ┣ 软驱复位
	int	13h	; ┛
	
; 下面在 A 盘的根目录寻找 LOADER.BIN
;/***我们在bochs的bochsrc配置文件中配置了floppya: 1_44=a.img, status=inserted 和 boot: a 两句，即我们的虚拟机是使用软盘启动的，该软盘即是a.img，我们首先是将boot.asm编译的boot.bin用dd写入到a.img，注意是写入，不是复制粘贴，即boot.bin已经成了该盘开始的一部分，前面已经说过，最开始的三句话确定了该盘的文件系统是FAT12。后来我们才把把loader.bin和kernel.bin放到了这个软盘的根目录下，所以才会有下面的寻找loader.bin***/
	mov	word [wSectorNo], SectorNoOfRootDirectory
LABEL_SEARCH_IN_ROOT_DIR_BEGIN:
	cmp	word [wRootDirSizeForLoop], 0	; ┓
	jz	LABEL_NO_LOADERBIN		; ┣ 判断根目录区是不是已经读完
	dec	word [wRootDirSizeForLoop]	; ┛ 如果读完表示没有找到 LOADER.BIN
	mov	ax, LOADER_SEG
	mov	es, ax			; es <- LOADER_SEG
	mov	bx, LOADER_OFF		; bx <- LOADER_OFF	于是, es:bx = LOADER_SEG:LOADER_OFF
	mov	ax, [wSectorNo]		; ax <- Root Directory 中的某 Sector 号
	mov	cl, 1
	call	ReadSector

	mov	si, LoaderFileName	; ds:si -> "LOADER  BIN"
	mov	di, LOADER_OFF		; es:di -> LOADER_SEG:0100 = LOADER_SEG*10h+100
	cld
	mov	dx, 10h
LABEL_SEARCH_FOR_LOADERBIN:
	cmp	dx, 0					; ┓循环次数控制,
	jz	LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR	; ┣如果已经读完了一个 Sector,
	dec	dx					; ┛就跳到下一个 Sector
	mov	cx, 11
LABEL_CMP_FILENAME:
	cmp	cx, 0
	jz	LABEL_FILENAME_FOUND	; 如果比较了 11 个字符都相等, 表示找到
	dec	cx
	lodsb				; ds:si -> al
	cmp	al, byte [es:di]
	jz	LABEL_GO_ON
	jmp	LABEL_DIFFERENT		; 只要发现不一样的字符就表明本 DirectoryEntry 不是
; 我们要找的 LOADER.BIN
LABEL_GO_ON:
	inc	di
	jmp	LABEL_CMP_FILENAME	;	继续循环

LABEL_DIFFERENT:
	and	di, 0FFE0h		; else ┓	di &= E0 为了让它指向本条目开头
	add	di, 20h			;      ┃
	mov	si, LoaderFileName	;      ┣ di += 20h  下一个目录条目
	jmp	LABEL_SEARCH_FOR_LOADERBIN;    ┛

LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR:
	add	word [wSectorNo], 1
	jmp	LABEL_SEARCH_IN_ROOT_DIR_BEGIN

LABEL_NO_LOADERBIN:
	mov	dh, 2			; "No LOADER."
	call	DispStr			; 显示字符串
%ifdef	_BOOT_DEBUG_
	mov	ax, 4c00h		; ┓
	int	21h			; ┛没有找到 LOADER.BIN, 回到 DOS
%else
	jmp	$			; 没有找到 LOADER.BIN, 死循环在这里
%endif

LABEL_FILENAME_FOUND:			; 找到 LOADER.BIN 后便来到这里继续
	mov	ax, RootDirSectors
	and	di, 0FFE0h		; di -> 当前条目的开始
	add	di, 01Ah		; di -> 首 Sector
	mov	cx, word [es:di]
	push	cx			; 保存此 Sector 在 FAT 中的序号
	add	cx, ax
	add	cx, DeltaSectorNo	; 这句完成时 cl 里面变成 LOADER.BIN 的起始扇区号 (从 0 开始数的序号)
	mov	ax, LOADER_SEG
	mov	es, ax			; es <- LOADER_SEG
	mov	bx, LOADER_OFF		; bx <- LOADER_OFF	于是, es:bx = LOADER_SEG:LOADER_OFF = LOADER_SEG * 10h + LOADER_OFF
	mov	ax, cx			; ax <- Sector 号

LABEL_GOON_LOADING_FILE:
	push	ax			; ┓
	push	bx			; ┃
	mov	ah, 0Eh			; ┃ 每读一个扇区就在 "Booting  " 后面打一个点, 形成这样的效果:
	mov	al, '.'			; ┃
	mov	bl, 0Fh			; ┃ Booting ......
	int	10h			; ┃
	pop	bx			; ┃
	pop	ax			; ┛

	mov	cl, 1
	call	ReadSector
	pop	ax			; 取出此 Sector 在 FAT 中的序号
	call	GetFATEntry
	cmp	ax, 0FFFh
	jz	LABEL_FILE_LOADED
	push	ax			; 保存 Sector 在 FAT 中的序号
	mov	dx, RootDirSectors
	add	ax, dx
	add	ax, DeltaSectorNo
	add	bx, [BPB_BytsPerSec]
	jmp	LABEL_GOON_LOADING_FILE
LABEL_FILE_LOADED:

	mov	dh, 1			; "Ready."
	call	DispStr			; 显示字符串

;/***执行下面一句，cs会被赋值为LOADER_SEG即90000h，而实际loader.bin被加载的开始位置是90100h处，因此跳到了90100h处执行，loader.asm中最开始的org 0100h就是由于这个原因。***/
; *****************************************************************************************************
	jmp	LOADER_SEG:LOADER_OFF	; 这一句正式跳转到已加载到内存中的 LOADER.BIN 的开始处
						; 开始执行 LOADER.BIN 的代码
						; Boot Sector 的使命到此结束
; *****************************************************************************************************



;============================================================================
;变量
;----------------------------------------------------------------------------
wRootDirSizeForLoop	dw	RootDirSectors	; Root Directory 占用的扇区数, 在循环中会递减至零.
wSectorNo		dw	0		; 要读取的扇区号
bOdd			db	0		; 奇数还是偶数

;============================================================================
;字符串
;----------------------------------------------------------------------------
LoaderFileName		db	"LOADER  BIN", 0	; LOADER.BIN 之文件名
; 为简化代码, 下面每个字符串的长度均为 MessageLength
MessageLength		equ	9
BootMessage:		db	"Booting  "; 9字节, 不够则用空格补齐. 序号 0
Message1		db	"Ready.   "; 9字节, 不够则用空格补齐. 序号 1
Message2		db	"No LOADER"; 9字节, 不够则用空格补齐. 序号 2
;============================================================================


;----------------------------------------------------------------------------
; 函数名: DispStr
;----------------------------------------------------------------------------
; 作用:
;	显示一个字符串,