30天自制操作系统第4天harib01h

最新推荐文章于 2021-03-09 16:40:08 发布
最新推荐文章于 2021-03-09 16:40:08 发布
阅读量331 收藏
点赞数
分类专栏： 30天自制操作系统 文章标签： c语言 os bootloader
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/zl18206208825/article/details/104723065
版权

30天自制操作系统

第4天 C语言与画面显示的练习

今天的成果

harib01h
准备材料（windows环境）
开始实验

  1. 在tolset文件夹下创建子文件侠harib01h;

  2. 打开记事本，输入以下代码并另存为 !cons_nt.bat文件（windows 批处理），存放在harib01h文件夹中;

cmd.exe

ps:当然也可以直接使用 win + r 快捷键也可以，不过最好还是创建一个比较好。因为以后打开时不需要再麻烦了。
3. 打开vc code,输入以下代码并保存为 naskfunc.nas,存放在harib01h文件夹中；

; naskfunc
; TAB=4

[FORMAT "WCOFF"]				; 制作目标文件的模式
[INSTRSET "i486p"]				; 要使用486指令的语句
[BITS 32]						; 制作32位模式用的机器语言
[FILE "naskfunc.nas"]			; 原文件名信息

		GLOBAL	_io_hlt, _io_cli, _io_sti, _io_stihlt
		GLOBAL	_io_in8,  _io_in16,  _io_in32
		GLOBAL	_io_out8, _io_out16, _io_out32
		GLOBAL	_io_load_eflags, _io_store_eflags

[SECTION .text]	

_io_hlt:	; void io_hlt(void);
		HLT
		RET

_io_cli:	; void io_cli(void);
		CLI
		RET

_io_sti:	; void io_sti(void);
		STI
		RET

_io_stihlt:	; void io_stihlt(void);
		STI
		HLT
		RET

_io_in8:	; int io_in8(int port);
		MOV		EDX,[ESP+4]		; port
		MOV		EAX,0
		IN		AL,DX
		RET

_io_in16:	; int io_in16(int port);
		MOV		EDX,[ESP+4]		; port
		MOV		EAX,0
		IN		AX,DX
		RET

_io_in32:	; int io_in32(int port);
		MOV		EDX,[ESP+4]		; port
		IN		EAX,DX
		RET

_io_out8:	; void io_out8(int port, int data);
		MOV		EDX,[ESP+4]		; port
		MOV		AL,[ESP+8]		; data
		OUT		DX,AL
		RET

_io_out16:	; void io_out16(int port, int data);
		MOV		EDX,[ESP+4]		; port
		MOV		EAX,[ESP+8]		; data
		OUT		DX,AX
		RET

_io_out32:	; void io_out32(int port, int data);
		MOV		EDX,[ESP+4]		; port
		MOV		EAX,[ESP+8]		; data
		OUT		DX,EAX
		RET

_io_load_eflags:	; int io_load_eflags(void);
		PUSHFD		; 指 PUSH EFLAGS
		POP		EAX
		RET

_io_store_eflags:	; void io_store_eflags(int eflags);
		MOV		EAX,[ESP+4]
		PUSH	EAX
		POPFD		; 指 POP EFLAGS
		RET
  1. 打开vc code,输入以下代码并保存为 bootpack.c 存放在haribooj文件夹中。
void io_hlt(void);
void io_cli(void);
void io_out8(int port, int data);
int io_load_eflags(void);
void io_store_eflags(int eflags);

void init_palette(void);
void set_palette(int start, int end, unsigned char *rgb);
void boxfill8(unsigned char *vram, int xsize, unsigned char c, int x0, int y0, int x1, int y1);

#define COL8_000000		0
#define COL8_FF0000		1
#define COL8_00FF00		2
#define COL8_FFFF00		3
#define COL8_0000FF		4
#define COL8_FF00FF		5
#define COL8_00FFFF		6
#define COL8_FFFFFF		7
#define COL8_C6C6C6		8
#define COL8_840000		9
#define COL8_008400		10
#define COL8_848400		11
#define COL8_000084		12
#define COL8_840084		13
#define COL8_008484		14
#define COL8_848484		15

void HariMain(void)
{
    char *vram;
    int xsize,ysize;

    init_palette();
    vram = (char *) 0xa0000;
    xsize = 320;
    ysize = 200;

	boxfill8(vram, xsize, COL8_008484,  0,         0,          xsize -  1, ysize - 29);
	boxfill8(vram, xsize, COL8_C6C6C6,  0,         ysize - 28, xsize -  1, ysize - 28);
	boxfill8(vram, xsize, COL8_FFFFFF,  0,         ysize - 27, xsize -  1, ysize - 27);
	boxfill8(vram, xsize, COL8_C6C6C6,  0,         ysize - 26, xsize -  1, ysize -  1);

	boxfill8(vram, xsize, COL8_FFFFFF,  3,         ysize - 24, 59,         ysize - 24);
	boxfill8(vram, xsize, COL8_FFFFFF,  2,         ysize - 24,  2,         ysize -  4);
	boxfill8(vram, xsize, COL8_848484,  3,         ysize -  4, 59,         ysize -  4);
	boxfill8(vram, xsize, COL8_848484, 59,         ysize - 23, 59,         ysize -  5);
	boxfill8(vram, xsize, COL8_000000,  2,         ysize -  3, 59,         ysize -  3);
	boxfill8(vram, xsize, COL8_000000, 60,         ysize - 24, 60,         ysize -  3);

	boxfill8(vram, xsize, COL8_848484, xsize - 47, ysize - 24, xsize -  4, ysize - 24);
	boxfill8(vram, xsize, COL8_848484, xsize - 47, ysize - 23, xsize - 47, ysize -  4);
	boxfill8(vram, xsize, COL8_FFFFFF, xsize - 47, ysize -  3, xsize -  4, ysize -  3);
	boxfill8(vram, xsize, COL8_FFFFFF, xsize -  3, ysize - 24, xsize -  3, ysize -  3);

    for (;;)
    {
        io_hlt();
    }
}

void init_palette(void)
{
    static unsigned char table_rgb[16 * 3] = {
        0x00, 0x00, 0x00,   /* 0 : 黑 */
        0xff, 0x00, 0x00,   /* 1 : 亮红 */
        0x00, 0xff, 0x00,   /* 2 : 亮绿 */
        0xff, 0xff, 0x00,   /* 3 : 亮黄 */
        0x00, 0x00, 0xff,   /* 4 ：亮蓝 */
        0xff, 0x00, 0xff,   /* 5 : 亮紫 */
        0x00, 0x00, 0xff,   /* 6 : 浅亮蓝 */
        0xff, 0xff, 0xff,   /* 7 ：白 */
        0xc6, 0xc6, 0xc6,   /* 8 : 亮灰 */
        0x84, 0x00, 0x00,   /* 9 : 暗红 */
        0x00, 0x84, 0x00,   /* 10 : 暗绿 */
        0x84, 0x84, 0x00,   /* 11 : 暗黄 */
        0x00, 0x00, 0x84,   /* 12 : 暗青 */
        0x84, 0x00, 0x84,   /* 13 : 暗紫 */
        0x00, 0x84, 0x84,   /* 14 : 浅暗蓝 */
        0x84, 0x84, 0x84   /* 15 : 暗灰 */
    };
    set_palette(0, 15, table_rgb);
    return;

    /* C语言中的static char语句只能用于数据， 相当于汇编中的DB指令 */
}

void set_palette(int start, int end, unsigned char *rgb)
{
    int i, eflags;
    eflags = io_load_eflags();  /* 记录中断许可标志的值 */
    io_cli();                   /* 将中断许可标志置为0， 禁止中断 */
    io_out8(0x03c8, start);
    for (i = start; i <= end; i++) {
        io_out8(0x03c9, rgb[0] / 4);
        io_out8(0x03c9, rgb[1] / 4);
        io_out8(0x03c9, rgb[2] / 4);
        rgb += 3;
    }
    io_store_eflags(eflags);    /*  复原中断许可标志 */
    return;
}

void boxfill8(unsigned char *vram, int xsize, unsigned char c, int x0, int y0, int x1, int y1)
{
	int x, y;
	for (y = y0; y <= y1; y++) {
		for (x = x0; x <= x1; x++)
			vram[y * xsize + x] = c;
	}
    return;
}

ps: 出现任务栏，
；
5. 打vc code，输入以下代码并保存为 asmhead.nas,存放在harib01h文件夹中。

; haribote-os boot asm
; TAB=4

BOTPAK	EQU		0x00280000		; bootpack装载处
DSKCAC	EQU		0x00100000		; 磁盘缓存的地方
DSKCAC0	EQU		0x00008000		; 磁盘高速缓存的场所（实时模式）

; 有关BOOT_INFO
CYLS	EQU		0x0ff0			; 设定启动区
LEDS	EQU		0x0ff1
VMODE	EQU		0x0ff2			; 关于颜色数目的信息，颜色的位数
SCRNX	EQU		0x0ff4			; 分辨率的X（screen x）
SCRNY	EQU		0x0ff6			; 分辨率的Y（screen y)
VRAM	EQU		0x0ff8			; 图像缓冲区的开始地址

		ORG		0xc200			; 这个程序要被装载到内存的什么地方呢？

; 画面模式设定

		MOV		AL,0x13			; VGA显卡，320x200x8位彩色
		MOV		AH,0x00
		INT		0x10
		MOV		BYTE [VMODE],8	; 记录画面模式（C语言参照）
		MOV		WORD [SCRNX],320
		MOV		WORD [SCRNY],200
		MOV		DWORD [VRAM],0x000a0000

; 用BIOS取得键盘各种LED指示灯的状态

		MOV		AH,0x02
		INT		0x16 			; keyboard BIOS
		MOV		[LEDS],AL

; 使PIC不授受一切中断
;	如果要初始PIC的话，要在AT兼容的规范中，
;	如果不把这家伙放在CLI面前，我偶尔会举起来
; 	稍后进行PIC的初始化

        MOV		AL,0xff
        OUT		0x21,AL
        NOP						; 如果连续OUT命令的话，可能会有不太好的机型
        OUT		0xa1,AL

        CLI						; 甚至禁止CPU层面插队

; cpu从1 mb以上的内存,a20gate设定

        CALL	waitkbdout
        MOV		AL,0xd1
        OUT		0x64,AL
        CALL	waitkbdout
        MOV		AL,0xdf			; enable A20
        OUT		0x60,AL
        CALL	waitkbdout

; 保护模式过渡

[INSTRSET "i486p"]				; 用于记述想要使用的486命令

        LGDT	[GDTR0]			; 暂定GDT设定
        MOV		EAX,CR0
        AND		EAX,0x7fffffff	; 使bit31为0（为子禁止寻乎）
		OR		EAX,0x00000001	; 使bit0为1（为子保护模式转移）
        MOV		CR0,EAX
        JMP		pipelineflush
pipelineflush:
        MOV		AX,1*8			; 可读区段32bit
        MOV		DS,AX
        MOV		ES,AX
        MOV		FS,AX
        MOV		GS,AX
        MOV		SS,AX

; bootpack的传送

        MOV		ESI,bootpack	; 传输源
        MOV		EDI,BOTPAK		; 传输目的地
        MOV		ECX,512*1024/4
        CALL	memcpy

; 顺便磁盘数据也向原来的位置传送

; 首先从引导扇区

        MOV		ESI,0x7c00		; 传输源
        MOV		EDI,DSKCAC		; 传输目的地
        MOV		ECX,512/4
        CALL	memcpy

; 剩下的全部

        MOV		ESI,DSKCAC0+512	; 传输源
        MOV		EDI,DSKCAC+512	; 传输目的地
        MOV		ECX,0
        MOV		CL,BYTE [CYLS]
        IMUL	ECX,512*18*2/4	; 从柱面数转换成字节数 /4
        SUB		ECX,512/4		; 通过IPL减去
        CALL	memcpy

; 我们已经完成了需要使用asmhead 进行的所有操作
; 放到bootpack中

; 启动bootpack

        MOV		EBX,BOTPAK
		MOV		ECX,[EBX+16]
		ADD		ECX,3			; ECX += 3;
		SHR		ECX,2			; ECX /= 4;
		JZ		skip			; 无需转移
		MOV		ESI,[EBX+20]	; 传输源
		ADD		ESI,EBX
		MOV		EDI,[EBX+12]	; 传输目的地
		CALL	memcpy
skip:
		MOV		ESP,[EBX+12]	; 堆栈初始值
		JMP		DWORD 2*8:0x0000001b

waitkbdout:
		IN		AL,0x64
		AND		AL,0x02
		JNZ		waitkbdout		; 如果AND的结果不为0，请跳转至waitkbdou
		RET

memcpy:
		MOV		EAX,[ESI]
		ADD		ESI,4
		MOV		[EDI],EAX
		ADD		EDI,4
		SUB		ECX,1
		JNZ		memcpy			; 如果减法不为0，则返回memcpy
		RET
; memcpy也可以用字符串指令编写，除非你忘记了地址大小写前缀

		ALIGNB	16
GDT0:
		RESB	8				; 空选择器
		DW		0xffff,0x0000,0x9200,0x00cf	; 读/定段32bit
		DW		0xffff,0x0000,0x9a28,0x0047	; 可执行段32bit(用于bootpack)

		DW		0
GDTR0:
		DW		8*3-1
		DD		GDT0

		ALIGNB	16
bootpack:
  1. 打开 VC code 创建 ipl10.nas 文件，输入以下代码，也存放的harib01h中；
; haribote-ipl
; TAB=4

CYLS	EQU		10				; 要读取到什么程度

		ORG		0x7c00			; 启动装载程序

; 以下记述用于标准FAT12格式软盘

		JMP		entry
		DB		0x90
		DB		"HARIBOTE"		; 磁盘名称（可以是任意字符串）
		DW		512				; 每个扇区的大小（必须是512）
		DB		1				; 簇的大小（必须为一个扇区）
		DW		1				; FAT12的起始位置（一般从第一个扇区开始
		DB		2				; FAT的个数（必须为2）
		DW		224				; 根目录的大小（一般设成224项）
		DW		2880			; 该磁盘的大小（必须是2880扇区）
		DB		0xf0			; 该磁盘的种类（必须是0xf0
		DW		9				; FAt的长度（必须是9扇区）
		DW		18				; 一个磁道有几个扇区（必须是18）
		DW		2				; 磁头数（必须是2）
		DD		0				; 不使用分区，必须是0
		DD		2880			; 磁盘大小
		DB		0,0,0x29		; 意义不明固定
		DD		0xffffffff		; （可能是）卷标号码
		DB		"HARIBOTEOS "	; 磁盘的名称（11字节）
		DB		"FAT12   "		; 磁盘格式名称（8字节）
		RESB	18				; 先空出18字节

; 程序主体

entry:
		MOV		AX,0			; 初始化寄存器
		MOV		SS,AX
		MOV		SP,0x7c00
		MOV		DS,AX

; 读磁盘

		MOV		AX,0x0820
		MOV		ES,AX
		MOV		CH,0			; 柱面 0
		MOV		DH,0			; 磁头 0
		MOV		CL,2			; 扇区 2
readloop:
		MOV		SI,0			; 记录失败次数的寄存器
retry:
		MOV		AH,0x02			; AH=0x02 : 读入磁盘
		MOV		AL,1			; 1 个扇区
		MOV		BX,0
		MOV		DL,0x00			; A 驱动器
		INT		0x13			; 调用磁盘BIOS
		JNC		next			; 没出错时跳转到next
		ADD		SI,1			; SI 加 1
		CMP		SI,5			; 比较 SI 与 5
		JAE		error			; SI >= 5 时，跳转到error
		MOV		AH,0x00
		MOV		DL,0x00			; A 驱动器
		INT		0x13			; 重置驱动器
		JMP		retry
next:
		MOV		AX,ES			; 把内存地址后移0x200
		ADD		AX,0x0020
		MOV		ES,AX			; 因为没有 ADD ES,0x020 指令，所以这里稍微绕个弯
		ADD		CL,1			; CL 加 1
		CMP		CL,18			; 比较 CL 与 18
		JBE		readloop		; 如果 CL <= 18，则跳转至readloop 
		MOV		CL,1
		ADD		DH,1
		CMP		DH,2
		JB		readloop		; 如果 DH < 2， 则跳转到readloop
		MOV		DH,0
		ADD		CH,1
		CMP		CH,CYLS
		JB		readloop		; 如果 CH < CYLS，则跳转至readloop

; 因为看完了实行haribote.sys

		MOV		[0x0ff0],CH		; IPL读到什么地方结束
		JMP		0xc200

error:
		MOV		SI,msg
putloop:
		MOV		AL,[SI]
		ADD		SI,1			; SI 加 1
		CMP		AL,0
		JE		fin
		MOV		AH,0x0e			; 显示一个文字
		MOV		BX,15			; 指定字符颜色
		INT		0x10			; 调用显卡BIOS
		JMP		putloop
fin:
		HLT						; 让CPu停止，等待指令
		JMP		fin				; 无限循环
msg:
		DB		0x0a, 0x0a		; 换行两次
		DB		"load error"
		DB		0x0a			; 换行
		DB		0

		RESB	0x7dfe-$		; 重复0x00一直到0x7dfe

		DB		0x55, 0xaa
  1. 打开记事本，输入以下代码，另存为 make.bat, 同样放到harib01h中；
..\z_tools\make.exe %1 %2 %3 %4 %5 %6 %7 %8 %9
  1. 创建 Makefile,并输入以下代码并存放到harib01h中;
TOOLPATH = ../z_tools/
INCPATH  = ../z_tools/haribote/

MAKE     = $(TOOLPATH)make.exe -r
NASK     = $(TOOLPATH)nask.exe
CC1      = $(TOOLPATH)cc1.exe -I$(INCPATH) -Os -Wall -quiet
GAS2NASK = $(TOOLPATH)gas2nask.exe -a
OBJ2BIM  = $(TOOLPATH)obj2bim.exe
BIM2HRB  = $(TOOLPATH)bim2hrb.exe
RULEFILE = $(TOOLPATH)haribote/haribote.rul
EDIMG    = $(TOOLPATH)edimg.exe
IMGTOL   = $(TOOLPATH)imgtol.com
COPY     = copy
DEL      = del

# 默认

default :
	$(MAKE) img

# 文件生成规则

ipl10.bin : ipl10.nas Makefile
	$(NASK) ipl10.nas ipl10.bin ipl10.lst

asmhead.bin : asmhead.nas Makefile
	$(NASK) asmhead.nas asmhead.bin asmhead.lst

bootpack.gas : bootpack.c Makefile
	$(CC1) -o bootpack.gas bootpack.c

bootpack.nas : bootpack.gas Makefile
	$(GAS2NASK) bootpack.gas bootpack.nas

bootpack.obj : bootpack.nas Makefile
	$(NASK) bootpack.nas bootpack.obj bootpack.lst

naskfunc.obj : naskfunc.nas Makefile
	$(NASK) naskfunc.nas naskfunc.obj naskfunc.lst

bootpack.bim : bootpack.obj naskfunc.obj Makefile
	$(OBJ2BIM) @$(RULEFILE) out:bootpack.bim stack:3136k map:bootpack.map \
		bootpack.obj naskfunc.obj
# 3MB+64KB=3136KB

bootpack.hrb : bootpack.bim Makefile
	$(BIM2HRB) bootpack.bim bootpack.hrb 0

haribote.sys : asmhead.bin bootpack.hrb Makefile
	copy /B asmhead.bin+bootpack.hrb haribote.sys

haribote.img : ipl10.bin haribote.sys Makefile
	$(EDIMG)   imgin:../z_tools/fdimg0at.tek \
		wbinimg src:ipl10.bin len:512 from:0 to:0 \
		copy from:haribote.sys to:@: \
		imgout:haribote.img

# 命令

img :
	$(MAKE) haribote.img

run :
	$(MAKE) img
	$(COPY) haribote.img ..\z_tools\qemu\fdimage0.bin
	$(MAKE) -C ../z_tools/qemu

install :
	$(MAKE) img
	$(IMGTOL) w a: haribote.img

clean :
	-$(DEL) *.bin
	-$(DEL) *.lst
	-$(DEL) *.gas
	-$(DEL) *.obj
	-$(DEL) bootpack.nas
	-$(DEL) bootpack.map
	-$(DEL) bootpack.bim
	-$(DEL) bootpack.hrb
	-$(DEL) haribote.sys

src_only :
	$(MAKE) clean
	-$(DEL) haribote.img
编译及运行
  1. 双击 !cons_nt.bat,并在打开的命令行中输入 make run
    在这里插入图片描述
  2. VMware中运行结果，如下图
    在这里插入图片描述
    ps: 结果就是这样，因为本次实验的目的是任务栏(harib01h)，光标没有了且输出了矩形，以后会有更精彩。敬请期待！
    好的今天到这里harib01h就张结束了，请大家多多支持！！！
阿龙-LAMW
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
《30天自制操作系统》 day4 小结
mintancy的博客
07-26 1660
1. 用C语言往内存写入Naskfunc.nas中增加了一个函数可供C语言调用的函数_write_mem8，用于实现直接写入指定内存地址的语句。 如果C语言中write_mem8(0x1234,0x56);语句， 则动作上相当于汇编的MOV BYTE[0x1234],0x56第一个数字在内存里的存放地址[ESP+4] 下一个数字的存放就依次累加4 值得注意的是，如果和C语言联合使用的话，
《30天自制操作系统》day1--4 若干问题
xuhaoran406的博客
11-01 245
阅读建议：本文针对已经做过《30天自制操作系统》第一到四天相关内容的读者，笔者写本文时查阅相关资料较少，可能会有错误，仅供参考，欢迎指正。 1.关于 bootpack.c 中的主函数名 可能作者将HariMain这个主函数名嵌入到编译器中，总之不能改 2.第四天的调色板说明 根据笔者所做的若干实验猜测，应该是8位彩色模式是一个假彩色模式，每个数字代表一...
30天自制操作系统第1~15天实验日志.zip
02-17
30天自制操作系统第1~15天实验日志，包括实验内容，问题及解决方式，描述创新点
获取电脑磁盘信息
04-02
VC++获取电脑磁盘信息，设备信息，硬盘信息。代码打包！
《30天自制操作系统》实现中文显示
weixin_34355559的博客
07-21 424
　　《30天自制操作系统》最近一直再看，最近已经看到后面了，看到第28天，里面讲到可以实现对全角字符的支持，而原操作系统代码里面只是支持了日语显示，而中文版的这本书也只是讲了一个思路，具体的实现也是没有的。网上也好像没有人实现过这个吧，我是找不到。(由于书中每一章每一小节都有代码，我看书的时候就懒得去实际写代码，就简单看看。不过这次就可以写一下了，加深对这个系统的了解)反正没事做，就准备实现对这个...
30天自制操作系统综合大设计harib12g.zip
02-07
30天自制操作系统最后的实验验收，将近两千行的代码，两点在于开机动画的帧数多，密码，双击，时钟绘制的好看，直线的绘制，可以用拖动的方式绘制矩形，还可以通过输入的方式改变绘制的大小，以及窗口颜色来改变颜色
harib02e.zip
09-13
“harib02e.zip”这个名字可能对熟悉这个项目的人来说并不陌生，它是川合秀实的“30天自制操作系统”计划的一部分。这个计划鼓励开发者在30天内从零开始创建一个简单的操作系统，旨在让开发者了解操作系统的底层运作...
harib11i.rar
01-05
《30天自制操作系统》是一本引导读者逐步构建操作系统的学习教程，旨在帮助读者理解操作系统的原理和实现。在这个过程中，作者通常会提供每日任务，读者按照指导完成编码工作。"harib11i.rar" 是一个与这个教程相关...
OSASK.zip_OSA_osask系统下载_操作系统制作_自制 操作系统_自制操作系统
最新发布
09-20
4. **编译与链接**：理解如何将源代码编译成可执行文件，以及链接器如何把多个编译单元整合成一个可运行程序，是自制操作系统的关键技能。 5. **调试技巧**：学习使用调试工具如GDB来检查代码运行状态，定位并修复...
YunGameDownload.zip
06-21
当涉及到“操作系统显示中文字符”这一主题时，我们主要讨论的是如何在操作系统环境中正确地显示、输入和处理中文字符，这对于中文用户来说至关重要。 首先，操作系统需要具备对Unicode字符集的支持，因为Unicode...
按钮实现
weixin_45736498的博客
06-20 430
带圆角按钮的实现 实现按钮的方式 button: 行内块级元素 <input type="button">: 表单组件 <button>: 按钮 a: 链接，在鼠标悬停的时候可以提供不同的样式 div 实现主要看自己选择什么，主要是css样式 button html <input type="button" value="点击"> <br> <br> <button value="点击">点击&lt
30天自制操作系统学习-第4天
qq511714326的博客
10-03 1170
1 用C语言写入内存 前三天的学习我们顺利让一个大小1440kb的helloos.img镜像文件运行起来，显示出hello world字样，可是这样的屏幕一片漆黑， 显示更我们熟悉的windos，linux等系统相去甚远，这次我们尝试让屏幕显示出一点“颜色”出来，往naskfunc.nas里添加一个我们 用来显示颜色的函数吧： _write_mem8: ; void write_mem8...
<30天自制操作系统>第四天
talent_CYJ
07-22 1210
第四天内容主要是基于第三天的图形界面显示更进了一步。主要是更复杂的显示，而不是单纯的切换到显示模式。对显卡内存进行数据写入，从而显示出我们想要的画面。想要画东西，只要往VRAM里写数据即可，先看以下程序：_write_mem8: ; void write_mem8(int addr, int data); MOV ECX,[ESP+4] ; [ESP+4]中存放
【30天自制操作系统】第四天
pipizhuwcy的博客
12-01 135
void io_hlt(void); void io_cli(void); void io_out8(int port, int data); int io_load_eflags(void); void io_store_eflags(int eflags); /*就算在同一个源文件里，如果想在定义之前使用,还是必须事先申明*/ void init_palette(void); void set_palette(int start, int end, unsigned char *rgb); voi
《30天自制操作系统》04_day_学习笔记
weixin_30345577的博客
08-17 110
harib01a: 　　P65 用C语言实现内存写入 实现一个往黑画面上写入东西的函数 　　修改了naskfunc.nas中的内容 　　在bootpack.c中 用write_mem8()函数将VRMA中全部写入了15 　　显示的全部像素的颜色为第15种颜色（白色）可以试着修改 ;naskfunc.nas中添加的内容_write_mem8: ; void write_m...
30天制作操作系统第4天
recordliu的博客
03-09 178
30天制作操作系统第四天 这是一个菜鸡为了学习操作系统来练习写的操作系统，参照于书籍《30天自制操作系统》。 相关程序已经放到GitHub中，如果我的能力到位我可能会在这个操作系统的基础上进行添加及优化，作者已经把所有东西都做到极致了，我能做的很少，我只能把自己分析学习的文章总结出来。因为自己能力可能不到位，可能会有些错误希望大家理解，发到这里更多的原因的起到记录作用，如果以后的我回看我写的文章有错误，我会进行修改，同时也希望大家互相学习。 相关项目及源码已经放到GitHub中：https://githu
javascript基础第四天(小白一枚)
hackerhua的博客
04-20 140
javasciprt基础学习 各位前辈及正在一起学习的童靴们,愿在属于自己的世界发光发热,一起学习一起交流,怀着初心,一起前行 初心 鄙人刚入门javascript没多久(一直处于自学),一直也喜欢做开发(中二少年),总幻想着有一天用技术改变着这个世界能为更多人带来美好,这是我第一次写博客(但愿你们喜欢),记录着每一次的学习,每一步的成长! 共勉(之前的会尽快补上) 基础 数组.简单来说就是存放东...
C#调用Win32 api学习总结
热门推荐
bcbobo21cn的专栏
03-19 1万+
从.NET平台调用Win32 API         Win32 API可以直接控制Microsoft Windows的核心，因为API（Application Programming Interface）本来就是微软留给我们直接控制Windows的接口。 一.    基础知识         Win32 API是C语言（注意，不是C++语言，尽管C语言是C++语言的子集）函数集。
30天自制操作系统day4
坏脾气的半瓶子
05-16 304
第四天的重点在于调用显卡BIOS中断，并使用其中断，从而使图形显示需求界面但是连接之前的内容，发现还是有需要重新确认的地方比如.sys文件，其实是由一个汇编编写从而生成的.bin文件与C语言编写生成的obj.文件再生成的镜像文件.hrb，拼接而成的，稍微有些绕，看一下,Makefile可见，首先是C语言入口与其从属函数各自生成.obj，后连接生成映像.bim,再生成.hrb,然后执行两个copy命...
30天自制操作系统第五天
xiaoana_139的博客
12-31 685
操作系统实验日志5 第5天：结构体、文字显示与GDT/IDT初始化 30天自制操作系统第五天操作系统实验日志5一、实验主要内容1、 内容1：接收启动信息2、 内容2：使用结构体3、 内容3：使用箭头记号4、 内容4：显示字符5、 内容5：增加字体6、 内容6：显示字符串7、 内容7：显示变量值8、 内容8：显示鼠标指针9、 内容9：GDT与IDT的初始化（使鼠标移动的前提）二、遇...
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值