emu8086打印等腰三角形

 emu8086软件下载：https://wwa.lanzoui.com/i2u73bi

 

三角形的打印可以借助emu8086.inc，这个库里有一些封装好的函数便于我们使用。比如GOTOXY可以让我们定位到屏幕上要显示字符的地方，然后通过PUTC来显示字符。

对于一个三角形，第一行为1个*，往后每行比上一行多两个*，下一行的坐标相对于上一行横坐标减1纵坐标加1。

先定义两个变量分别存储行和列坐标，然后用GOTOXY col,row来定位坐标，然后通过循环来显示*，循环的次数通过更改CX寄存器的值来改变。然后就可以用下面的方式来产生三角形了。

GOTOXY col,row  

mov cx, 1

c1:

    PUTC '*'

loop c1      

add row,1 

sub col,1



GOTOXY col,row  

mov cx, 3

c2:

    PUTC '*'

loop c2  

add row,1 

sub col,1



GOTOXY col,row  

mov cx, 5

c3:

    PUTC '*'

loop c3 

可以看到上面的代码有很多重复的地方，我们可以考虑使用循环来对代码进行优化。这里需要注意，在打印*的时候已经使用了一个循环，如果在外面再套一个循环，CX寄存器的使用就存在冲突。这里需要用到压栈操作，在进入内层循环之前，先将CX寄存器的值存起来，等内层循环执行完毕，再把刚才存的值返还给CX，这样两个循环就不会冲突了。代码如下：

mov cx, 5

c:



    push cx

   

    GOTOXY col,row   



    mov cx, num

    c1:

        PUTC '*'

    loop c1      

   

    add row,1 

    sub col,1

    add num,2



    pop cx

loop c

可以看到现在代码比之前简洁了很多，这里一共定义了三个变量，除了行和列，还定义了一个num，用来表示每次要打印几个*，这个值每执行一次自加2，用于设定下一次打印*的个数。

如果要改变三角形的位置，更改col和row的初始值即可；如果要改变三角形的大小，更改外层循环的次数即可。

需要注意定义变量不能放在程序开头，这样编译器会将其翻译成别的指令，为了防止出现这样的错误，有两种解决方案，一是将变量定义放在RET的后面；二是依然放在开头，但是在程序第一句加一个jmp指令，跳转到变量定义完毕的后面。

在需要定位屏幕输入位置的时候，调用GOTOXY加坐标即可，那我们是否也可以构造一个函数，我们只需要输入三角形顶点的位置和三角形的大小就可以画出想要的三角形呢？答案是肯定的。

我们可以在刚才的代码基础上修改，将其依赖的参数从外部传入，定义函数的方法可以参考emu8086.inc这个库。对于用到的GOTOXY和PUTC，我们可以将其源码抄写过来放到我们的函数中，最终构建的函数如下所示：

triangle MACRO x y n     


jmp cc 

col db x   

row db y

num dw 1  


cc:

mov cx, n

c:

    push cx
   

    PUSH    AX

    PUSH    BX

    PUSH    DX

    MOV    AH, 02h

    MOV    DH, row

    MOV    DL, col

    MOV    BH, 0

    INT     10h

    POP     DX

    POP     BX

    POP     AX 

   

    mov cx, num

    c1:

        PUSH   AX

        MOV    AL, '*'

        MOV    AH, 0eh

        INT     10h    

        POP     AX

    loop c1      


    sub col,1 

    add row,1

    add num,2


    pop cx

loop c 

对于上面的代码，还是可以进行优化的，我们是将x的值赋给col，col又将其赋给DL，如果将x直接送给DL，就不用定义col这个变量了。对于row，num也是一样的。接下来我们尝试将变量定义去掉，直接对寄存器进行操作。

    我们用AX寄存器来顶替num的作用，在开始的地方给AX赋初值，然后在循环中让AX自加即可。刚开始需要给DH DL寄存器赋值来定义起始点，直接用传入参数赋值即可，然后在循环内让DH和DL寄存器自加或自减来改变坐标。

通过阅读GOTOXY的代码发现其在函数进入和退出的时候进行了压栈和出栈操作，是因为其内部对有些寄存器进行了操作，为了不影响这些寄存器本来的值，要对其原本的值进行保护。这里我们也参考它的做法，对我们修改的寄存器进行保护。

最终完成代码如下：

triangle MACRO x y n  
    
    PUSH    DX
    PUSH    CX
    PUSH    AX  

    MOV     DH, y
    MOV     DL, x 
    MOV     CX, n   
    MOV     AX, 1
c:
    PUSH CX
    
    PUSH    AX
    PUSH    BX
    MOV     AH, 02h
    MOV     BH, 0
    INT     10h
    POP     BX
    POP     AX  
    
    mov cx, AX
    c1:
        PUSH    AX
        MOV     AL, '*'
        MOV     AH, 0Eh
        INT     10h     
        POP     AX
    loop c1        
    sub DL,1  
    add DH,1 
    add AX,2
    
    POP CX
loop c 
    POP    AX
    POP    CX
    POP    DX 
ENDM   

ORG    100h  

triangle 6,1,5

RET  
           
END              

实验效果如下：