【区块链安全 | 第十七篇】类型之引用类型（一）-CSDN博客

原创文章，禁止转载，否则保留追究法律责任的权利。

本文链接：https://blog.csdn.net/2301_77485708/article/details/146882635

文章目录

引用类型

在这里插入图片描述

引用类型

引用类型的值可以通过多个不同的名称进行修改。这与值类型形成对比，在值类型中，每当使用一个值类型的变量时，都会获得一个独立的副本。因此，引用类型比值类型需要更谨慎地处理。

目前，引用类型包括结构体（structs）、数组（arrays）和映射（mappings）。如果使用引用类型，必须明确提供数据存储的位置：memory（其生命周期仅限于外部函数调用期间）、storage（存储状态变量的位置，其生命周期与合约的生命周期一致）或 calldata（一个特殊的数据存储区域，其中包含函数参数）。

如果赋值或类型转换导致数据存储位置发生变化，则会自动触发复制操作，而在同一数据存储位置内部进行赋值时，仅在某些情况下会触发复制（对于 storage 类型）。

数据存储位置

每个引用类型都有一个额外的注释，即“数据存储位置”，用于指明其存储位置。数据存储位置包括 memory、storage 和 calldata。calldata 是一个不可修改、不可持久化的区域，其中存储了函数参数，其行为大多数情况下类似于 memory。

在函数体中声明或作为返回参数的 calldata 位置的数组和结构体必须在使用或返回之前进行赋值。在某些使用非平凡控制流的情况下，编译器可能无法正确检测初始化。在这些情况下，一个常见的解决方法是先将受影响的变量赋值给自身，然后再进行正确的初始化。

分配行为

数据存储位置不仅与数据的持久性相关，还会影响赋值的语义：

在 storage 和 memory（或 calldata）之间的赋值总是会创建一个独立的副本。
在 memory 之间的赋值仅创建引用。这意味着对一个 memory 变量的修改会影响所有引用同一数据的 memory 变量。
从 storage 赋值给本地 storage 变量时，也只是赋值引用。
其他所有对 storage 的赋值都会进行复制。例如，对状态变量的赋值，或对 storage 结构体类型的本地变量的成员赋值，即使本地变量本身只是一个引用。

举个例子：

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.5.0 <0.9.0;

contract C {
    // x 的数据存储位置是 storage。
    // 这是唯一可以省略数据存储位置的地方。
    uint[] x;

    // memoryArray 的数据存储位置是 memory。
    function f(uint[] memory memoryArray) public {
        x = memoryArray; // 可以执行，会复制整个数组到 storage
        uint[] storage y = x; // 可以执行，赋值的是指针，y 的数据存储位置是 storage
        y[7]; // 合法，返回第 8 个元素
        y.pop(); // 合法，通过 y 修改 x
        delete x; // 合法，清空数组，同时影响 y

        // 以下操作无法执行，因为它需要在 storage 中创建一个新的临时/匿名数组，
        // 但 storage 是静态分配的：
        // y = memoryArray;

        // 同样，“delete y” 也是不合法的，因为对指向 storage 对象的本地变量的赋值
        // 只能来自已有的 storage 对象。
        // 它会“重置”指针，但没有合理的位置可以指向。
        // 更多细节请参考“delete” 运算符的文档。
        // delete y;

        g(x); // 调用 g，传递 x 的引用
        h(x); // 调用 h，创建一个独立的临时副本存储在 memory
    }

    function g(uint[] storage) internal pure {}
    function h(uint[] memory) public pure {}
}