【汇编语言】by王爽 | 实验9：根据材料编程

前言：本实验为王爽老师的《汇编语言》第三版中的实验9（p187）

实验环境：DOSBox 0.74-3

实验任务：

        这个编程任务必须在进行下面的课程之前独立完成，因为后面的课程中，需要通过这个实验而获得的编程经验。

        编程：在屏幕中间分别显示绿色、绿底红色、白底蓝色的字符串'welcome to masm!'。

        编程所需的知识通过阅读、分析下面的材料获得。

        80x25彩色字符模式显示缓冲区（以下简称为显示缓冲区）的结构：

        内存地址空间中，B8000H~BFFFFH共32KB的空间，为80x25彩色字符模式的显示缓冲区。向这个地址空间写入数据，写入的内容将立即出现在显示器上。

        在80x25彩色字符模式下，显示器可以显示25行，每行80个字符，每个字符可以有256种属性（背景色、前景色、闪烁、高亮等组合信息）

        这样，一个字符在显示缓冲区中就要占两个字节，分别存放字符的ASCII码和属性。80x25模式下，一屏的内容在显示缓冲区中共占4000个字节。

        显示缓冲区分为8页，每页4KB（≈4000B），显示器可以显示任意一页的内容。一般清空下，显示第0页的内容。也就是通常情况下，B8000H~B8F9FH中的4000个字节的内容将出现在显示器上。

        在一页的显示缓冲区中：

        偏移000~09F 对应显示器上的第1行（80个字符占160字节）；

        偏移0A0~13F对应显示器上的第2行；

        偏移140~1DF对应显示器上的第3行。

        依次类推，可知，偏移F00~F9F对应显示器上的第25行。

        在一行中，一个字符占两个字节的存储空间（一个字），低位字节存储字符的ASCII吗，高位字节存储字符的属性。一行共有80个字符，占160字节。

        即在一行中：

        00~01 单元对应显示器上的第1列；

        02~03 单元对应显示器上的第2列；

        04~05 单元对应显示器上的第3列；

        依次类推，可知，9E~9F 单元对应显示器上的第80列。

       例：在显示器的0行0列显示黑底绿色的字符串'ABCDEF'

       （'A'的ASCII码值为41H，02H表示黑底绿色）

       显示缓冲区里的内容为：

                          00  01  02  03  04  05  06  07  08  09  0A  0B   . . . 0E  0F

       B800:0000  41  02  42  02  43  02  44  02  45  02  46  02   . . .  . .   . .

       ...      

       B800:00A0  . .   . .   . .   . .   . .   . .   . .   . .   . .   . .   . .   . .   . . .  . .   . .

       可以看出，在显示缓冲区中，偶地址存放字符，奇地址存放字符的颜色属性。

       一个在屏幕上显示的字符，具有前景（字符色）和背景（底色）两种颜色，字符还可以以高亮度和闪烁的方式显示。前景色、背景色、闪烁、高亮等信息被记录在属性字节中。

       属性字节的格式：

                        7        6        5        4       3       2        1       0     

       含义：      BL      R       G       B        I       R       G       B

                       闪烁       背景               高亮        前景

       R：红色

       G：绿色

       B：蓝色

       可以按位设置属性字节，从而配出各种不同的前景色和背景色。

       比如：

       红底绿色：属性字节为：01000010B；

       红底闪烁绿色，属性字节为：11000010B；

       红底高亮绿色，属性字节为：01001010B；

       黑底白色，属性字节为：00000111B；

       白底蓝色，属性字节为：01110001B。

       例：在显示器的0行0列显示红底高亮闪烁绿色的字符串'ABCDEF'

       (红底高亮闪烁绿色，属性字节为：11001010B-->CAH)

       显示缓冲区里的内容为：

                               00  01  02  03  04  05  06  07  08  09  0A  0B  ...  9E  9F

       B800：0000    41 CA  42 CA 43 CA 44 CA 45 CA 46 CA ....

       ...

       B800：00A0

       注意：闪烁的效果必须在全屏DOS的方式下才能看到。

程序代码：

assume cs:code,ds:data,ss:stack

data segment
    db 'welcome to masm!'  ;字符串(0~0Fh)
    db 02h,24h,71h  ;显示样式(10h~12h)
data ends

stack segment
    dw 8 dup (0)  ;16个字节大小的栈
stack ends

code segment
  start: mov ax,data
         mov ds,ax  ;ds指向data段
         mov ax,stack
         mov ss,ax  ;ss指向stack段
         mov sp,10h  ;栈顶指向10h
         
         mov ax,0b800h
         mov es,ax  ;es指向彩色字符模式显示缓冲区段（修改该段数据显示字符串）

         mov si,0  ;si指向data段数据（0~10h:字符串）（10h~12h:样式）
         mov di,1660  ;di指向es段数据（1660从屏幕中间开始）
         mov bx,10h  ;bx指向第一个样式

         mov cx,3  ;3行数据
     s1: push cx  ;保存cx大循环值

         mov cx,16  ;字符串含有16个字符
     s0: mov al,ds:[si]  ;字符ASCII码保存在ax的低字节
         mov ah,ds:[bx] ;样式信息保存在ax的高字节
         mov es:[di],ax  ;ds段数据（字符+样式）copy到es段
      
         inc si  ;si指向下一个字符
         add di,2  ;di也指向下一个字符（显示缓冲区的一个字符占两个字节）
         loop s0
         ;将字符串复制到es段中，并设置样式

         mov si,0  ;进入下一行字符串显示，si重新指向ds：0000
         add di,128  ;下一行字符串显示的地址
         pop cx
         inc bx
         loop s1
         ;进入下一行循环

         mov ax,4c00h
         int 21h
code ends
end start

运行结果：