最近在看王爽老师的汇编语言,写的确实很好,简单易懂,引人入胜!相比较我们学校一些老师的书籍,那简直是··· 惨绝人寰
先说一下思路:
题目的简单表述就是:将一个段的内容复制到另一个段,不过要排列成固定的形式,然后还要做一个计算,并且将结果也保存在后面的段中。
数据的读取:
汇编源程序中定义的同一个段中的数据是连续排放的(不同的段中的数据则会另起一个地址),所以我们可以将data段中的数据看成三个连续排放的数组:
- 它们各自的起始地址不一样。
- 因为数组成员的长度不一样,所以需要两个变量控制各个数组内成员的访问,si、di。
数据的存入:
table段是一个具有21个同一个结构的布局,所以可以用C语言中的结构体数组来看待它:
- 用一个变量来控制各个数组成员的访问,bx
- 在结构体内部直接加上相对偏移地址即可。
除法操作:
按顺序存入年份、收入之后,先不慌存入雇员数,因为此时ax、dx寄存器中正好存储的是收入,所以随之将人均收入计算出来并存入,随后再存入雇员数。
assume cs:code
data segment
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
dw 11542,14430,15257,17800
data ends
table segment
db 21 dup ('year summ ne ?? ')
table ends
code segment
start: mov ax,data
mov ds,ax
mov ax,table
mov es,ax
mov ax,0
mov bx,0
mov dx,0;存储四字节数据的高两字节
mov si,0
mov di,0
mov cx,21
s:mov ax,[si];年份
mov es:[bx],ax
mov dx,[si+2]
mov es:[bx+2],dx
mov ax,[84+si];收入。84 = 4字节*21
mov es:[bx+5],ax
mov dx,[84+si+2]
mov es:[bx+7],dx
div word ptr [168+di];平均工资。先计算人均收入。168 = 84+ 4字节*21
mov es:[bx+13],ax
mov ax,[168+di];雇员
mov es:[bx+10],ax
add bx,16;bx控制结构体数组成员的存入
add si,4;si控制年份、收入的读取
add di,2;di控制雇员数的读取
loop s
mov ax,4c00h
int 21h
code ends
end start
程序完成之后,我也搜了一些其他人的程序,各式各样,有多个loop的、有用到栈的,反观我自己写的程序,我觉得没必要那么复杂,简单的思路足矣。
补充:将loop那段程序改写得更加结构化如下:
s:mov ax,[si]
mov es:[bx],ax
mov dx,[si+2]
mov es:[bx].2,dx;结构体
mov ax,84[si];数组
mov es:[bx].5,ax
mov dx,84[si+2]
mov es:[bx].7,dx
div word ptr 168[di]
mov es:[bx].13,ax
mov ax,168[di]
mov es:[bx].10,ax
add bx,16
add si,4
add di,2
loop s