嵌入式裸机开发之点亮LED

博客大部分都是来自朱有鹏老师的课堂笔记 声明来处 我只是总结一下方便后期回顾

1.LED物理特性介绍
LED本身有2个接线点，一个是LED的正极，一个是LED的负极。
LED这个硬件的功能就是点亮或者不亮，物理上想要点亮一颗LED只需要给他的正负极上加正电压即可，
要熄灭一颗LED只需要去掉电压即可。
2。查阅原理图了解板载LED硬件接法
查阅原理图，发现开发板上一共有5颗LED。其中一颗D26的接法是：正极接5V，负极接地。因此这颗LED只要上电就会常亮因此我们分析这颗LED是电源指示灯。
剩下4颗LED的接法是：正极接3.3V，负极接了SoC上的一个引脚（GPIO），具体详细接法是：
D22：GPJ0_3
D23：GPJ0_4
D24：GPJ0_5
D25：PWMTOUT1(GPD0_1)
3GPIO概念的引入
GPIO:general purpose input output 通用输入输出
GPIO就是芯片的引脚（芯片上的引脚有些不是GPIO，只有一部分是），
作为GPIO的这类引脚，他的功能和特点是可以被编程控制它的工作模式，也可以编程控制他的电压高低等。
这也就有了设计电路时就把LED接在了一个GPIO上，这样我们就可以通过编程控制GPIO的模式和输入输出值来操控LED亮还是灭；

4：然后就有了软硬件编程的接口了 寄存器（都是要通过查阅数据手册的）
查阅数据手册可知，GPJ0相关的寄存器有以下：
GPJ0CON, （GPJ0 control）GPJ0控制寄存器，用来配置各引脚的工作模式
GPJ0DAT, （GPJ0 data）当引脚配置为input/output模式时，寄存器的相应位和引脚的电平高低相对应。
GPJ0PUD, （pull up down）控制引脚内部弱上拉、下拉
GPJ0DRV, （driver）配置GPIO引脚的驱动能力
GPJ0CONPDN，（记得是低功耗模式下的控制寄存器）
GPJ0PUDPDN （记得是低功耗模式下的上下拉寄存器）
注：在驱动LED点亮时，应该将GPIO配置为output模式。

实际上真正操控LED的硬件，主要的有：GPJ0CON, GPJ0DAT 这么2个。
如何点亮LED，编程的步骤是：
1、操控GPJ0CON寄存器中，选中output模式
2、操控GPJ0DAT寄存器，相应的位设置为0

寄存器与内存的统一编址 通过地址来找到寄存器进行操控

编译、下载、运行看结果
编译时用我们的工程管理，直接make编译得到led.bin和210.bin
下载运行可以用usb启动dnw下载；也可以用sd卡烧录下载，根据自己的情况用
一般都用usb下载，因为方便。如果电脑主板插上dnw会死机没法解决，那只有sd卡下载启动了。
注意：开发板上按下电源键之后4颗LED默认都是半亮的，当我们下载程序后其中3颗变的很亮，
注意dnw的使用的时候要注意
使用的是usb转otg线
注意调com和烧录的地址

实验步骤
1：通过地址0xE0200240找到GPJ0COM寄存器 该寄存器就是完成对引脚工作模式的控制0b0001表示输出模式
2：往该寄存器写值写入 0x1111_1111 因为
D22：GPJ0_3
D23：GPJ0_4
D24：GPJ0_5三个引脚有关 但是我们编程的时候可以把整个8个引脚都变成output模式
每个引脚4位 0b0001表示输出模式 则写入0x1111_1111即可
上面两部就是控制了GPIO的工作模式，输出模式
3：通过地址0xE0200244找到GPJ0DAT寄存器，该寄存器8个位分别就是反应了各个引脚的状态。要输出0则直接将该bit为设为0则对应引脚输出0
4；将0x0存入GPJ0DAT寄存器作位引脚输出的状态
5：裸机开发注意要进行死循环 防止cpu跑飞；

看三个代码 一步步编程

/*
    *作者：
    *实现led D22 D23 D24点亮
    *实现步骤
        1：通过地址0xE0200240找到GPJ0COM寄存器 该寄存器就是完成对引脚工作模式的控制0b0001表示输出模式
        2：往该寄存器写值写入 0x1111_1111 因为
            D22：GPJ0_3
            D23：GPJ0_4
            D24：GPJ0_5三个引脚有关 但是我们编程的时候可以把整个8个引脚都变成output模式
            每个引脚4位 0b0001表示输出模式  则写入0x1111_1111即可
        上面两部就是控制了GPIO的工作模式，输出模式
        3：通过地址0xE0200244找到GPJ0DAT寄存器，该寄存器8个位分别就是反应了各个引脚的状态。要输出0则直接将该bit为设为0则对应引脚输出0
        4；将0x0存入GPJ0DAT寄存器作位引脚输出的状态
        5：裸机开发注意要进行死循环 防止cpu跑飞；
*/

_start:
    // 第一步：把0x11111111写入0xE0200240(GPJ0CON)位置
    ldr r0, =0x11111111 // 从后面的=可以看出用的是ldr伪指令，因为需要编译器来判断这个数
    ldr r1, =0xE0200240 // 是合法立即数还是非法立即数。一般写代码都用ldr伪指令
    str r0, [r1]            // 寄存器间接寻址。功能是把r0中的数写入到r1中的数为地址的内存中去

    ldr r0, =0x0            // 把0写入到GPJ0DAT寄存器中，引脚即输出低电平，LED点亮
    ldr r1, =0xE0200244
    str r0, [r1]

flag:                           // 这两行写了一个死循环。因为裸机程序是直接在CPU上运行的，CPU会
    b flag                      // 逐行运行裸机程序直到CPU断电关机。如果我们的程序所有的代码都
                                // 执行完了CPU就会跑飞（跑飞以后是未定义的，所以千万不能让CPU
                                // 跑飞），不让CPU跑飞的办法就是在我们整个程序执行完后添加死循环

/*
 * 文件名： led.s   
 * 作者：  朱老师(购买了朱有鹏老师的嵌入式视频 声明一下来历)
 * 描述：  流水灯
 */

#define GPJ0CON 0xE0200240
#define GPJ0DAT 0xE0200244

.global _start                  // 把_start链接属性改为外部，这样其他文件就可以看见_start了
_start:
    // 第一步：把所有引脚都设置为输出模式，代码不变
    ldr r0, =0x11111111         // 从后面的=可以看出用的是ldr伪指令，因为需要编译器来判断这个数
    ldr r1, =GPJ0CON            // 是合法立即数还是非法立即数。一般写代码都用ldr伪指令
    str r0, [r1]                // 寄存器间接寻址。功能是把r0中的数写入到r1中的数为地址的内存中去

    // 要实现流水灯，只要在主循环中实现1圈的流水显示效果即可
flash:
    // 第1步：点亮LED1，其他熄灭
    ldr r0, =((0<<3) | (1<<4) | (1<<5)) // 清清楚楚的看到哪个灭，哪个是亮
    ldr r1, =GPJ0DAT
    str r0, [r1]                // 把0写入到GPJ0DAT寄存器中，引脚即输出低电平，LED点亮
    // 然后延时
    bl delay                    // 使用bl进行函数调用

    // 第2步：点亮LED2，其他熄灭
    ldr r0, =((1<<3) | (0<<4) | (1<<5)) // 清清楚楚的看到哪个灭，哪个是亮
    ldr r1, =GPJ0DAT
    str r0, [r1]                // 把0写入到GPJ0DAT寄存器中，引脚即输出低电平，LED点亮
    // 然后延时
    bl delay    

    // 第3步：点亮LED3，其他熄灭
    ldr r0, =((1<<3) | (1<<4) | (0<<5)) // 清清楚楚的看到哪个灭，哪个是亮
    ldr r1, =GPJ0DAT
    str r0, [r1]                // 把0写入到GPJ0DAT寄存器中，引脚即输出低电平，LED点亮
    // 然后延时
    bl delay        


    b flash


// 延时函数：函数名：delay
delay:
    ldr r2, =9000000
    ldr r3, =0x0
delay_loop: 
    sub r2, r2, #1              //r2 = r2 -1
    cmp r2, r3                  // cmp会影响Z标志位，如果r2等于r3则Z=1，下一句中eq就会成立
    bne delay_loop
    mov pc, lr                  // 函数调用返回

/*
led最后实验 流水灯实验

最后一个D25 根据我们查阅原理图以及查看数据手册可知 

它是接在GPDO_1引脚上。
GPDOCON有16位分别有4个引脚 则每个引脚4位。
GPDODAT有4位分别表示4个引脚的工作状态，每个引脚1位。
GPDOCON寄存器的bit4~7表示该引脚的工作模式  设置4~7为0001（0x1） 则表示是输出状态。
GPDODAT寄存器的bit1表示该引脚的工作状态 设置1位0则表示底电平则led放光 反正1则高电平不发光。

*/

/*
    led最后实验  流水灯实验

    最后一个D25 根据我们查阅原理图以及查看数据手册可知 

    它是接在GPDO_1引脚上。
    GPDOCON有16位分别有4个引脚 则每个引脚4位。
    GPDODAT有4位分别表示4个引脚的工作状态，每个引脚1位。
    GPDOCON寄存器的bit4~7表示该引脚的工作模式  设置4~7为0001（0x1） 则表示是输出状态。
    GPDODAT寄存器的bit1表示该引脚的工作状态 设置1位0则表示底电平则led放光 反正1则高电平不发光。

*/

#define GPJOCON 0xE0200240
#define GPJODAT 0xE0200244
#define GPDOCON 0xE02000A0
#define GPDODAT 0xE02000A4

.global _start

_start:
    ldr r0, =0x11111111
    ldr r1, =GPJOCON
    str r0, [r1]
    ldr r0, =0x1111
    ldr r1, =GPDOCON
    str r0, [r1]


flash:                      设置标志  为循环起名字



    ldr r0, =((0<<3) | (1<<4) | (1<<5))  //可以改写成 ~(1<<3)
    ldr r1, =GPJODAT
    str r0, [r1]
    bl delay

    ldr r0, =((1<<3) | (0<<4) | (1<<5)) //可以改写成 ~(1<<4)
    ldr r1, =GPJODAT
    str r0, [r1]
    bl delay

    ldr r0, =((1<<3) | (1<<4) | (0<<5))`//可以改写成 ~(1<<5)
    ldr r1, =GPJODAT
    str r0, [r1]
    bl delay

    ldr r0, =((1<<3) | (1<<4) | (1<<5)) //可以改写成 1111
    ldr r1, =GPJODAT
    str r0, [r1]
    bl delay

    ldr r0, = 0x0
    ldr r1, =GPDODAT
    str r0, [r1]
    bl delay

    ldr r0, = (1<<1)
    ldr r1, =GPDODAT
    str r0, [r1]
    bl delay

    b flash

delay:
    ldr r2, =9000000
    ldr r3, =0x0
delay_loop:
    sub r2, r2, #1
    cmp r2, r3
    bne delay_loop
    mov pc, lr