洛谷P1182 数列分段Section II（二分）

数列分段Section II

题目描述

对于给定的一个长度为N的正整数数列A[i]，现要将其分成M（M≤N）段，并要求每段连续，且每段和的最大值最小。

关于最大值最小：

例如一数列4 2 4 5 1要分成3段

将其如下分段：

[4 2][4 5][1]

第一段和为6，第2段和为9，第3段和为1，和最大值为9。

将其如下分段：

[4][2 4][5 1]

第一段和为4，第2段和为6，第3段和为6，和最大值为6。

并且无论如何分段，最大值不会小于6。

所以可以得到要将数列4 2 4 5 1要分成3段，每段和的最大值最小为6。

输入输出格式

输入格式：
输入文件divide_b.in的第1行包含两个正整数N，M，第2行包含N个空格隔开的非负整数A[i]，含义如题目所述。

输出格式：
输出文件divide_b.out仅包含一个正整数，即每段和最大值最小为多少。

分析：二分答案然后判断是否可行。

代码

const
  maxn=100000;
var
  a:array[0..maxn] of longint;
  n,m,i,s,max:longint;

function check(x:longint):boolean;
var
  p,q,i:longint;
begin
  q:=1;
  p:=0;
  for i:=1 to n do
    begin
      if p+a[i]<=x
        then p:=p+a[i]
        else begin
               p:=a[i];
               inc(q);
               if q>m then exit(false);
             end;
    end;
  exit(true);
end;

procedure find(l,r:longint);
var
  mid:longint;
begin
  mid:=(l+r) div 2;
  if l>=r then
    begin
      writeln(mid);
      halt;
    end;
  if check(mid) then find(l,mid) else find(mid+1,r);
end;

begin
  readln(n,m);
  for i:=1 to n do
    begin
      read(a[i]);
      if a[i]>max then max:=a[i];
      s:=s+a[i];
    end;
  find(max,s);
end.