30天自制操作系统第3天harib00h

最新推荐文章于 2021-03-08 20:11:24 发布

阿龙-LAMW

最新推荐文章于 2021-03-08 20:11:24 发布

阅读量223

点赞数

分类专栏： 30天自制操作系统

本文链接：https://blog.csdn.net/zl18206208825/article/details/104563531

版权

30天自制操作系统专栏收录该内容

69 篇文章 7 订阅

订阅专栏

转载CDN：https://blog.csdn.net/zl18206208825/article/details/104581294

30天自制操作系统

第3天进入32位模式并导入 C 语言

开始导入C语言

harib00i

准备材料（windows环境）

VMware Workstation
Visual Studio Code
程序和源代码：https://pan.baidu.com/s/1bFGAYgnA0m9KB7tzFrMD5g
提取码：d210
Makefile
windows 批处理

开始实验

在tolset文件夹下创建子文件侠harib00i;
打开记事本，输入以下代码并另存为 !cons_nt.bat文件（windows 批处理），存放在harib00i文件夹中;

cmd.exe

ps:当然也可以直接使用 win + r 快捷键也可以，不过最好还是创建一个比较好。因为以后打开时不需要再麻烦了。
3. 打开vc code，输入以下代码并保存为 bootpack.c,存放在harib00i文件夹中。

void HariMain(void)
{

fin:
    /* 这里想定上HLT，但C语言不能用HLT！ */
    goto fin;
}

打开vc code，输入以下代码并保存为 asmhead.nas,存放在harib00i文件夹中。

; haribote-os boot asm
; TAB=4

BOTPAK	EQU		0x00280000		; bootpack装载处
DSKCAC	EQU		0x00100000		; 磁盘缓存的地方
DSKCAC0	EQU		0x00008000		; 磁盘高速缓存的场所（实时模式）

; 有关BOOT_INFO
CYLS	EQU		0x0ff0			; 设定启动区
LEDS	EQU		0x0ff1
VMODE	EQU		0x0ff2			; 关于颜色数目的信息，颜色的位数
SCRNX	EQU		0x0ff4			; 分辨率的X（screen x）
SCRNY	EQU		0x0ff6			; 分辨率的Y（screen y)
VRAM	EQU		0x0ff8			; 图像缓冲区的开始地址

		ORG		0xc200			; 这个程序要被装载到内存的什么地方呢？

; 画面模式设定

		MOV		AL,0x13			; VGA显卡，320x200x8位彩色
		MOV		AH,0x00
		INT		0x10
		MOV		BYTE [VMODE],8	; 记录画面模式（C语言参照）
		MOV		WORD [SCRNX],320
		MOV		WORD [SCRNY],200
		MOV		DWORD [VRAM],0x000a0000

; 用BIOS取得键盘各种LED指示灯的状态

		MOV		AH,0x02
		INT		0x16 			; keyboard BIOS
		MOV		[LEDS],AL

; 使PIC不授受一切中断
;	如果要初始PIC的话，要在AT兼容的规范中，
;	如果不把这家伙放在CLI面前，我偶尔会举起来
; 	稍后进行PIC的初始化

        MOV		AL,0xff
        OUT		0x21,AL
        NOP						; 如果连续OUT命令的话，可能会有不太好的机型
        OUT		0xa1,AL

        CLI						; 甚至禁止CPU层面插队

; cpu从1 mb以上的内存,a20gate设定

        CALL	waitkbdout
        MOV		AL,0xd1
        OUT		0x64,AL
        CALL	waitkbdout
        MOV		AL,0xdf			; enable A20
        OUT		0x60,AL
        CALL	waitkbdout

; 保护模式过渡

[INSTRSET "i486p"]				; 用于记述想要使用的486命令

        LGDT	[GDTR0]			; 暂定GDT设定
        MOV		EAX,CR0
        AND		EAX,0x7fffffff	; 使bit31为0（为子禁止寻乎）
		OR		EAX,0x00000001	; 使bit0为1（为子保护模式转移）
        MOV		CR0,EAX
        JMP		pipelineflush
pipelineflush:
        MOV		AX,1*8			; 可读区段32bit
        MOV		DS,AX
        MOV		ES,AX
        MOV		FS,AX
        MOV		GS,AX
        MOV		SS,AX

; bootpack的传送

        MOV		ESI,bootpack	; 传输源
        MOV		EDI,BOTPAK		; 传输目的地
        MOV		ECX,512*1024/4
        CALL	memcpy

; 顺便磁盘数据也向原来的位置传送

; 首先从引导扇区

        MOV		ESI,0x7c00		; 传输源
        MOV		EDI,DSKCAC		; 传输目的地
        MOV		ECX,512/4
        CALL	memcpy

; 剩下的全部

        MOV		ESI,DSKCAC0+512	; 传输源
        MOV		EDI,DSKCAC+512	; 传输目的地
        MOV		ECX,0
        MOV		CL,BYTE [CYLS]
        IMUL	ECX,512*18*2/4	; 从柱面数转换成字节数 /4
        SUB		ECX,512/4		; 通过IPL减去
        CALL	memcpy

; 我们已经完成了需要使用asmhead 进行的所有操作
; 放到bootpack中

; 启动bootpack

        MOV		EBX,BOTPAK
		MOV		ECX,[EBX+16]
		ADD		ECX,3			; ECX += 3;
		SHR		ECX,2			; ECX /= 4;
		JZ		skip			; 无需转移
		MOV		ESI,[EBX+20]	; 传输源
		ADD		ESI,EBX
		MOV		EDI,[EBX+12]	; 传输目的地
		CALL	memcpy
skip:
		MOV		ESP,[EBX+12]	; 堆栈初始值
		JMP		DWORD 2*8:0x0000001b

waitkbdout:
		IN		AL,0x64
		AND		AL,0x02
		JNZ		waitkbdout		; 如果AND的结果不为0，请跳转至waitkbdou
		RET

memcpy:
		MOV		EAX,[ESI]
		ADD		ESI,4
		MOV		[EDI],EAX
		ADD		EDI,4
		SUB		ECX,1
		JNZ		memcpy			; 如果减法不为0，则返回memcpy
		RET
; memcpy也可以用字符串指令编写，除非你忘记了地址大小写前缀

		ALIGNB	16
GDT0:
		RESB	8				; 空选择器
		DW		0xffff,0x0000,0x9200,0x00cf	; 读/定段32bit
		DW		0xffff,0x0000,0x9a28,0x0047	; 可执行段32bit(用于bootpack)

		DW		0
GDTR0:
		DW		8*3-1
		DD		GDT0

		ALIGNB	16
bootpack:

打开 VC code 创建 ipl10.nas 文件，输入以下代码，也存放的harib00i中；

; haribote-ipl
; TAB=4

CYLS	EQU		10				; 要读取到什么程度

		ORG		0x7c00			; 启动装载程序

; 以下记述用于标准FAT12格式软盘

		JMP		entry
		DB		0x90
		DB		"HARIBOTE"		; 磁盘名称（可以是任意字符串）
		DW		512				; 每个扇区的大小（必须是512）
		DB		1				; 簇的大小（必须为一个扇区）
		DW		1				; FAT12的起始位置（一般从第一个扇区开始
		DB		2				; FAT的个数（必须为2）
		DW		224				; 根目录的大小（一般设成224项）
		DW		2880			; 该磁盘的大小（必须是2880扇区）
		DB		0xf0			; 该磁盘的种类（必须是0xf0
		DW		9				; FAt的长度（必须是9扇区）
		DW		18				; 一个磁道有几个扇区（必须是18）
		DW		2				; 磁头数（必须是2）
		DD		0				; 不使用分区，必须是0
		DD		2880			; 磁盘大小
		DB		0,0,0x29		; 意义不明固定
		DD		0xffffffff		; （可能是）卷标号码
		DB		"HARIBOTEOS "	; 磁盘的名称（11字节）
		DB		"FAT12   "		; 磁盘格式名称（8字节）
		RESB	18				; 先空出18字节

; 程序主体

entry:
		MOV		AX,0			; 初始化寄存器
		MOV		SS,AX
		MOV		SP,0x7c00
		MOV		DS,AX

; 读磁盘

		MOV		AX,0x0820
		MOV		ES,AX
		MOV		CH,0			; 柱面 0
		MOV		DH,0			; 磁头 0
		MOV		CL,2			; 扇区 2
readloop:
		MOV		SI,0			; 记录失败次数的寄存器
retry:
		MOV		AH,0x02			; AH=0x02 : 读入磁盘
		MOV		AL,1			; 1 个扇区
		MOV		BX,0
		MOV		DL,0x00			; A 驱动器
		INT		0x13			; 调用磁盘BIOS
		JNC		next			; 没出错时跳转到next
		ADD		SI,1			; SI 加 1
		CMP		SI,5			; 比较 SI 与 5
		JAE		error			; SI >= 5 时，跳转到error
		MOV		AH,0x00
		MOV		DL,0x00			; A 驱动器
		INT		0x13			; 重置驱动器
		JMP		retry
next:
		MOV		AX,ES			; 把内存地址后移0x200
		ADD		AX,0x0020
		MOV		ES,AX			; 因为没有 ADD ES,0x020 指令，所以这里稍微绕个弯
		ADD		CL,1			; CL 加 1
		CMP		CL,18			; 比较 CL 与 18
		JBE		readloop		; 如果 CL <= 18，则跳转至readloop 
		MOV		CL,1
		ADD		DH,1
		CMP		DH,2
		JB		readloop		; 如果 DH < 2， 则跳转到readloop
		MOV		DH,0
		ADD		CH,1
		CMP		CH,CYLS
		JB		readloop		; 如果 CH < CYLS，则跳转至readloop

; 因为看完了实行haribote.sys

		MOV		[0x0ff0],CH		; IPL读到什么地方结束
		JMP		0xc200

error:
		MOV		SI,msg
putloop:
		MOV		AL,[SI]
		ADD		SI,1			; SI 加 1
		CMP		AL,0
		JE		fin
		MOV		AH,0x0e			; 显示一个文字
		MOV		BX,15			; 指定字符颜色
		INT		0x10			; 调用显卡BIOS
		JMP		putloop
fin:
		HLT						; 让CPu停止，等待指令
		JMP		fin				; 无限循环
msg:
		DB		0x0a, 0x0a		; 换行两次
		DB		"load error"
		DB		0x0a			; 换行
		DB		0

		RESB	0x7dfe-$		; 重复0x00一直到0x7dfe

		DB		0x55, 0xaa

打开记事本，输入以下代码，另存为 make.bat, 同样放到harib00i中；

..\z_tools\make.exe %1 %2 %3 %4 %5 %6 %7 %8 %9

创建 Makefile,并输入以下代码并存放到harib00i中;

TOOLPATH = ../z_tools/
INCPATH  = ../z_tools/haribote/

MAKE     = $(TOOLPATH)make.exe -r
NASK     = $(TOOLPATH)nask.exe
CC1      = $(TOOLPATH)cc1.exe -I$(INCPATH) -Os -Wall -quiet
GAS2NASK = $(TOOLPATH)gas2nask.exe -a
OBJ2BIM  = $(TOOLPATH)obj2bim.exe
BIM2HRB  = $(TOOLPATH)bim2hrb.exe
RULEFILE = $(TOOLPATH)haribote/haribote.rul
EDIMG    = $(TOOLPATH)edimg.exe
IMGTOL   = $(TOOLPATH)imgtol.com
COPY     = copy
DEL      = del

# 默认

default :
	$(MAKE) img

# 文件生成规则

ipl10.bin : ipl10.nas Makefile
	$(NASK) ipl10.nas ipl10.bin ipl10.lst

asmhead.bin : asmhead.nas Makefile
	$(NASK) asmhead.nas asmhead.bin asmhead.lst

bootpack.gas : bootpack.c Makefile
	$(CC1) -o bootpack.gas bootpack.c

bootpack.nas : bootpack.gas Makefile
	$(GAS2NASK) bootpack.gas bootpack.nas

bootpack.obj : bootpack.nas Makefile
	$(NASK) bootpack.nas bootpack.obj bootpack.lst

bootpack.bim : bootpack.obj Makefile
	$(OBJ2BIM) @$(RULEFILE) out:bootpack.bim stack:3136k map:bootpack.map \
		bootpack.obj
# 3MB+64KB=3136KB

bootpack.hrb : bootpack.bim Makefile
	$(BIM2HRB) bootpack.bim bootpack.hrb 0

haribote.sys : asmhead.bin bootpack.hrb Makefile
	copy /B asmhead.bin+bootpack.hrb haribote.sys

haribote.img : ipl10.bin haribote.sys Makefile
	$(EDIMG)   imgin:../z_tools/fdimg0at.tek \
		wbinimg src:ipl10.bin len:512 from:0 to:0 \
		copy from:haribote.sys to:@: \
		imgout:haribote.img

# 命令

img :
	$(MAKE) haribote.img

run :
	$(MAKE) img
	$(COPY) haribote.img ..\z_tools\qemu\fdimage0.bin
	$(MAKE) -C ../z_tools/qemu

install :
	$(MAKE) img
	$(IMGTOL) w a: haribote.img

clean :
	-$(DEL) *.bin
	-$(DEL) *.lst
	-$(DEL) *.gas
	-$(DEL) *.obj
	-$(DEL) bootpack.nas
	-$(DEL) bootpack.map
	-$(DEL) bootpack.bim
	-$(DEL) bootpack.hrb
	-$(DEL) haribote.sys

src_only :
	$(MAKE) clean
	-$(DEL) haribote.img

编译及运行

双击 !cons_nt.bat,并在打开的命令行中输入 make run
VMware中运行结果，如下图

ps: 结果就是这样，因为本次实验的目的是开始导入C语言，光标没有了且输出了全黑屏，准备要加载C语言了，以后会有更精彩。敬请期待！
好的今天到这里harib00i就张结束了，请大家多多支持！！！

阿龙-LAMW

关注

0
点赞
踩
0

收藏

觉得还不错? 一键收藏
0
评论
30天自制操作系统第3天harib00h

30天自制操作系统第3天进入32位模式并导入 C 语言32位模式前期准备harib00h准备材料（windows环境）VMware WorkstationVisual Studio Code程序和源代码：https://pan.baidu.com/s/1bFGAYgnA0m9KB7tzFrMD5g提取码：d210Makefilewindows 批处理开始实验在tol...
复制链接

扫一扫