Hive 3.x|第七天|分区表和分桶表

分区表

分区表实际上就是对应一个 HDFS 文件系统上的独立的文件夹，该文件夹下是该分区所
有的数据文件。
Hive 中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。
在查询时通过 WHERE 子句中的表达式选择查询所需要的指定的分区，这样的查询效率
会提高很多。

实操

1. 首先在datas目录里创建三个相应的文件：dept_20200401.log

10	ACCOUNTING	1700
20	RESEARCH	1800

dept_20200402.log

30	SALES	1900
40	OPERATIONS	1700

dept_20200403.log

50	TEST	2000
60	DEV	1900

2. 在Hive中创建分区表

hive (default)> create table dept_partition(
deptno int, dname string, loc string)
partitioned by (day string)
row format delimited fields terminated by '\t'

3. 加载数据到分区表中
   注意：分区表加载数据时，必须指定分区

hive (default)> load data local inpath  '/opt/module/hive/datas/dept_20200401.log' into table dept_partition  partition(day='20200401');
hive (default)> load data local inpath  '/opt/module/hive/datas/dept_20200402.log' into table dept_partition  partition(day='20200402');
hive (default)> load data local inpath  '/opt/module/hive/datas/dept_20200403.log' into table dept_partition  partition(day='20200403');

4. 去HDFS中查看
   

5. 查询
   单分区查询

select * from dept_partition where day='20200401';

多分区联合查询

select * from dept_partition where day='20200401'
 union
 select * from dept_partition where day='20200402'
 union
 select * from dept_partition where day='20200403';

select * from dept_partition where day='20200401' or day='20200402' or day='20200403';

增加分区

alter table dept_partition add partition(day='20200404');
alter table dept_partition add partition(day='20200405')  partition(day='20200406');

删除分区

alter table dept_partition drop partition  (day='20200406');
alter table dept_partition drop partition  (day='20200404'), partition(day='20200405');

查看分区表有多少分区

show partitions dept_partition;

查看分区表结构

desc formatted dept_partition;

二级分区

创建二级分区表

首先正常地创建一个表

 create table dept_partition2(
 deptno int, dname string, loc string
 )
partitioned by (day string, hour string)
row format delimited fields terminated by '\t';

加载数据到二级分区表中

 load data local inpath 
'/opt/module/hive/datas/dept_20200401.log' into table dept_partition2 partition(day='20200401', hour='12');

查询分区数据

hive (default)> select * from dept_partition2 where day='20200401' and  hour='12';

分区表和数据产生关联的方式

如果直接把文件上传到HDFS上

hive (default)> dfs -mkdir -p /user/hive/warehouse/mydb.db/dept_partition2/day=20200401/hour=13;
hive (default)> dfs -put /opt/module/datas/dept_20200401.log  /user/hive/warehouse/mydb.db/dept_partition2/day=20200401/hour=13;

让分区表和数据产生关联，有三种方式：

1. 执行修复命令

 msck repair table dept_partition2;

2. 上传数据后添加分区

alter table dept_partition2 add  partition(day='201709',hour='14');

3. 直接load 数据到分区

load data local inpath  '/opt/module/hive/datas/dept_20200401.log' into table dept_partition2 partition(day='20200401',hour='15');

动态分区

关系型数据库中，对分区表 Insert 数据时候，数据库自动会根据分区字段的值，将数据插入到相应的分区中。
Hive 中也提供了类似的机制，即动态分区(Dynamic Partition)，只不过，使用 Hive 的动态分区，需要进行相应的配置。

开启动态分区参数设置

开启动态分区功能（默认 true，开启）

set hive.exec.dynamic.partition=true

设置为非严格模式（动态分区的模式，默认 strict，表示必须指定至少一个分区为静态分区，nonstrict 模式表示允许所有的分区字段都可以使用动态分区。）

set hive.exec.dynamic.partition.mode=nonstrict

在所有执行 MR 的节点上，最大一共可以创建多少个动态分区。默认 1000

set hive.exec.max.dynamic.partitions=1000

在每个执行 MR 的节点上，最大可以创建多少个动态分区。该参数需要根据实际的数据来设定。比如：源数据中包含了一年的数据，即 day 字段有 365 个值，那么该参数就需要设置成大于 365，如果使用默认值 100，则会报错。

set hive.exec.max.dynamic.partitions.pernode=100

整个 MR Job 中，最大可以创建多少个 HDFS 文件。默认 100000

set hive.exec.max.created.files=100000

当有空分区生成时，是否抛出异常。一般不需要设置。默认 false

hive.error.on.empty.partition=false

实操

需求：将 dept 表中的数据按照地区（loc 字段），插入到目标表 dept_partition 的相应分区中。

1. 创建目标分区表

hive (default)> create table dept_partition_dy(id int, name string)  partitioned by (loc int) row format delimited fields terminated by '\t';

2. 设置动态分区

set hive.exec.dynamic.partition.mode = nonstrict;
hive (default)> insert into table dept_partition_dy partition(loc) select  deptno, dname, loc from dept;

3. 查看目标分区表的分区情况

hive (default)> show partitions dept_partition;

分桶表

分区提供一个隔离数据和优化查询的便利方式。不过，并非所有的数据集都可形成合理
的分区。对于一张表或者分区，Hive 可以进一步组织成桶，也就是更为细粒度的数据范围划分。
分桶是将数据集分解成更容易管理的若干部分的另一个技术。
分区针对的是数据的存储路径；分桶针对的是数据文件。

创建分桶表

现准备数据

1001 ss1
1002 ss2
1003 ss3
1004 ss4
1005 ss5
1006 ss6
1007 ss7
1008 ss8
1009 ss9
1010 ss10
1011 ss11
1012 ss12
1013 ss13
1014 ss14
1015 ss15
1016 ss16

HQL语句创建

create table stu_buck(id int, name string) 
clustered by(id)  into 4 buckets 
row format delimited fields terminated by '\t';

导入数据到分桶表中

load data inpath '/student.txt' into table stu_buck;

查询分桶的数据

select * from stu_buck;

分桶规则

根据结果可知：Hive 的分桶采用对分桶字段的值进行哈希，然后除以桶的个数求余的方式决定该条记录存放在哪个桶当中。

注意事项

1. reduce 的个数设置为-1,让 Job 自行决定需要用多少个 reduce 或者将reduce 的个数设置为大于等于分桶表的桶数.
2. 从 hdfs 中 load 数据到分桶表中，避免本地文件找不到问题
3. 不要使用本地模式

insert 方式将数据导入分桶表

hive(default)>insert into table stu_buck select * from student_insert;