洛谷P1605 迷宫

迷宫

问题描述

给定一个N*M方格的迷宫，迷宫里有T处障碍，障碍处不可通过。给定起点坐标和

终点坐标，问: 每个方格最多经过1次，有多少种从起点坐标到终点坐标的方案。在迷宫

中移动有上下左右四种方式，每次只能移动一个方格。数据保证起点上没有障碍。

分析

  此题数据不大可以用深度搜索，搜过的点标记一下退出的时候回溯，搜到终点ans就+1。注意：起点一开始要标记为走过。

时间复杂度

O（2^n）

代码

const
  maxn=10;
  dx:array[1..4] of -1..1=(-1,0,1,0);
  dy:array[1..4] of -1..1=(0,1,0,-1);
var
  a:array[0..maxn,0..maxn] of longint;
  f:array[0..maxn,0..maxn] of boolean;
  i,n,m,ans,t,p,q,x1,x2,y1,y2:longint;


function check(x,y:longint):boolean;
begin
  check:=true;
  if (x<1) or (x>n) or(y<1) or (y>m) or (a[x,y]=1) or (f[x,y])
    then exit(false);
end;


procedure dfs(x,y:longint);
var
  i:longint;
begin
  f[x,y]:=true;
  if (x=x2) and (y=y2) then
    begin
      inc(ans);
      exit;
    end;
  for i:=1 to 4 do
    if check(x+dx[i],y+dy[i]) then
      begin
        f[x+dx[i],y+dy[i]]:=true;
        dfs(x+dx[i],y+dy[i]);
        f[x+dx[i],y+dy[i]]:=false;
      end;
end;


begin
  readln(n,m,t);
  readln(x1,y1,x2,y2);
  for i:=1 to t do
    begin
      readln(p,q);
      a[p,q]:=1;
    end;
  dfs(x1,y1);
  writeln(ans);
end.