oracle函数实现字符串分割，返回表格式的结果集

CREATE OR REPLACE FUNCTION highsoft_split(p_str       IN long,--VARCHAR2,
                                          p_delimiter IN VARCHAR2)
/****************************************************************
  功能说明：实现了类似Java方法split的功能。可将字符串根据自定义分割符进行分割，返回结果为表格式的结果集。
 
  传入参数：
      p_str         传入需要进行分割的字符串
      p_delimiter   自定义分割符号

  返回参数：
     strings_table    --分割完成后，以表格式的结果集

  修改说明：
 
  ****************************************************************/                                          
  RETURN strings_table IS
  j         INT := 0;
  i         INT := 1;
  len       INT := 0;
  len1      INT := 0;
  str       long;--VARCHAR2(2000);
  str_split strings_table := strings_table();
BEGIN
  len  := LENGTH(p_str);
  len1 := LENGTH(p_delimiter);

  WHILE j < len LOOP
    j := INSTR(p_str, p_delimiter, i);
 
    IF j = 0 THEN
      j   := len;
      str := SUBSTR(p_str, i);
      str_split.EXTEND;
      str_split(str_split.COUNT) := str;
    
      IF i >= len THEN
        EXIT;
      END IF;
    ELSE
      str := SUBSTR(p_str, i, j - i);
      i   := j + len1;
      str_split.EXTEND;
      str_split(str_split.COUNT) := str;
    END IF;
  END LOOP;

  RETURN str_split;
END highsoft_split;