flex 开发的电子画板(桌面应用程序)

最新推荐文章于 2019-07-17 05:31:52 发布
最新推荐文章于 2019-07-17 05:31:52 发布
阅读量268 收藏
点赞数
文章标签： Flex AIR Adobe Flash UP
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/zorrolg/article/details/83887306
版权

可以画线，圆，方块，以及截取当前画板图像的功能。

 

直接上代码吧，我的环境是AIR 2.6， FB4。

 

ElectronicBoard.mxml  主程序。

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" 
						width="100%" height="100%"
						applicationComplete="init()" layout="absolute"
						showTitleBar="false" showStatusBar="false" showFlexChrome="false" borderStyle="none">
	<mx:Script>
		<![CDATA[
			import flash.net.dns.AAAARecord;
			
			import mx.binding.utils.BindingUtils;
			import mx.collections.ArrayCollection;
			import mx.controls.Alert;
			import mx.controls.FileSystemList;
			import mx.controls.FileSystemTree;
			import mx.core.Application;
			import mx.core.UIComponent;
			import mx.events.FlexEvent;
			import mx.graphics.ImageSnapshot;
			import mx.graphics.codec.JPEGEncoder;
			import mx.managers.PopUpManager;
			
			private var oY:Number;
			private var nX:Number;
			private var oX:Number;
			private var nY:Number;
			private var _isDown:Boolean=false;
			private var showBasePanelFlag:Boolean=false;
			private var _file:File;
			private var sprit:Sprite=new Sprite();
			private var comUI:UIComponent=new UIComponent();
			private var PrObj:Object=new Object();
			private var _imgByteArray:ByteArray;
			private var  saveDirectoryPath:String;
			[Bindable]
			private var pop1:ConsolePanel;
			 
			private function init():void
			{
				//全屏
				systemManager.stage.addEventListener(FullScreenEvent.FULL_SCREEN,fullScreenHand);
				systemManager.stage.displayState = StageDisplayState.FULL_SCREEN_INTERACTIVE;
				//清除画板
				myPanel.removeAllChildren();
				myPanel.visible=true;
				//0x869ca7设置画笔颜色。
				myPanel.graphics.lineStyle(0,0xFFFFFF,0);
				//绘制一个透明度为0.1的画板。
				myPanel.graphics.beginFill(0xFFFFFF,0.1);
				myPanel.graphics.drawRect(0,0,this.width,this.height);
				myPanel.graphics.endFill();
				//添加鼠标事件监听，即画笔动作的处理。
				myPanel.addEventListener(MouseEvent.MOUSE_DOWN,downHandler);
				myPanel.addEventListener(MouseEvent.MOUSE_MOVE,moveHandler);
				myPanel.addEventListener(MouseEvent.MOUSE_UP,upHandler);
				//弹出设置面板
				pop1 = ConsolePanel(PopUpManager.createPopUp(myPanel,ConsolePanel,false));
				//鼠标移动到设置面板上时，显示设置面板，否则隐藏到屏幕上方。
				pop1.addEventListener(MouseEvent.ROLL_OVER,moveImage);
				pop1.addEventListener(MouseEvent.ROLL_OUT,moveout);
				//初始化设置面板位置。
				pop1.x = (stage.width - pop1.width)/2;
				pop1.y = -220;
				//设置面板上的按钮事件处理。
				pop1.btn_cancel.addEventListener(MouseEvent.CLICK,btn_cancel_clickHandler);
				pop1.btn_reset.addEventListener(MouseEvent.CLICK,btn_reset_clickHandler);
				pop1.btn_recovery.addEventListener(MouseEvent.CLICK,btn_recovery_clickHandler);
				pop1.prScrn.addEventListener(MouseEvent.CLICK,prScrn_clickHandler);
				//设置面板中保存清除，撤消，恢复等操作所涉及对象的集合。
				if(pop1.indexList.length!=0)
				{
					pop1.indexList.removeAll();
				}
				if(pop1.tempDel.length!=0)
				{
					pop1.tempDel.removeAll();
				}	
			}
			
			private function fullScreenHand(evt:FullScreenEvent):void{
				if(evt.fullScreen)
				{}
				else
				{//一旦退出全屏即退出系统。
					this.exit();
				}
			}
			//---------截屏----------------
			protected function prScrn_clickHandler(event:MouseEvent):void
			{
				var now:Date=new Date();
				var encode:JPEGEncoder=new JPEGEncoder(100);
				var m : Matrix = new Matrix();
				//ImageSnapshot类抓取myPanel面板的BitmapData
				var bmp:BitmapData = ImageSnapshot.captureBitmapData(myPanel,m,null,null,null,true);
				bmp.draw(myPanel,m);
				//解析为ByteArray
				_imgByteArray=encode.encode(bmp);
				//设置文件名
				var imgName:String="\\"+df.format(now)+".jpg";
				//第一次保存图片，打开保存位置对话框选择保存位置。
				if (_file == null) {
					//默认打开的保存路径为桌面，并且对话框有默认的文件名，文件名为设置的imgName。
					_file =new File(File.desktopDirectory.nativePath +  imgName);
					//对话框标题。
					_file.browseForSave("请选择截屏图片的保存位置");
					//单击保存按钮派发事件。
					_file.addEventListener(Event.SELECT,getSavePathHandler);
					//单击取消按钮将判断条件回置为初始状态。
					_file.addEventListener(Event.CANCEL,function():void{_file = null;return;});
				} else {
					//若是第一次以后打开，则_file不为空，saveDirectoryPath值已经在getSavePathHandler方法中赋值，其值为第一次选择的保存路径。
					_file =new File(saveDirectoryPath +  imgName);
//					Alert.show(_file.nativePath);
					writeDataToImage();
				}
			}
			//点击保存按钮，触发select事件时的处理函数。
			private function getSavePathHandler(event:Event):void
			{
				_file = event.target as File;
				//得到选择的路径，将其转换为数组处理。
				var pathDirectoryArr:Array = _file.nativePath.toString().split("\\");
				//去掉文件名。
				pathDirectoryArr.pop();
//				Alert.show(pathDirectoryArr.join("\\"));
				//将保存目录的路径保存到saveDirectoryPath变量中。
				saveDirectoryPath= pathDirectoryArr.join("\\");
				writeDataToImage();
			}
			//使用文件流生成截图。
			private function writeDataToImage():void
			{
				var filestream:FileStream=new FileStream();
				try{
					filestream.open(_file,FileMode.WRITE);
					filestream.writeBytes(_imgByteArray);
					filestream.close();	
				}catch(e:Error){
					Alert.show(e.message);
				}
			}
			//撤销按钮操作。
			protected function btn_cancel_clickHandler(event:MouseEvent):void
			{   
				if(pop1.indexList.length != 0 && pop1.indexList.length >= 0)
				{
					pop1.tempDel.addItem(pop1.indexList.getItemAt(pop1.indexList.length-1));
					myPanel.removeChild(pop1.indexList.getItemAt(pop1.indexList.length - 1) as DisplayObject);
					pop1.indexList.removeItemAt(pop1.indexList.length-1);
				}
			}
			
			//-----清空白板按钮操作--------
			protected function btn_reset_clickHandler(event:MouseEvent):void
			{
				myPanel.removeAllChildren();
				pop1.indexList.removeAll();
				pop1.tempDel.removeAll();
			}
			
			//------图形恢复按钮操作-------
			protected function btn_recovery_clickHandler(event:MouseEvent):void
			{
				
				if(pop1.tempDel.length!=0)
				{
					pop1.indexList.addItem(pop1.tempDel.getItemAt(pop1.tempDel.length-1))
					myPanel.addChild(pop1.tempDel.getItemAt(pop1.tempDel.length-1) as DisplayObject);
					pop1.tempDel.removeItemAt(pop1.tempDel.length-1);	  
				}
			}
			//绘图时，鼠标按下操作处理。
			private function downHandler(e:MouseEvent):void
			{
				_isDown=true;
				oX = myPanel.mouseX;
				oY = myPanel.mouseY;
				sprit=new Sprite();
			}
			//---------绘图时，鼠标释放操作处理。----------
			private function upHandler(e:MouseEvent):void
			{
				_isDown=false;
				oX=myPanel.mouseX;
				oY=myPanel.mouseY;
				var Num:Number=Number(myPanel.numChildren)-1;
				if(pop1.spriteFlag!="截屏")
				{
					if(Num>=0)
					{
						pop1.indexList.addItem(myPanel.getChildAt(myPanel.numChildren-1));
					}
				} else {
					//截屏操作只需要保存最后一个绘制上去的图形对象。
					PrObj=myPanel.getChildAt(myPanel.numChildren-1);
				}
			}
			//-----鼠标移动事件-----------
			private function moveHandler(e:MouseEvent):void
			{
				if(_isDown)
				{
					myPanel.graphics.lineStyle(pop1._lineSize,pop1._lineColor,1);
					
					//-----生成线-----------
					if(pop1.spriteFlag=="线"){
						
						sprit.graphics.lineStyle(pop1._lineSize,pop1._lineColor,1);//应用线条样式
						sprit.graphics.beginFill(0xffffff,1);//图的内部填充
						var x:Number = myPanel.mouseX;
						var y:Number = myPanel.mouseY;
						sprit.graphics.moveTo(oX,oY);
						sprit.graphics.lineTo(x,y);
						var uiCom:UIComponent=new UIComponent();
						uiCom.addChild(sprit);
						myPanel.addChild(uiCom);
						oX=x;
						oY=y;
					}
					//---生成圆--------					
					if(pop1.spriteFlag=="圆"){
						
						sprit.graphics.clear();
						sprit.graphics.lineStyle(pop1._lineSize,pop1._lineColor,1);
						sprit.graphics.beginFill(pop1._fillColor,pop1._fillAlpha);
						
						nX = myPanel.mouseX;
						nY = myPanel.mouseY;
						
						var cX:Number=oX+(nX-oX)/2;
						var cY:Number=oY+(nY-oY)/2;
						var preX:Number  =Math.min(oX,nX);
						var preY:Number  =Math.min(oY,nY);
						var cWidth:Number = Math.abs(oX - nX);
						var cHeight:Number  = Math.abs(oY- nY);
						sprit.graphics.drawEllipse(preX,preY,cWidth,cHeight);
						var uiCom:UIComponent = new UIComponent();
						uiCom.addChild(sprit);
						myPanel.addChild(uiCom);
					}
					//----------生成矩形-------------
					if(pop1.spriteFlag=="矩形"){
						sprit.graphics.clear();
						
						sprit.graphics.lineStyle(pop1._lineSize,pop1._lineColor,1);
						sprit.graphics.beginFill(pop1._fillColor,pop1._fillAlpha);
						nX=myPanel.mouseX;
						nY=myPanel.mouseY;
						sprit.graphics.drawRect(oX,oY,nX-oX,nY-oY);
						var uiCom:UIComponent = new UIComponent();
						uiCom.addChild(sprit);
						myPanel.addChild(uiCom);
					}
					//----------生成截屏区域-------------
					if(pop1.spriteFlag=="截屏"){
						//sprit=new Sprite();
						
						sprit.graphics.clear();
						sprit.graphics.lineStyle(pop1._lineSize,pop1._lineColor,1);
						sprit.graphics.beginFill(pop1._fillColor,pop1._fillAlpha);
						nX=myPanel.mouseX;
						nY=myPanel.mouseY;
						sprit.graphics.drawRect(oX,oY,nX-oX,nY-oY);
						comUI.addChild(sprit);
						comUI.width=sprit.width;
						comUI.height=sprit.height;
						myPanel.addChild(comUI);
					}
				}
			}
			
			//----------移出浮动窗-------
			private function moveImage(event:MouseEvent):void {
				myMoveIn.play();	
			}
			//----------移走浮动窗------
			private function moveout(event:MouseEvent):void{
				myMoveOut.play();
			}
		]]>
	</mx:Script>
	<mx:DateFormatter id="df" formatString="YYYY-MM-DD JJ-NN-SS"/>
	<mx:Move id="myMoveIn" target="{pop1}" duration="300" yTo="0" />
	<mx:Move id="myMoveOut" target="{pop1}" duration="300" yTo="-230" />

	<mx:Canvas width="100%" height="100%" id="myPanel" borderStyle="solid" fontSize="12" backgroundSize="100%">
		
	</mx:Canvas>
</mx:WindowedApplication>

 

设置面板ConsolePanel.mxml

<?xml version="1.0" encoding="utf-8"?>

<mx:TitleWindow xmlns:mx="http://www.adobe.com/2006/mxml"
				width="500"  height="242" fontSize="12"
				creationComplete="canvas1_creationCompleteHandler(event)" alpha="1">
	<mx:Script>
		<![CDATA[
			import mx.binding.utils.BindingUtils;
			import mx.collections.ArrayCollection;
			import mx.controls.Alert;
			import mx.events.CollectionEvent;
			import mx.events.FlexEvent;
			import mx.utils.ColorUtil;
			import mx.utils.StringUtil;
			[Bindable] 
			public var _lineSize:int=1;
			[Bindable] 
			public var _lineColor:uint=0x000000;
			[Bindable] 
			public var _fillAlpha:Number=0;
			[Bindable] 
			public var _fillColor:uint=0xffffff;
			private var _changeLineFlag:Boolean = false;
			private var _changeFillFlag:Boolean = false;
			public var spriteFlag:String="线";
			public var indexList:ArrayCollection=new ArrayCollection();//myPanel显示对象
			public var tempDel:ArrayCollection=new ArrayCollection();//临时删除对象

			
			private function canvas1_creationCompleteHandler(event:FlexEvent):void
			{				
				BindingUtils.bindProperty(this,"_lineSize",hs,"value");
				BindingUtils.bindProperty(this,"_fillAlpha",fillalpha,"value");
				indexList.addEventListener(CollectionEvent.COLLECTION_CHANGE,listChange);
				tempDel.addEventListener(CollectionEvent.COLLECTION_CHANGE,tempDelChange);
			}
			private function listChange(evt:CollectionEvent):void
			{
				if(indexList.length==0)
				{
					btn_cancel.enabled=false;
					btn_reset.enabled=false;
				}
				else
				{
					btn_cancel.enabled=true;
					btn_reset.enabled=true;
				}
			}
			private function tempDelChange(evt:CollectionEvent):void
			{
				if(tempDel.length==0)
				{
					btn_recovery.enabled=false;
				}
				else
				{
					btn_recovery.enabled=true;
				}
			}
			//设置线条颜色和填充颜色时，例如设置线条颜色，需要首先点击线条颜色方块，在点击下方八个颜色方块中的任意一色，可更换线条颜色。
			private function changeColor(event:MouseEvent):void
			{
				var colorValue:uint = (event.target as GridItem).getStyle("backgroundColor");
//				Alert.show("_changeLineFlag :"+_changeLineFlag +"   _changeFillFlag : "+_changeFillFlag+"  colorValue:"+colorValue);
				if (_changeLineFlag) {
					_lineColor = colorValue;
				} 
				if (_changeFillFlag) {
					_fillColor = colorValue;
				}
			}
		]]>
	</mx:Script>
	<mx:Canvas id="spritPanelBox" width="100%" height="100%" backgroundColor="#5599AA" alpha="0.6">
		<mx:Canvas id="chooseBox" width="472" height="194" x="0" y="0">
			
			<mx:Label text="线条色" fontWeight="bold" x="10" y="18"/>
			<mx:Label text="填充色" fontWeight="bold" x="129" y="18"/>
			
			<mx:Button label="椭圆" id="circle" icon="@Embed(source='img/圆.png')" click="this.spriteFlag='圆';" width="75.2" x="242.8" y="82"/>
			<mx:Button label="线" id="line"  icon="@Embed(source='img/线 .png')" click="this.spriteFlag='线';" width="75.2" x="242.75" y="14"/>
			<mx:Button label="矩形" id="rect" icon="@Embed(source='img/矩形.png')" click="this.spriteFlag='矩形'" width="75.2" x="242.8" y="48"/>
			
			<mx:Button label="截屏" id="prScrn" icon="@Embed(source='img/截屏.png')" x="410" y="39" labelPlacement="bottom"/>
			<mx:Button label="撤消" id="btn_cancel" icon="@Embed(source='img/撤销.png')" enabled="false"  x="326" y="14"/>
			<mx:Button label="清除" id="btn_reset" icon="@Embed(source='img/清除.png')" enabled="false"  x="326" y="48"/>
			<mx:Button label="恢复" id="btn_recovery" icon="@Embed(source='img/恢复.png')" enabled="false" width="77.5" x="326" y="82"/>
			<mx:HBox width="100%" horizontalGap="23" verticalGap="0"  x="0" y="148" height="39">
				<mx:VBox verticalGap="0" width="229" height="39">
					<mx:HSlider  id="hs" value="{_lineSize}" minimum="1" maximum="20" snapInterval="1" tickInterval="1" liveDragging="true"/>
					<mx:Label id="lb_lineSize" text="笔刷大小：{hs.value}px"/>
				</mx:VBox>
				<mx:VBox verticalGap="0" height="39">
					<mx:HSlider  id="fillalpha"  value="{_fillAlpha}" minimum="0" maximum="1" tickInterval="0.1" snapInterval="0.1" liveDragging="true"/>
					<mx:Label id="lb_fillAlpha" text="填充区透明度：{fillalpha.value}"/>
				</mx:VBox>
			</mx:HBox>
			<mx:HRule x="0" y="136" width="462" height="1"/>
			<mx:TextInput id="fillColor" x="180" y="16" width="30" height="25" backgroundColor="{_fillColor}" focusRect="false" editable="false"  focusIn="_changeFillFlag = true;" focusOut="_changeFillFlag = false;"/>
			<mx:TextInput id="lineColor" x="62" y="16" width="30" height="25" backgroundColor="{_lineColor}" focusRect="false" editable="false" focusIn="_changeLineFlag = true;" focusOut="_changeLineFlag = false;"/>
			<mx:Grid x="10" y="46" width="224.8" height="73">
				<mx:GridRow width="100%" height="100%">
					<mx:GridItem width="100%" height="100%" backgroundColor="black" click="changeColor(event)">
					</mx:GridItem>
					<mx:GridItem width="100%" height="100%" backgroundColor="white" click="changeColor(event)">
					</mx:GridItem>
					<mx:GridItem width="100%" height="100%" backgroundColor="gray" click="changeColor(event)">
					</mx:GridItem>
					<mx:GridItem width="100%" height="100%" backgroundColor="yellow" click="changeColor(event)">
					</mx:GridItem>
				</mx:GridRow>
				<mx:GridRow width="100%" height="100%">
					<mx:GridItem width="100%" height="100%" backgroundColor="purple" click="changeColor(event)">
					</mx:GridItem>
					<mx:GridItem width="100%" height="100%" backgroundColor="red" click="changeColor(event)">
					</mx:GridItem>
					<mx:GridItem width="100%" height="100%" backgroundColor="green" click="changeColor(event)">
					</mx:GridItem>
					<mx:GridItem width="100%" height="100%" backgroundColor="blue" click="changeColor(event)">
					</mx:GridItem>
				</mx:GridRow>
			</mx:Grid>
		</mx:Canvas>
	</mx:Canvas>
</mx:TitleWindow>
 

 

 

 

 

zorrolg
关注
Flex桌面程序开发记录
qige8888的博客
08-21 225
1. 警告框中使用中文按钮：   Alert.yesLabel = "是"; Alert.noLabel = "否"; Alert.cancelLabel = "取消"; 2. 日期选择输入框相关属性设置：   nianling=new DateField; nianling.dayNames=['日','一','二','三','四','五','六']; nianling.mon...
Flex构建Android和iOS应用程序视频教程
07-23
资源名称：Flex构建Android和iOS应用程序视频教程资源目录：【】00Introduction【】01GettingStartedwithFlexandAndroid【】03UnderstandingtheArchitectureofaFlexMobileApp【】04UtilizingMobileComponents【】05...
电子画板程序
03-28
程序完整没有错误include"..\ucos-ii\includes.h" /* uC/OS interface */ #include "..\ucos-ii\add\osaddition.h" #include "..\inc\drv.h" #include "..\inc\drv\tchscr.h" #include #include #pragma import(__use_no_semihosting_swi) // ensure no functions that use semihosting //const U32 Line_Button_ID=100; //const U32 Circle_Button_ID=101; //const U32 Curve_Button_ID=102; //const U32 Clear_Button_ID=103; //const U32 Draw_Wnd_ID=104; #define Line_Button_ID 100 #define Circle_Button_ID 101 #define Curve_Button_ID 102 #define Clear_Button_ID 103 #define Draw_Wnd_ID 104
FLEX画图板，很难找到的哦
flyhighwl的博客
01-09 99
&lt;?xml version="1.0" encoding="utf-8"?&gt; &lt;mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="vertical" creationComplete="init()"&gt; &lt;mx:Script&gt; &lt;![
将应用程序从Flex 3迁移至Flex 4(转载)
weixin_30633507的博客
11-01 138
在本指南中，我将介绍如何将一个实际应用程序从 Flex 3 迁移至 Flex 4。文中提供的示例涵盖了 Flex 应用程序开发的所有重要领域，包括 CSS、Spark 组件、自定义外观、嵌入字体等。 在您自己动手之转换之前，这看起来好像是一项艰巨的任务。如果您阅读了本指南之后，您就会发现Flex 4在组件架构、CSS改进、新状态机制和新图形标记语言FXG等各方面的优势。MX组件的向后兼容性和F...
Flex 开源的画图板程序
yuanpan的专栏
11-06 3605
 Flex 开源的画图板程序 创建时间：2009年10月2日Flex 一个开源的画图板程序。很强大。http://www.nocircleno.com/graffiti/examples/drawing_app_1_2/列举了很多关于Flex flash的开源代码及资料http://www.zengrong.net/?page_id=48
Flex Google Map桌面地图应用程序
06-27
7. **API集成**：作为Flex应用，它可能利用了Google Maps API来获取和处理地图数据，同时也可能与其他Google服务（如Geocoding API或Places API）进行集成。 8. **性能优化**：Flex通常比HTML5更擅长处理复杂的图形...
Flex4：开发RIA应用程序
01-24
- 桌面部署：使用Adobe AIR技术，Flex应用程序可被转换成桌面应用，通过桌面运行。 7. Flex开发流程： - 设计和规划：确定应用需求，设计用户界面和交互流程。 - 编写代码：使用MXML和ActionScript开发应用程序的...
将Flex集成到JavaEE应用程序的最佳实践
03-02
开发环境现有的JavaEE应用集成BlazeDS开发Flex客户端增强RemoteObject对象下载参考资料传统的JavaEE应用程序通常使用某种MVC框架（例如，Struts）作为前端用户界面，随着Flex的兴起，基于RIA的客户端能够给用户带来...
flexx：用纯Python编写桌面和Web应用程序
02-05
Flexx 是否想了解有关Flexx（更改）的最新信息？ 订阅。 介绍 是用于创建图形用户界面（GUI）的纯Python工具箱，该工具箱使用Web技术进行呈现。 应用程序完全是用Python编写的； 即时生成必要JavaScript。 您可以使用Flexx创建（跨平台）桌面应用程序，Web应用程序，并将应用程序导出到独立HTML文档中。 它也可以在Jupyter笔记本中使用。 该文档位于。 代码在。 例 单击下面的图像为交互式示例： 在有一个演示服务器。 动机 Flexx的主要动机是不可否认的事实，即Web（即浏览器技术）已成为一种越来越流行的方法，用于向用户交付应用程序以及（交互式）
使用Flex开发Adobe AIR程序--桌面快捷方式管理器
01-21
使用Flex开发Adobe AIR程序--桌面快捷方式管理器,适合新手进一步熟悉api，遇到典型的问题，1）调用外部exe文件，2）打包，3）读写文件，路径问题，...
flex画板简单版
04-29
使用鼠标画线条,调节线条粗细,颜色,笔触形状,透明度,空置了一个工具窗口,你可以自己往里面添加工具.
flex画图板实例 源码
07-30
flex画图板实例 源码 flex画图板实例 源码 flex画图板实例 源码 flex画图板实例 源码flex画图板实例 源码
Flex画板实现～
03-20
NULL 博文链接：https://rwl6813021.iteye.com/blog/786046
Flex【原创】Air桌面应用程序最小化托盘
weixin_30387339的博客
07-17 215
如题:Air桌面应用程序最小化托盘功能实现 1.核心类 : 处理最小化托盘的逻辑 package { import flash.desktop.NativeApplication; import flash.desktop.SystemTrayIcon; import flash.display.BitmapData; import fla...
Flex4.0画板
alshow
05-16 139
myPanel.width){ return; } if(mY+r>myPanel.height){ return; } var y1:Number=Math.abs(y-mY); myPanel.contentGroup.graphics.lineStyle(xianti...
Flex桌面程序(入门)之绘制一个移动的圆
weixin_30413739的博客
02-27 82
package { import flash.display.Shape; import flash.display.Sprite; import flash.events.Event; [SWF(width="400", height="300", frameRate="30")] public class MyDemo extends Sprite { p...
Flex4中使用Path实现画板功能，解决恢复，撤消问题
weixin_34343000的博客
07-18 85
近期需要做一个画板的功能，又鉴于SDK3.0的例子，现在都用SDK4.0在开发了，3.0里实现的一些在4.0里并不适合使用；找了很多相关的资料，也不基于Path实现画板功能；最近在官方网上看找到一些资料，拿出来分享一下；再也不用纠结于 多条lineTo, 难解决操作记录的问题，尤其在解决恢复，撤消问题；不多说，贴上代码：<?xmlversion="1.0"encoding="ut...
使用Flex 3开发AIR 1.5应用程序官方指南
5. **部署和打包**: 文档会指导开发者如何将Flex应用打包成AIR应用程序，以便在用户计算机上安装和运行。 6. **调试和测试**: 如何使用Flex Builder的内置工具进行代码调试，以及如何在不同操作系统和版本的AIR环境...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值