洛谷P1316 丢瓶盖

丢瓶盖

问题描述

陶陶是个贪玩的孩子，他在地上丢了A个瓶盖，为了简化问题，我们可以当作这A个瓶盖丢在一条直线上，现在他想从这些瓶盖里找出B个，使得距离最近的2个距离最大，他想知道，最大可以到多少呢？

分析

先排序然后二分答案，只要这个答案是可行的就往后二分否则往前二分。

代码

const
  maxn=100000;
var
  a:array[0..maxn] of longint;
  i,l,r,n,k,ans,mid:longint;


procedure qsort(l,r:longint);
var
  i,j,k:longint;
begin
  if l>=r then exit;
  i:=l;j:=r;
  k:=a[(l+r) div 2];
  repeat
    while a[i]<k do inc(i);
    while a[j]>k do dec(j);
    if i<=j then
      begin
        a[0]:=a[i];a[i]:=a[j];a[j]:=a[0];
        inc(i);dec(j);
      end;
  until i>j;
  qsort(l,j);qsort(i,r);
end;


function check(p:longint):boolean;
var
  s,i,j:longint;
begin
  j:=1;
  s:=1;
  for i:=2 to n do
    if a[i]-a[j]>=p then
      begin
        inc(s);
        j:=i;
        if s=k then exit(true);
      end;
  exit(false);
end;


begin
  readln(n,k);
  for i:=1 to n do
    read(a[i]);
  qsort(1,n);
  l:=1;
  r:=a[n]-a[1];
  while l<=r do
    begin
      mid:=(l+r) div 2;
      if check(mid) then
        begin
          ans:=mid;
          l:=mid+1;
        end
      else r:=mid-1;
    end;
  writeln(ans);
end.