操作系统实验好难——系统引导

http://blog.sina.com.cn/s/blog_4b3646350100an8k.html


实验目的

  • 建立对操作系统引导过程的深入认识;
  • 掌握操作系统的基本开发过程;
  • 能对操作系统进行简单的控制,揭开操作系统的神秘面纱。

实验内容

此次实验的基本内容是:编写一个放入引导扇区的操作系统引导程序bootsect.s,和一个进入保护模式前的设置程序setup.s,并将该bootsect.s和setup.s编译后在Bochs中运行,进行实验。

编写的引导程序bootsect.s和setup.s主要完成如下三个部分的功能:

  1. bootsect.s能在屏幕上打印一段提示信息“XXX is booting...”,其中XXX是你给自己的操作系统起的名字,例如LZJos、Sunix等(可以上论坛上秀秀谁的OS名字最帅)。(实验者也可以 做一个特色logo并显示在屏幕上,以表示自己操作系统的与众不同,当然这要花费一定的时间,也不属于加分内容,鼓励大家在将来有时间的时候做一下。)
  2. bootsect.s能完成setup.s的载入,并跳转到setup.s开始地址执行。而setup.s向屏幕输出一行“Now we are in SETUP”。
  3. setup.s能获取基本的硬件参数(如内存参数、显卡参数、硬盘参数等,在本实验中只要获取一个参数就取分,获取多个参数不加分,但后面的实验中会用到 某些参数,如实验六的终端设备需要显卡的参数,所以在将来需要的时候能再回来修改),将这些参数放在内存的特定地址,留着将来使用,并输出到屏幕上。

实验报告

完成实验后,在实验报告中回答如下问题:

  1. 你觉得boot的过程复杂吗?为什么?
  2. 摒弃一切清规戒律,尝试设计一个更简洁的boot过程

评分标准

  • bootsect显示正确,15%
  • bootsect正确读入setup,15%
  • setup显示正确,10%
  • setup获取硬件参数正确,15%
  • setup正确显示硬件参数,15%
  • tools/build.c修改正确,10%
  • 实验报告,20%

实验提示

操作系统的boot代码有很多,并且大部分是相似的,所以可以仿照这些代码编写。本实验将仿照Linux-0.11/boot目录下的bootsect.s和setup.s进行,以剪裁它们为主线。当然,如果能完全从头编写来实现实验所要求的功能是再好不过了。

同济大学赵炯博士的《Linux内核0.11完全注释》一书的第3章是非常有帮助的参考,可以在“资料和文件下载”中下载到电子版。实验中可能遇到的各种问题,在这里几乎都能找到答案。校友谢煜波撰写的《操作系统引导探究》也是一份很好的参考。

需要注意的是,Linux的汇编代码使用AS86编译,语法上和我们在汇编课上所学的汇编稍有不同,请注意观察。

下面将给出一些更具体的“提示”,没自信者要认真阅读,强者可忽略它们,牛人向后转去找更肥的草吧。鬼脸

Linux 0.11相关代码详解

boot/bootsect.s、boot/setup.s和tools/build.c是本实验会涉及到的程序。它们的功能详见《Linux内核0.11完全注释》的3.3、3.4和13.2节。

如果使用Windows下的环境,那么要注意Windows环境里提供的build.c是一个经过修改过的版本。Linus Torvalds的原版是将0.11内核的最终目标代码输出到标准输出,由make程序将数据重定向到Image文件,这在Linux、Unix和 Minix等系统下都是非常有效的。但Windows本身的缺陷(也许是特色)决定了在Windows下不能这么做,所以flyfish修改了 build.c,将输出直接写入到Image(flyfish是写入到Boot.img文件,我们为了两个环境的一致,也为了最大化地与原始版本保持统 一,将其改为Image)文件中。同时为了适应Windows下的一些特殊情况,他还做了一些其它小的修改。

完成bootsect.s的屏幕输出功能

首先来看完成屏幕显示的关键代码如下:

    ! 首先读入光标位置

    mov    ah,#0x03                

    xor     bh,bh

    int        0x10



    ! 显示字符串“LZJos is running...”

    mov cx,#25                  ! 要显示的字符串长度

    mov  bx,#0x0007              ! page 0, attribute 7 (normal)

    mov       bp,#msg1

    mov     ax,#0x1301              ! write string, move cursor

    int  0x10



inf_loop:

    jmp        inf_loop                ! 后面都不是正经代码了,得往回跳呀

    ! msg1处放置字符串



msg1:

    .byte 13,10                  ! 换行+回车

    .ascii "LZJos is running..."

    .byte 13,10,13,10                    ! 两对换行+回车

    !设置引导扇区标记0xAA55

    .org 510

boot_flag:

    .word 0xAA55                      ! 必须有它,才能引导

接下来,将完成屏幕显示的代码在开发环境中编译,并使用linux-0.11/tools/build.c将编译后的目标文件做成Image文件。

编译和运行

Ubuntu上先从终端进入~/oslab/linux-0.11/boot/目录。Windows上则先双击快捷方式“MinGW32.bat”,将打开一个命令行窗口,当前目录是oslab。无论那种系统,都执行下面两个命令:

as86 -0 -a -o bootsect.o bootsect.s

ld86 -0 -s -o bootsect bootsect.o

其中-0(注意:这是数字0,不是字母O)表示生成8086的16位目标程序,-a表示生成与GNU as和ld部分兼容的代码,-s告诉链接器ld86去除最后生成的可执行文件中的符号信息。

如果这两个命令没有任何输出,说明编译与链接都通过了。Ubuntu下用ls -l可列出下面的信息:

-rw--x--x    1  root  root  544  Jul  25  15:07   bootsect

-rw------    1  root  root  257  Jul  25  15:07   bootsect.o

-rw------    1  root  root  686  Jul  25  14:28   bootsect.s

Windows下用dir可列出下面的信息:

2008-07-28  20:14               544 bootsect

2008-07-28  20:14               924 bootsect.o

2008-07-26  20:13             5,059 bootsect.s

其中bootsect.o是中间文件,没有用处。bootsect是编译、链接后的目标文件。

需要留意的文件是bootsect的文件大小是544字节,而引导程序必须要正好占用一个磁盘扇区,即512个字节。造成多了32个字节的原因是ld86 产生的是Minix可执行文件格式,这样的可执行文件处理文本段、数据段等部分以外,还包括一个Minix可执行文件头部,它的结构如下:

struct exec {

    unsigned char a_magic[2];  //执行文件魔数

    unsigned char a_flags;

    unsigned char a_cpu;       //CPU标识号

    unsigned char a_hdrlen;    //头部长度,32字节或48字节

    unsigned char a_unused;

    unsigned short a_version;

    long a_text; long a_data; long a_bss; //代码段长度、数据段长度、堆长度

    long a_entry;    //执行入口地址

    long a_total;    //分配的内存总量

    long a_syms;     //符号表大小 

};

算一算:6 char(6字节)+1 short(2字节)+6 long(24字节)=32,正好是32个字节,去掉这32个字节后就可以放入引导扇区了(这是tools/build.c的用途之一)。

对于上面的Minix可执行文件,其a_magic[0]=0x01,a_magic[1]=0x03,a_flags=0x10(可执行文件),a_cpu=0x04(表示Intel i8086/8088,如果是0x17则表示Sun公司的SPARC),所以bootsect文件的头几个字节应该是01 03 10 04。为了验证一下,Ubuntu下用命令“hexdump -C bootsect”可以看到:

00000000  01 03 10 04 20 00 00 00  00 02 00 00 00 00 00 00  |.... ...........|

00000010  00 00 00 00 00 00 00 00  00 82 00 00 00 00 00 00  |................|

00000020  b8 c0 07 8e d8 8e c0 b4  03 30 ff cd 10 b9 17 00  |.........0......|

00000030  bb 07 00 bd 3f 00 b8 01  13 cd 10 b8 00 90 8e c0  |....?...........|

00000040  ba 00 00 b9 02 00 bb 00  02 b8 04 02 cd 13 73 0a  |..............s.|

00000050  ba 00 00 b8 00 00 cd 13  eb e1 ea 00 00 20 90 0d  |............. ..|

00000060  0a 53 75 6e 69 78 20 69  73 20 72 75 6e 6e 69 6e  |.Sunix is runnin|

00000070  67 21 0d 0a 0d 0a 00 00  00 00 00 00 00 00 00 00  |g!..............|

00000080  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  |................|

*

00000210  00 00 00 00 00 00 00 00  00 00 00 00 00 00 55 aa  |..............U.|

00000220

Windows下用UltraEdit把该文件打开,果然如此。

图1 用UltraEdit打开文件bootsect


接下来干什么呢?是的,要去掉这32个字节的文件头部(tools/build.c的功能之一就是这个)!随手编个小的文件读写程序都可以去掉它。不过,懒且聪明的人会在Ubuntu下用命令:

$ dd bs=1 if=bootsect of=Image skip=32

生成的Image就是去掉文件头的bootsect。

Windows下可以用UltraEdit直接删除(选中这32个字节,然后按Ctrl+X)。

去掉这32个字节后,将生成的文件拷贝到linux-0.11目录下,并一定要命名为“Image”(注意大小写)。然后就“run”吧!

图2 bootsect引导后的系统启动情况


bootsect.s读入setup.s

首先编写一个setup.s,该setup.s可以就直接拷贝前面的bootsect.s(可能还需要简单的调整),然后将其中的显示的信息改为:“Now we are in SETUP”。

接下来需要编写bootsect.s中载入setup.s的关键代码。原版bootsect.s中下面的代码就是做这个的。

load_setup:

    mov       dx,#0x0000              !设置驱动器和磁头(drive 0, head 0): 软盘0磁头

    mov    cx,#0x0002              !设置扇区号和磁道(sector 2, track 0):0磁头、0磁道、2扇区

    mov     bx,#0x0200              !设置读入的内存地址:BOOTSEG+address = 512,偏移512字节

    mov     ax,#0x0200+SETUPLEN     !设置读入的扇区个数(service 2, nr of sectors),

                                       !SETUPLEN是读入的扇区个数,Linux 0.11设置的是4,

                                  !我们不需要那么多,我们设置为2

    int     0x13                    !应用0x13号BIOS中断读入2个setup.s扇区

    jnc  ok_load_setup           !读入成功,跳转到ok_load_setup: ok - continue

    mov        dx,#0x0000              !软驱、软盘有问题才会执行到这里。我们的镜像文件比它们可靠多了

    mov      ax,#0x0000              !否则复位软驱 reset the diskette

    int   0x13

    jmp load_setup              !重新循环,再次尝试读取

ok_load_setup:

    !接下来要干什么?当然是跳到setup执行。

所有需要的功能在原版bootsect.s中都是存在的,我们要做的仅仅是删除那些对我们无用的代码。

再次编译

现在有两个文件都要编译、链接。一个个手工编译,效率低下,所以借助Makefile是最佳方式。

在Ubuntu下,进入linux-0.11目录后,使用下面命令(注意大小写):

$ make BootImage

Windows下,在命令行方式,进入Linux-0.11目录后,使用同样的命令(不需注意大小写):

make BootImage

无论哪种系统,都会看到:

Unable to open 'system'

make: *** [BootImage] Error 1

有Error!这是因为make根据Makefile的指引执行了tools/build.c,它是为生成整个内核的镜像文件而设计的,没考虑我们只需要bootsect.s和setup.s的情况。它在向我们要“系统”的核心代码。为完成实验,接下来给它打个小补丁。

修改build.c

build.c从命令行参数得到bootsect、setup和system内核的文件名,将三者做简单的整理后一起写入Image。其中system是第三个参数(argv[3])。当“make all”或者“makeall”的时候,这个参数传过来的是正确的文件名,build.c会打开它,将内容写入Image。而“make BootImage”时,传过来的是字符串"none"。所以,改造build.c的思路就是当argv[3]是"none"的时候,只写bootsect和setup,忽略所有与system有关的工作,或者在该写system的位置都写上“0”。

修改工作主要集中在build.c的尾部,请斟酌。

当按照前一节所讲的编译方法编译成功后,run,就得到了如图3所示的运行结果,和我们想得到的结果完全一样。

图3 用修改后的bootsect.s和setup.s进行引导的结果


setup.s获取基本硬件参数

setup.s将获得硬件参数放在内存的0x90000处。原版setup.s中已经完成了光标位置、内存大小、显存大小、显卡参数、第一和第二硬盘参数的保存。

用ah=#0x03调用0x10中断可以读出光标的位置,用ah=#0x88调用0x15中断可以读出内存的大小。有些硬件参数的获取要稍微复杂一些,如磁盘参数表。在PC机中BIOS设定的中断向量表中int 0x41的中断向量位置(4*0x41 = 0x0000:0x0104)存放的并不是中断程序的地址,而是第一个硬盘的基本参数表。第二个硬盘的基本参数表入口地址存于int 0x46中断向量位置处。每个硬盘参数表有16个字节大小。下表给出了硬盘基本参数表的内容:

表1 磁盘基本参数表

位移 大小 说明
0x00 柱面数
0x02 字节 磁头数
0x0E 字节 每磁道扇区数
0x0F 字节 保留

所以获得磁盘参数的方法就是复制数据。

下面是将硬件参数取出来放在内存0x90000的关键代码。

mov        ax,#INITSEG     

mov ds,ax !设置ds=0x9000

mov       ah,#0x03        !读入光标位置

xor  bh,bh

int    0x10            !调用0x10中断

mov        [0],dx          !将光标位置写入0x90000.



!读入内存大小位置

mov        ah,#0x88

int 0x15

mov     [2],ax



!从0x41处拷贝16个字节(磁盘参数表)

mov      ax,#0x0000

mov       ds,ax

lds    si,[4*0x41]

mov      ax,#INITSEG

mov      es,ax

mov    di,#0x0004

mov       cx,#0x10

rep                 !重复16次

movsb

现在已经将硬件参数(只包括光标位置、内存大小和硬盘参数,其他硬件参数取出的方法基本相同,此处略去)取出来放在了0x90000处,接下来的工作是将这些参数显示在屏幕上。这些参数都是一些无符号整数,所以需要做的主要工作是用汇编程序在屏幕上将这些整数显示出来。

以十六进制方式显示比较简单。这是因为十六进制与二进制有很好的对应关系(每4位二进制数和1位十六进制数存在一一对应关系),显示时只需将原二进制数每 4位划成一组,按组求对应的ASCII码送显示器即可。ASCII码与十六进制数字的对应关系为:0x30~0x39对应数字0~9,0x41~0x46 对应数字a~f。从数字9到a,其ASCII码间隔了7h,这一点在转换时要特别注意。为使一个十六进制数能按高位到低位依次显示,实际编程中,需对bx 中的数每次循环左移一组(4位二进制),然后屏蔽掉当前高12位,对当前余下的4位(即1位十六进制数)求其ASCII码,要判断它是0~9还是a~f, 是前者则加0x30得对应的ASCII码,后者则要加0x37才行,最后送显示器输出。以上步骤重复4次,就可以完成bx中数以4位十六进制的形式显示出 来。

下面是完成显示16进制数的汇编语言程序的关键代码,其中用到的BIOS中断为INT 0x10,功能号0x0E(显示一个字符),即AH=0x0E,AL=要显示字符的ASCII码。

!以16进制方式打印栈顶的16位数

print_hex:

    mov      cx,#4           ! 4个十六进制数字

    mov   dx,(bp)         ! 将(bp)所指的值放入dx中,如果bp是指向栈顶的话

print_digit:

    rol dx,#4           ! 循环以使低4比特用上 !! 取dx的高4比特移到低4比特处。

    mov     ax,#0xe0f       ! ah = 请求的功能值,al = 半字节(4个比特)掩码。

    and      al,dl           ! 取dl的低4比特值。

    add al,#0x30        ! 给al数字加上十六进制0x30

    cmp    al,#0x3a

    jl      outp            !是一个不大于十的数字

    add  al,#0x07        !是a~f,要多加7

outp: 

    int 0x10

    loop        print_digit

    ret

这里用到了一个loop指令,每次执行loop指令,cx减1,然后判断cx是否等于0。如果不为0则转移到loop指令后的标号处,实现循环;如果为0 顺序执行。另外还有一个非常相似的指令:rep指令,每次执行rep指令,cx减1,然后判断cx是否等于0,如果不为0则继续执行rep指令后的串操作 指令,直到cx为0,实现重复。

!打印回车换行

print_nl:

    mov ax,#0xe0d       ! CR

    int 0x10

    mov al,#0xa         ! LF

    int 0x10

    ret

只要在适当的位置调用print_bx和print_nl(注意,一定要设置好栈,才能进行函数调用)就能将获得硬件参数打印到屏幕上,完成此次实验的任 务。但事情往往并不总是顺利的,前面的两个实验大多数实验者可能一次就编译调试通过了(这里要提醒大家:编写操作系统的代码一定要认真,因为要调试操作系 统并不是一件很方便的事)。但在这个实验中会出现运行结果不对的情况(为什么呢?因为我们给的代码并不是100%好用的)。所以接下来要复习一下汇编,并 学学在Bochs中如何调试操作系统代码

我想经过漫长而痛苦的调试后,大家一定能兴奋地得到下面的运行结果:

图4 用可以打印硬件参数的setup.s进行引导的结果


Memory Size是0x3C00KB,算一算刚好是15MB(扩展内存),加上1MB正好是16MB,看看Bochs配置文件bochs/bochsrc.bxrc:

……

megs: 16

……

ata0-master: type=disk, mode=flat, cylinders=410, heads=16, spt=38

……

这些都和上面打出的参数吻合,表示此次实验是成功的。



++++++++++++++++++++++++++++++++++++++++++++++++++++++++

http://blog.sina.com.cn/s/blog_4b3646350100an8l.html

bootsect.s只是做了修改:

SYSSIZE = 0x3000
.globl begtext, begdata, begbss, endtext, enddata, endbss
.text
begtext:
.data
begdata:
.bss
begbss:
.text

SETUPLEN = 4    ! nr of setup-sectors
BOOTSEG  = 0x07c0   ! original address of boot-sector
INITSEG  = 0x9000   ! we move boot here - out of the way
SETUPSEG = 0x9020   ! setup starts here
SYSSEG   = 0x1000   ! system loaded at 0x10000 (65536).
ENDSEG   = SYSSEG + SYSSIZE  ! where to stop loading

ROOT_DEV = 0x306

entry _start
_start:
!-------------------------
 mov ax,#BOOTSEG
 mov ds,ax
 mov ax,#INITSEG
 mov es,ax
 mov cx,#256
 sub si,si
 sub di,di
 rep
 movw
 jmpi go,INITSEG
!---------------------------
go: mov ax,cs
 mov ds,ax
 mov es,ax
! put stack at 0x9ff00.
 mov ss,ax
 mov sp,#0xFF00  ! arbitrary value >>512

! load the setup-sectors directly after the bootblock.
! Note that 'es' is already set up.
!-----------------------------
load_setup:
 mov dx,#0x0000  ! drive 0, head 0
 mov cx,#0x0002  ! sector 2, track 0
 mov bx,#0x0200  ! address = 512, in INITSEG
 mov ax,#0x0200+SETUPLEN ! service 2, nr of sectors
 int 0x13   ! read it
 jnc ok_load_setup  ! ok - continue
 mov dx,#0x0000
 mov ax,#0x0000  ! reset the diskette
 int 0x13
 j load_setup
!---------------------------
ok_load_setup:

! Print some inane message

 mov ah,#0x03  ! read cursor pos
 xor bh,bh
 int 0x10

 mov cx,#29
 mov bx,#0x0007  ! page 0, attribute 7 (normal)
 mov bp,#msg1
 mov ax,#0x1301  ! write string, move cursor
 int 0x10


 jmpi 0,SETUPSEG

msg1:
 .byte 13,10
 .ascii "Kerberos is Loading ..."
 .byte 13,10,13,10

.org 508
root_dev:
 .word ROOT_DEV
boot_flag:
 .word 0xAA55

.text
endtext:
.data
enddata:
.bss
endbss:
setup.s也只是修改了一下:

INITSEG  = 0x9000 ! we move boot here - out of the way
SYSSEG   = 0x1000 ! system loaded at 0x10000 (65536).
SETUPSEG = 0x9020 ! this is the current segment

.globl begtext, begdata, begbss, endtext, enddata, endbss
.text
begtext:
.data
begdata:
.bss
begbss:
.text

entry start
start:
! -------打印字符串----------------
 mov ax,cs;
 mov ds,ax;
 mov es,ax;
!--------代码段与数据段、附加段在一个位置--------
 mov ah,#0x03  ! read cursor pos
 xor bh,bh
 int 0x10
 
 mov cx,#22
 mov bx,#0x0007  ! page 0, attribute 7 (normal)
 mov bp,#msg1
 mov ax,#0x1301  ! write string, move cursor
 int 0x10

!--------打印光标位置---------------

 mov ax,#INITSEG ! this is done in bootsect already, but...
 mov ds,ax
 mov ah,#0x03 ! read cursor pos
 xor bh,bh
 int 0x10  ! save it in known place, con_init fetches
 mov [0],dx  ! it from 0x90000.

 mov cx,#13
 mov bx,#0x0007  ! page 0, attribute 7 (normal)
 mov bp,#cursor1
 mov ax,#0x1301  ! write string, move cursor
 int 0x10
  
!----------调用函数用数字打印------------
 push [0]
 call print_hex
 call print_nl
 pop [0];
 
!----------打印内存信息-------------------------- 
! Get memory size (extended mem, kB)
 mov ah,#0x03  ! read cursor pos
 xor bh,bh
 int 0x10
 
 mov cx,#14
 mov bx,#0x0007  ! page 0, attribute 7 (normal)
 mov bp,#memory
 mov ax,#0x1301  ! write string, move cursor
 int 0x10
 
 mov ah,#0x88
 int 0x15
 mov [2],ax
 
 push [2]
 call print_hex
 mov ax,#0xe4b   !K
 int 0x10
 mov al,#0x42   !B
 int 0x10
 call print_nl
 pop [0];
!----------------------------
msg1:
 .ascii "Ahh! I'm in SETUP..."
 .byte 13,10
cursor1:
 .byte 13,10
 .ascii "Cursor Pos:"
memory:
 .byte 13,10
 .ascii "Memory Size:"
!--------将16进制输出到屏幕上的函数----------------
print_hex:
 mov bp,sp;
 add bp,#2;
 mov dx,(bp)  ! 将(bp)所指的值放入dx中,如果bp是指向栈顶的话
 mov cx,#4   ! 4个十六进制数字
print_digit:
 rol dx,#4   ! 循环以使低4比特用上 !! 取dx的高4比特移到低4比特处。  
  mov ax,#0xe0f  ! ah = 请求的功能值,al = 半字节(4个比特)掩码。  
  and al,dl   ! 取dl的低4比特值。
  add al,#0x30  ! 给al数字加上十六进制0x30   
  cmp al,#0x3a
  jl outp    !是一个不大于十的数字   
  add al,#0x07   !是a~f,要多加7
outp:
 int 0x10   
 loop print_digit   
 ret
 
!打印回车换行
print_nl:
 mov ax,#0xe0d  ! CR
 int 0x10
 mov al,#0xa  ! LF   
 int 0x10
 ret

.text
endtext:
.data
enddata:
.bss
endbss

以上代码仅供参看,水平有限,研究成果,不提倡摘抄,可以研究,不供投机用,谢谢合作!


<script>window._bd_share_config={"common":{"bdSnsKey":{},"bdText":"","bdMini":"2","bdMiniList":false,"bdPic":"","bdStyle":"0","bdSize":"16"},"share":{}};with(document)0[(getElementsByTagName('head')[0]||body).appendChild(createElement('script')).src='http://bdimg.share.baidu.com/static/api/js/share.js?v=89860593.js?cdnversion='+~(-new Date()/36e5)];</script>
阅读(825) | 评论(0) | 转发(1) |
给主人留下些什么吧!~~
评论热议
已标记关键词 清除标记
相关推荐
Linux是一个多任务、多用户的操作系统,它以其良好的特性和资源的免费性而得到了蓬勃的发展。  本书通过大量的图示和实例,深入浅出的介绍了Linux的基本原理和应用。主要包括Linux的基本概念和操作,Linux的树型结构,Linux的文本编辑,Linux的安装和启动,用户管理,Shell编程技术,进程管理,C编译器,系统扩充,维护与监视,Linux的图形界面,网络的基本概念与设置,Linux在网络资源共享和电子邮件方面的应用,以及DNS、FTP、Web和Proxy服务器等内容。  本书可作为Linux操作系统课程的教材,也可作为电脑爱好者,相关技术人员及参加Linux认证考试人士的参考书。 一、关于Linux Linux是一个正在蓬勃发展的极富生命力的操作系统。芬兰青年Linus Torvalds和其杰作的传奇故事吸引了无数的电脑爱好者尝试去使用Linux,但他们中的大多数人却被Unix类操作系统传统的枯燥的字符界面、艰涩懂的操作命令和数量庞大的基本概念以及基础知识所吓退。Linux在这几年中迅速地发展,Turbo Linux宣布该公司已经开始盈利了,这说明了Linux正在逐渐大众化。在未来的几年中,Linux在各行各业中的应用将遍地开花,能熟练操作Linux将是每一个系统管理员所需掌握的基本技能。 曾经有一种说法:能熟练操作Linux的人,必定是电脑业界的顶尖高手。本书正是为改变这一种看法而面世的,它主要面向那些对电脑系统有初步认识的初学者,即使读者从未接受过电脑方面的系统训练,甚至连微软的Windows都没有学过,也能从本书中获益。 二、本书特点 1)在介绍过程中,着重于概念的层次性和内容的衔接,使读者更容易进行学习。 2)为了能把深奥、复杂的概念和操作表达明白,本书使用了大量的插图和实际操作例子,使之通俗易懂。例如:在网络应用部分中的很多例子,都在中山大学服务器上运行,每天都在承受巨大的访问量。 3)配置了大量习题。 三、本书结构安排 本书共分19章,遵循由简到繁、由易到的讲解方式来组织、安排内容。 第1章:Linux基础。本章首先对Unix进行了概述,然后介绍了Linux的技术特点、Linux的版本,以及Linux对中文的支持。 第2章:基本操作。本章主要介绍了Linux的一些基本操作。如:注册、注销、远程登录、更改时间、关闭系统等。 第3章:树型结构。本章主要介绍了Linux的文件结构、目录结构,同时还介绍了链接,并用大量的实例形象生动地说明了Linux下各种文件的操作。 第4章:文本编辑。本章主要介绍了Linux下的文本编辑器,这是使用Linux的一些基本技能。学好本章,有利于以后的学习。 第5章:Linux的安装和启动。本章主要介绍了Linux的安装和启动,其中涉及到一些原理以及其他Unix类操作系统上的原理。 第6章:用户管理。本章主要介绍了Linux下增加用户、删除用户、设置用户组的各种操作,这些操作是进入Linux系统的第一步。 第7章:Shell和Shell编程。本章主要介绍了Shell的基本概念、Shell脚本以及awk的相关知识。 第8章:进程管理。本章主要介绍了在Linux中的进程管理。其中包括了进程、进程数、进程的优先级、定时执行等。 第9章:C编译器—— gcc。本章主要介绍了Linux下面的编译器—— gcc的基本用法以及Make与Makefile的一些基本知识。 第10章:系统扩充。本章主要介绍了在Linux中系统的扩充,包括软件的安装和内核的升级等内容。 第11章:系统维护与监视。本章主要介绍了Linux中的文件系统维护与监视。其中包括交换空间、/proc的信息以及各种日志文件和进程记账等。 第12章:图形界面。本章主要介绍了X Window以及它的配置,并且介绍了在KDE环境下汉化的基本思想,用实例来讲解了Linux汉化的基础知识。 第13章:网络的基本概念与设置。本章主要介绍了网络的基本概念,并在讲解这个概念的同时,讲解Linux中的网络配置。在此同时讲解了Linux的基本的网络命令,这对于理解Linux的网络上面的基本运用有着很大的作用。 第14章:网络资源共享。本章主要介绍了NFS文件系统、NFS文件系统的架设、Samba的资源共享、打印机网络共享等内容。 第15章:电子邮件。本章主要介绍电子邮件系统、Linux下的电子邮件系统,以及建立Linux下的邮件服务器。 第16章:DNS服务器。本章主要介绍DNS工作的原理、Linux下的域名服务器系统以及BIND的安装与配置等内容。详细叙述了主DNS服务器和辅助DNS服务器的配置以及DNS的安全。 第17章:FTP服务器。本章主要介绍了wu-ftp服务器的安装、配置和使用,Proftpd服务器的安装、配置和使用。 第18章:W
©️2020 CSDN 皮肤主题: 深蓝海洋 设计师:CSDN官方博客 返回首页