重定位和链接脚本

链接脚本

地址无关码：

(PIC，position independent code)：汇编源文件被编码成二进制可执行程序时编码方式与位置（内存地址）无关

地址有关码：

汇编源码编码成二进制可执行程序后和内存地址是有关的

运行地址

程序实际运行时地址（指定方式：由实际运行时被加载到内存的哪个位置说了算）
 

链接地址：

 链接时指定的地址（指定方式为：Makefile中用-Ttext -(地址)，或者链接脚本-Tlink.lds -o）

链接脚本其实是个规则文件，他是程序员用来指挥链接器工作的。链接器会参考链接脚本，并且使用其中规定的规则来处理.o文件中那些段，将其链接成一个可执行程序。
    链接脚本的关键内容有2部分：段名 + 地址（作为链接地址的内存地址）
    链接脚本的理解：
    SECTIONS {}    这个是整个链接脚本
    . 点号在链接脚本中代表当前位置。
    = 等号代表赋值
 

SECTIONS
{
	. = 0x20000000;  //  .  表示当前地址，  = 表示赋值                
	
	.text : {                                       //代码段
		start.o                       //表示放在第一行
		sdram_init.o              
		* (.text)                     //其他 .text 属性的文件在代码段中随便放
	}
    		
	.data : {                                   //数据段    存放初始化为非0的全局变量和 局部变量
		* (.data)                  //表示 .data 属性的文件随便放     如果要指定文件放的位置就要把文件名打出来
	}
	
	bss_start = .;                       //把当前地址 赋值给标号 bss_start 方便其他程序引用
	.bss : {                                 //只存放初始化为0全局变量和局部变量
		* (.bss)                    
	}
	
	bss_end  = .;	                假如从 0x20000000地址到 bss_start = 0x20000010 地址 那么 bss_start 的地址就为0x20000010
}

程序段的概念：代码段、数据段、bss段（ZI段）、自定义段
段就是程序的一部分，我们把整个程序的所有东西分成了一个一个的段，给每个段起个名字，然后在链接时就可以用这个名字来指示这些段。也就是说给段命名就是为了在链接脚本中用段名来让段站在核实的位置。

段名分为2种：一种是编译器链接器内部定好的，先天性的名字；一种是程序员自己指定的、自定义的段名。
先天性段名：
    代码段：（.text），又叫文本段，代码段其实就是函数编译后生成的东西
    数据段：（.data），数据段就是C语言中有显式初始化为非0的全局变量
    bss段：（.bss），又叫ZI（zero initial）段，就是零初始化段，对应C语言中初始化为0的全局         变量。
后天性段名：
    段名由程序员自己定义，段的属性和特征也由程序员自己定义。

重定位

为什么需要重定位？

1. 当某一段代码必须要在规定的地址才能执行时， 而这个地址与CPU设计时规定的地址不一样，就需要重定位。 如某一段代码必须要在0x20004000这个地址执行， 但在s5pv210中规定代码必须通过dnw下载到0x20000010这个地址执行，这时就需要重定位。

2. 当程序员预想某一段代码通过链接规定必须在0x20004000这个地址执行， 这是就与CPU设计时下载到的运行地址不同，就需要重定位

总结：当链接地址与运行地址不同时就需要重定位

            第一点：通过链接脚本将代码链接到0xd0024000
            第二点：dnw下载时将bin文件下载到0xd0020010

            第三点：代码执行时通过代码前段的少量位置无关码将整个代码搬移到0xd0024000
            第四点：使用一个长跳转跳转到0xd0024000处的代码继续执行，重定位完成

重定位只重定位数据段和代码段

/*
 * 文件名：	led.s	
 * 作者：	朱老师
 * 描述：	演示重定位（在SRAM内部重定位）
 */

#define WTCON		0xE2700000

#define SVC_STACK	0xd0037d80

.global _start					// 把_start链接属性改为外部，这样其他文件就可以看见_start了
_start:
	// 第1步：关看门狗（向WTCON的bit5写入0即可）
	ldr r0, =WTCON
	ldr r1, =0x0
	str r1, [r0]
	
	// 第2步：设置SVC栈
	ldr sp, =SVC_STACK
	
	// 第3步：开/关icache
	mrc p15,0,r0,c1,c0,0;			// 读出cp15的c1到r0中
	//bic r0, r0, #(1<<12)			// bit12 置0  关icache
	orr r0, r0, #(1<<12)			// bit12 置1  开icache
	mcr p15,0,r0,c1,c0,0;
	
	// 第4步：重定位
	// adr指令用于加载_start当前运行地址
	adr r0, _start  		// adr加载时就叫短加载		
	// ldr指令用于加载_start的链接地址:0xd0024000
	ldr r1, =_start // ldr加载时如果目标寄存器是pc就叫长跳转，如果目标寄存器是r1等就叫长加载	
	// bss段的起始地址
	ldr r2, =bss_start	// 就是我们重定位代码的结束地址，重定位只需重定位代码段和数据段即可
	cmp r0, r1			// 比较_start的运行时地址和链接地址是否相等
	beq clean_bss		// 如果相等说明不需要重定位，所以跳过copy_loop，直接到clean_bss
						// 如果不相等说明需要重定位，那么直接执行下面的copy_loop进行重定位
						// 重定位完成后继续执行clean_bss。

// 用汇编来实现的一个while循环
copy_loop:
	ldr r3, [r0], #4    // 源      先r0 赋给r3 然后r0 = r0 + 4  再赋给r3    
	str r3, [r1], #4	// 目的   这两句代码就完成了4个字节内容的拷贝  r1 = r3   r1 = r1 +4 
	cmp r1, r2			// r1和r2都是用ldr加载的，都是链接地址，所以r1不断+4总能等于r2
	bne copy_loop

	// 清bss段，其实就是在链接地址处把bss段全部清零
clean_bss:
	ldr r0, =bss_start					
	ldr r1, =bss_end
	cmp r0, r1				// 如果r0等于r1，说明bss段为空，直接下去
	beq run_on_dram			// 清除bss完之后的地址
	mov r2, #0
clear_loop:
	str r2, [r0], #4		// 先将r2中的值放入r0所指向的内存地址（r0中的值作为内存地址），
	cmp r0, r1				// 然后r0 = r0 + 4
	bne clear_loop

run_on_dram:	
	// 长跳转到led_blink开始第二阶段
	ldr pc, =led_blink				// ldr指令实现长跳转
	
	// 从这里之后就可以开始调用C程序了
	//bl led_blink					// bl指令实现短跳转
	
// 汇编最后的这个死循环不能丢
	b .

反汇编中 ldr r1, [pc, #72] （间接寻址） 表示 pc 当前地址 向下偏移72个字节 就得到r1的地址

pc的值如果不考虑流水线 那么pc就是 现在pc所在行的地址， 因为ARM中有两级流水线 所以pc的值是当前行向下移动两行的地址

sub r0, pc, #36  直接寻址    

一开始pc的值是运行地址（即通过dnw把程序下载到的地址0x20000010 ， 程序执行依次向下加4个字节 因为ARM是32位的一个int也是32位的4个字节）

ldr r3, [r0], #4            r3 = r0    r0 = r0+4
str r3, [r1], #4            r1+4 = r3 //先赋值再加4 r1 = r3  r1 = r1+4     

注意所有的代码都要用英文输入法输入， 包括链接脚本和makefile 中的符号       

                                                                                                                  参考朱老师大物课堂