转 第十五章 3D 基础 （3）（as3.0)

最新推荐文章于 2024-04-24 15:21:54 发布
最新推荐文章于 2024-04-24 15:21:54 发布
阅读量1.2k 收藏
点赞数
分类专栏： Flash Flex 文章标签： function import class 游戏 flash 测试

坐标旋转
     接下来是 3D  坐标旋转。这里要比第十和十一章中的 2D  坐标旋转要稍微复杂一些。
我们不仅可以在三个不同的轴上旋转，还可以同时在两个以上的轴上进行旋转。
     在 2D 坐标旋转中物体是绕着 z  轴旋转的，如图 15-9  所示。想一想命运之轮(Wheel of
Fortune)这类游戏---轮轴从轮盘的中心穿过。轮轴就是 z 轴。只改变 x  和 y  坐标。

转 <wbr>第十五章 <wbr>3D <wbr>基础 <wbr>（3）（as3.0)

图 15-9  z 轴旋转
     在 3D 中，我们也可以在 y  或 z  轴上旋转。x  轴的旋转如同车轮向前滚动，如图 15-10
所示。这时轮轴就是 x 轴。只改变 y  和 z  上的点。

转 <wbr>第十五章 <wbr>3D <wbr>基础 <wbr>（3）（as3.0)

图 15-10 x  轴旋转
 y  轴上的旋转，请想象一下老的唱片机，如图 15-11  所示。轴心是 y  轴。只改变 x 和 z
上的点。

转 <wbr>第十五章 <wbr>3D <wbr>基础 <wbr>（3）（as3.0)

 

图 15-11 y  轴旋转
     因此，对于 3D  而言，当我们在某个轴上旋转一个物体时，将改变两个轴上的位置。
回顾一下第十章，我们找到 2D  旋转的公式如下：
      x1 = cos(angle) * x - sin(angle) * y;
       y1 = cos(angle) * y + sin(angle) * x;
在 3D  中，方法几乎相同，但是需要指定操作的是哪个轴：x, y, z。因此得到下面三个公式：
      x1 = cos(angleZ) * x - sin(angleZ) * y;
       y1 = cos(angleZ) * y + sin(angleZ) * x;
      x1 = cos(angleY) * x - sin(angleY) * z;
       z1 = cos(angleY) * z + sin(angleY) * x;
       y1 = cos(angleX) * y - sin(angleX) * z;
       z1 = cos(angleX) * z + sin(angleX) * y;


下面，试一下 y  轴的旋转。以下代码可在 RotateY.as  中找到。创建 50  个 Ball3D  的实例，
随机放置舞台上。根据鼠标 x  轴上的位置计算出 y  轴角度。鼠标越向右，角度值越高。物
体就像跟着鼠标旋转一样。
package {
 import flash.display.Sprite;
 import flash.events.Event;
  public class RotateY extends Sprite {
   private var balls:Array;
   private var numBalls:uint = 50;

   private var fl:Number = 250;
   private var vpX:Number = stage.stageWidth / 2;
   private var vpY:Number = stage.stageHeight / 2;
   public function RotateY() {
   init();
  }
   private function init():void {
   balls = new Array();
     for (var i:uint = 0; i < numBalls; i++) {
      var ball:Ball3D = new Ball3D(15);
    balls.push(ball);
      ball.xpos = Math.random() * 200 - 100;
      ball.ypos = Math.random() * 200 - 100;
      ball.zpos = Math.random() * 200 - 100;
    addChild(ball);
   }
   addEventListener(Event.ENTER_FRAME, onEnterFrame);
  }
   private function onEnterFrame(event:Event):void {
     var angleY:Number = (mouseX - vpX) * .001;
     for (var i:uint = 0; i < numBalls; i++) {

   var ball:Ball3D = balls[i];
    rotateY(ball, angleY);
   }
   sortZ();
  }
   private function rotateY(ball:Ball3D, angleY:Number):void {
   var cosY:Number = Math.cos(angleY);
     var sinY:Number = Math.sin(angleY);
     var x1:Number = ball.xpos * cosY - ball.zpos * sinY;
     var z1:Number = ball.zpos * cosY + ball.xpos * sinY;
   ball.xpos = x1;
   ball.zpos = z1;
     if (ball.zpos > -fl) {
    var scale:Number = fl / (fl + ball.zpos);
      ball.scaleX = ball.scaleY = scale;
      ball.x = vpX + ball.xpos * scale;
      ball.y = vpY + ball.ypos * scale;
    ball.visible = true;
   } else {

    ball.visible = false;
   }
  }
   private function sortZ():void {
   balls.sortOn("zpos", Array.DESCENDING | Array.NUMERIC);
     for (var i:uint = 0; i < numBalls; i++) {
    var ball:Ball3D = balls[i];
    setChildIndex(ball, i);
   }
   }
 }
}
     重要的部分加粗表示。获得一个角度，然后使用该角度调用 rotateY 的方法。该方法中，
获得角度的正弦和余弦值，执行旋转，将 x1 和 z1  再赋值给 ball.xpos  和 ball.zpos。接下
来，就是标准透视以及 z  排序。运行结果如图 15-12  所示。
转 <wbr>第十五章 <wbr>3D <wbr>基础 <wbr>（3）（as3.0)

图 15-12  y 轴旋转
     如果这个程序没问题，大家一定也可以将其转换为 x  轴的旋转。只需要改变
onEnterFrame 方法并加入 rotateX  方法：
private function onEnterFrame(event:Event):void {
  var angleX:Number = (mouseY - vpY) * .001;
  for (var i:uint = 0; i < numBalls; i++) {
   var ball:Ball3D = balls[i];
  rotateX(ball, angleX);
 }
 sortZ();
}
private function rotateX(ball:Ball3D, angleX:Number):void {
  var cosX:Number = Math.cos(angleX);
  var sinX:Number = Math.sin(angleX);
  var y1:Number = ball.ypos * cosX - ball.zpos * sinX;
  var z1:Number = ball.zpos * cosX + ball.ypos * sinX;
  ball.ypos = y1;
 ball.zpos = z1;
  if (ball.zpos > -fl) {

   var scale:Number = fl / (fl + ball.zpos);
   ball.scaleX = ball.scaleY = scale;
   ball.x = vpX + ball.xpos * scale;
   ball.y = vpY + ball.ypos * scale;
  ball.visible = true;
  } else {
  ball.visible = false;
 }
}
     现在，angleX  是根据鼠标的 y  坐标确定的。然后计算出正余弦的值，并使用它们算出

y1  和 z1，再赋值给 ypos  和 zpos 属性。
     接下来，我们将两种旋转组合起来。以下是代码（可以在 RotateXY.as  中找到）：
package {
 import flash.display.Sprite;
 import flash.events.Event;
  public class RotateXY extends Sprite {
   private var balls:Array;
   private var numBalls:uint = 50;
   private var fl:Number = 250;
   private var vpX:Number = stage.stageWidth / 2;
   private var vpY:Number = stage.stageHeight / 2;
   public function RotateXY() {
   init();
  }
   private function init():void {
   balls = new Array();
     for (var i:uint = 0; i < numBalls; i++) {
      var ball:Ball3D = new Ball3D(15);
    balls.push(ball);
      ball.xpos = Math.random() * 200 - 100;

      ball.ypos = Math.random() * 200 - 100;
      ball.zpos = Math.random() * 200 - 100;
    addChild(ball);
   }
   addEventListener(Event.ENTER_FRAME, onEnterFrame);
  }
   private function onEnterFrame(event:Event):void {
     var angleX:Number = (mouseY - vpY) * .001;
     var angleY:Number = (mouseX - vpX) * .001;
     for (var i:uint = 0; i < numBalls; i++) {
    var ball:Ball3D = balls[i];
    rotateX(ball, angleX);
    rotateY(ball, angleY);
    doPerspective(ball);
   }
   sortZ();
  }
   private function rotateX(ball:Ball3D, angleX:Number):void {
   var cosX:Number = Math.cos(angleX);
     var sinX:Number = Math.sin(angleX);
     var y1:Number = ball.ypos * cosX - ball.zpos * sinX;
     var z1:Number = ball.zpos * cosX + ball.ypos * sinX;
   ball.ypos = y1;

   ball.zpos = z1;
  }
   private function rotateY(ball:Ball3D, angleY:Number):void {
   var cosY:Number = Math.cos(angleY);
     var sinY:Number = Math.sin(angleY);
     var x1:Number = ball.xpos * cosY - ball.zpos * sinY;
      var z1:Number = ball.zpos * cosY + ball.xpos * sinY;
   ball.xpos = x1;
   ball.zpos = z1;
  }
   private function doPerspective(ball:Ball3D):void {
     if (ball.zpos > -fl) {
    var scale:Number = fl / (fl + ball.zpos);
      ball.scaleX = ball.scaleY = scale;
      ball.x = vpX + ball.xpos * scale;
      ball.y = vpY + ball.ypos * scale;
    ball.visible = true;
   } else {
    ball.visible = false;
   }
  }
   private function sortZ():void {
   balls.sortOn("zpos", Array.DESCENDING | Array.NUMERIC);
     for (var i:uint = 0; i < numBalls; i++) {
    var ball:Ball3D = balls[i];
    setChildIndex(ball, i);
   }

  }
 }
}
     与前一个例子相比主要的变化用粗体表示。现在，我们计算出 angleY, angleX  ，并调
用 rotateX, rotateY。注意，我将透视的代码从 rotate  方法中分离到一个单独的方法中，因
为它不需要被调用两次。我相信根据前面的公式，您一定可以自行加入 rotateZ 方法。
     测试一下这个影片。通过将 3D  坐标旋转与前一节赛车游戏的“屏幕环绕”的概念相
结合，大家一定还可以创建出丰富的，交互性的 3D  环境。
 

 
碰撞检测
     本章的最后我要给大家介绍一下 3D  的碰撞检测。在 Flash  的三维空间中唯一可行的
方法就是距离碰撞检测。找出两个物体的距离（使用 3D 距离公式），如果小于两个物体的
半径之和，就产生了碰撞。
     我将前面 3D  反弹的例子改成了 3D  碰撞检测的例子，加入了少量的物体并扩大了一
些空间。代码中首先执行普通的 3D  运动及透视，然后做一个双重循环比较所有小球的位
置。如果有两个物体的距离小于它们的半径之和，就使用颜色转换代码将它们都设置为蓝色。
非常简单。以下是代码（Collision3D.as）：
package {
 import flash.display.Sprite;
 import flash.events.Event;
 import flash.geom.ColorTransform;
  public class Collision3D extends Sprite {
   private var balls:Array;
   private var numBalls:uint = 20;
   private var fl:Number = 250;
   private var vpX:Number = stage.stageWidth / 2;

   private var vpY:Number = stage.stageHeight / 2;
   private var top:Number = -200;
   private var bottom:Number = 200;
   private var left:Number = -200;
   private var right:Number = 200;
   private var front:Number = 200;
   private var back:Number = -200;
   public function Collision3D() {
   init();
  }
   private function init():void {
   balls = new Array();
     for (var i:uint = 0; i < numBalls; i++) {
      var ball:Ball3D = new Ball3D(15);
    balls.push(ball);
      ball.xpos = Math.random() * 400 - 200;
      ball.ypos = Math.random() * 400 - 200;
      ball.zpos = Math.random() * 400 - 200;
      ball.vx = Math.random() * 10 - 5;
      ball.vy = Math.random() * 10 - 5;
      ball.vz = Math.random() * 10 - 5;
    addChild(ball);
   }

   addEventListener(Event.ENTER_FRAME, onEnterFrame);
  }
   private function onEnterFrame(event:Event):void {
     for (var i:uint = 0; i < numBalls; i++) {
    var ball:Ball3D = balls[i];
    move(ball);
   }
     for (i = 0; i < numBalls - 1; i++) {
      var ballA:Ball3D = balls[i];
       for (var j:uint = i + 1; j < numBalls; j++) {
     var ballB:Ball3D = balls[j];
        var dx:Number = ballA.xpos - ballB.xpos;
        var dy:Number = ballA.ypos - ballB.ypos;
     var dz:Number = ballA.zpos - ballB.zpos;
        var dist:Number = Math.sqrt(dx*dx + dy*dy + dz*dz);
        if (dist < ballA.radius + ballB.radius) {
      var blueTransform:ColorTransform =
         new ColorTransform(0, 1, 1, 1, 0, 0, 255, 0);
      ballA.transform.colorTransform = blueTransform;
      ballB.transform.colorTransform = blueTransform;
     }
    }
   }

 sortZ();
  }
   private function move(ball:Ball3D):void {
      var radius:Number = ball.radius;
   ball.xpos += ball.vx;
   ball.ypos += ball.vy;
   ball.zpos += ball.vz;
     if (ball.xpos + radius > right) {
      ball.xpos = right - radius;
    ball.vx *= -1;
     } else if (ball.xpos - radius < left) {
      ball.xpos = left + radius;
    ball.vx *= -1;
   }
     if (ball.ypos + radius > bottom) {
      ball.ypos = bottom - radius;
    ball.vy *= -1;
     } else if (ball.ypos - radius < top) {
      ball.ypos = top + radius;
    ball.vy *= -1;
   }
     if (ball.zpos + radius > front) {
      ball.zpos = front - radius;

    ball.vz *= -1;
     } else if (ball.zpos - radius < back) {
    ball.zpos = back + radius;
    ball.vz *= -1;
   }
     if (ball.zpos > -fl) {
    var scale:Number = fl / (fl + ball.zpos);
      ball.scaleX = ball.scaleY = scale;
      ball.x = vpX + ball.xpos * scale;
      ball.y = vpY + ball.ypos * scale;
    ball.visible = true;
   } else {
    ball.visible = false;
   }
  }
   private function sortZ():void {
   balls.sortOn("zpos", Array.DESCENDING | Array.NUMERIC);
     for (var i:uint = 0; i < numBalls; i++) {
    var ball:Ball3D = balls[i];
    setChildIndex(ball, i);
   }
  }
 }

}
     重要的部分用粗体表示。小球起初都是红色的，当它们碰撞后，颜色发生改变。最后，
全部变为蓝色。
 

本章重要公式
     本章的重要公式是3D透视，坐标旋转以及距离的计算。
 
 
 
基本 
scale = fl / (fl + zpos);
sprite.scaleX = sprite.scaleY = scale;
sprite.alpha = scale; //  可选
sprite.x = vanishingPointX + xpos * scale;
sprite.y = vanishingPointY + ypos * scale;

 

 
Z  排序：
//  假设有一个带有 zpos 属性的 3D 物体的数组
objectArray.sortOn("zpos", Array.DESCENDING | Array.NUMERIC);
for(var i:uint = 0; i < numObjects; i++) {
    setChildIndex(objectArray[i], i);
}
 

 
坐标旋转：
x1 = cos(angleZ) * xpos - sin(angleZ) * ypos;
y1 = cos(angleZ) * ypos + sin(angleZ) * xpos;
x1 = cos(angleY) * xpos - sin(angleY) * zpos;
z1 = cos(angleY) * zpos + sin(angleY) * xpos;
y1 = cos(angleX) * ypos - sin(angleX) * zpos;
z1 = cos(angleX) * zpos + sin(angleX) * ypos;
 
 
 
3D  距离:
dist = Math.sqrt(dx * dx + dy * dy + dz * dz); 
 

 

其实现在CS4 CS5都已经出来了，用过的朋友都知道从CS4开始已经引入了3D这个概念，直接增加Z这个坐标属性以及旋转，不过作为知识是不会过时的哈哈，大家可以结合CS4的特性来修改下上面所描述的Z得坐标。
 

（如果要转载请注明出处http://blog.sina.com.cn/jooi，谢谢）

coding_most
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
ActionScript 3.0 开发人员指南 （AS3开发帮助文档）
07-17
第 3 章 : 使用数组 第 4 章 : 处理错误 第 5 章 : 使用正则表达式 第 6 章 : 使用 XML 第 7 章 : 使用本机 JSON 功能 第 8 章 : 处理事件 第 9 章 : 使用应用程序域 第 10 章 : 显示编程 第 11 章 : 使用...
“AS3.0高级动画编程”学习：第三章等角投影(上)
weixin_34348174的博客
07-13 97
什么是等角投影（isometric）? 刚接触这个概念时，我也很茫然，百度+google了N天后，找到了一些文章： [转载]等角(斜45度)游戏与数学 [转载]使用illustrator和正交投影原理以及基本三视图制图 以及这篇ppt：http://files.cnblogs.com/yjmyzz/Isometric.rar 建议先耐心看完这三篇文章，再往下看： 在之前学习的3D基础、...
JS Math.sin() 与 Math.cos()找x、y坐标
前端小狮的博客
06-06 5702
Math.sin(x) //x 的正玄值。返回值在 -1.0 到 1.0 之间； Math.cos(x) //x 的余弦值。返回的是 -1.0 到 1.0 之间的数； 这两个函数中的X 都是指的“弧度”而非“角度” Math.PI 相当于数学中的 π ， 180° ; 角度为 a, 则弧度为a * (π / 180) ; 弧度为 a, 则角度为a * (180 / π ) ;...
转 第十五章 3D 基础 （2）（as3.0)
roadProgram的专栏
10-12 762
Z  排序      在添加了多个物体后代码中显现出了一个新问题---称为z  排序。Z  排序就像它的名 字一样：物体如何在 z  轴上进行排序，或者说哪个物体在前面。由于物体都使用纯色，所 以看起来不是很明显。为了让效果更加明显，请将 Ball3D  的 init  方
转 第十五章 3D 基础 （1）（as3.0)
roadProgram的专栏
10-12 825
前面我们做的一切都是二维的（有时只有一维），但是已经可以做出非常酷的东东了。 现在，将它们带入到下一个等级。      创建 3D  图形总是那么另人兴奋。新加入的这个维度似乎将物体真正地带入到了生活 中。如何在 Flash  中实现 3D  在无数的书籍和教学软件中都有介
[Flash.ActionScript.3.0动画教程
09-15
第15章 3D基础 15.1 第3维和透视 15.1.1 z轴 15.1.2 透视公式 15.2 速度和加速度 15.3 回弹 15.3.1 单个物体回弹 15.3.2 多物体回弹 15.3.3 z轴排序 15.4 重力 15.5 折回 15.6 缓动和弹性 15.6.1 缓动 15.6.2 弹性 ...
Unity实现动态数字变化
极客园地
04-20 579
最近的项目需要动态显示数字，所以使用Text组件，将数字进行变化操作过程记录下来。
20.Unity飞机大战游戏
weixin_60435181的博客
04-21 270
Unity飞机大战游戏 结课大作业
苹果App Store政策调整，模拟器游戏或成为新机遇
cuckoomin的博客
04-22 613
随着智能手机的普及和技术的飞速发展，iPhone和Android手机已深入我们的日常生活，成为不可或缺的一部分。然而，随着模拟器游戏在iOS平台上的合法化，中国游戏厂商迎来了新的发展机遇。这不仅能够满足海外玩家对中国文化的好奇心，还能够通过游戏的形式传播中国文化，提升中国游戏在国际市场的知名度和影响力。同时，他们还需要深入了解海外市场的需求和特点，制定针对性的市场策略，以便更好地适应海外市场的竞争环境。面对新的政策环境和市场需求，中国游戏厂商需要不断创新和优化游戏内容，提升用户体验和满意度。
c++自制小游戏：c++人生重开模拟器（修仙版）
如果没有特别说明，c++都是基于GCC-4.9.2运行的
04-20 564
注：版本较新的基于GCC-4.9.2环境下运行的，旧版基于GCC版本更低，但多少不知道了。
Unity 时间格式 12小时制与24小时制
最新发布
weixin_44919646的博客
04-24 211
Unity 时间格式 12小时制与24小时制
​Gu‘reum 工作室在The Sandbox推出 2024 年农历新年活动！
BeepCrypto的博客
04-22 907
此次活动，Gu'reum 工作室准备了最高 500 SAND 的奖励，并得到了 The Sandbox Korea 额外 500 SAND 的赞助，总奖励达到了 1000 SAND。Gu'reum 工作室 相信以有机的方式建立社区，并专注于通过他们在The Sandbox上的体验促进深层次的联系和有意义的互动。在过去的 Seollal（农历新年）期间，韩国人的衣服上没有口袋，所以他们随身携带小袋来存放从长辈那里得到的钱。Gu'reum 工作室相信，只有确保创作者的自由和实验精神，才能最大限度地发挥创造力。
C语言：贪吃蛇游戏（万字解读超详细）
2301_80655639的博客
04-20 1036
贪吃蛇这个游戏应该我们小时候都玩过吧我相信能够点进这个博客的应该都很熟悉这个游戏了如果对这个游戏不熟悉的可以网上查查怎么玩，这样才能对这个游戏有个清晰的认知该篇博客需要拥有C语言基础（对指针熟悉、会链表的使用）下面我们需要先学习一些C语言之外的东西认真坚持看完，我相信你一定能完成这个接近500行的C语言贪吃蛇项目该类型内部封装了两个成员，一个x，一个y，代表坐标我们可以将我们的控制台理解为一个平面坐标图横向正方向是x轴正方向，竖向负方向是y轴正方向。
[Unity]打包Android后xxx方法丢失。
国家级摸鱼一级选手
04-23 242
Editor下C#一段反射代码运行正常，但是打包后报错。最后发现是PlayerSettings里的Managed Stripping Level（托管堆代码剥离级别）导致的，项目默认的是Medium。改成Low确实好使，但是会造成包体大了很多，于是后面只把丢失的那个方法给加了一个属性PreserveAttribute：[Preserve]，这样就能保证工程在导出时不会将其剥离。
GDPU unity游戏开发 碰撞体与关节
嫌人闲事
04-23 444
让你设计的角色跑起来吧，可以是动画，也可以是碰撞器的运动。
as3.0声音延迟播放
02-01
AS3.0声音延迟播放是指在播放声音时出现一定的时间延迟。这种延迟可能由于多种原因引起，例如电脑性能差、网络延迟、音频格式问题等。在AS3.0中，我们可以采取一些措施来减少声音延迟。 首先，确保使用适当的音频...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值