BZOJ 1833 & POJ 2282 The Counting Problem & huangyueying 贪心详解

huangyueying 是今天考试的一道题，除了数据范围比POJ大以外，完全就是一道题=。=

暴力的算法是一个一个的去算，显然会T =。=

所以，我们可以运用前缀和的思想来解决[a,b]之间的询问

我们在计算前保证a<=b

我们先算出[1,a-1] 0~9 出现的次数在算出[1,b] 之间0~9 出现的次数，再用后者减去前者就是[a,b]之间的数字，就是我们所需要的答案=w=

那么，怎么算呢 0.0

正常的数字是1、2、3……23、101……，

但是在这里，我们会发现一个规律：如果算上前导0，从0~9,00~99,000~999,0000~9999,00000~99999……即x位0~x位9 之间，每个数字出现的次数是一样一样的=w=

究竟次数是多少呢？0000~9999为例，我们发现每一个数字都有4位即它是由4个0~9之间的数字组成，而0000~9999一共有10000个这样的数字，

所以我们一共出现了 4*10000 个 0~9之间的数，而0~9每个数字出现的次数又是一样的，

所以每个数字出现的次数=4*10000/10

那么这就是个非常优美的规律的了=w=

让我们举个栗子，比如54732 ，我们一位一位的去处理，比如说第一位是5，易知第一位是0~4的个有10000个数，所以ans[0]~ans[4] 都加上10000；

但是5我们还没有处理，第一位是5的究竟有多少个数呢？显然是从50000~54732 一共 4732+1=4733个数，所以ans[5] 加上4733；

这时，我们仅仅完成了00000~54732 万位上的数字统计，那么后4位呢？

对于54732的后四位，我们在做到那一位的时候进行处理（就如5一样,有733个4，33个7,3个3,1个2）；

接下来就要处理00000~49999之间的后四位的数字统计，

就要用到我们刚才找到的那个优美的规律了=w=

我们来看后四位，当万位是0~4 时， 我们会发现我们数了5遍的 0000~9999，而在0000~9999之间，每个数字出现了多少次我们在刚才已经知道怎么算了，

所以把ans[0]~ans[9]都加上我们刚才得到的结论就可以了。

接下来我们处理54732的千位4,同上...

接下来我们处理54732的百位上的7，同上..

接下来我们处理54732的十位上3.，同上...

接下来我们处理54732的个位2，同上....

我们在完成这个大数的统计后，我们要减去我们多算了很多的前导0

那么我们究竟多算了多少前导0呢？

在最高位5的时候我们多算了10000个，在千位4的时候，我们多算了1000个，在百位的时候，我们多算了100个，在算到10位的时候，我们多算了10个，算到个位，我们多算了1个

所以我们一共多算了10000+1000+100+10+1个，减去这么多的ans[0]就行了

于是，一不小心就A了

注意，处理时只能用for循环而不能用while循环去对x取模，

比如500201，如果是取模的话500201处理完第一位后会直接处理201，肯定是不对的QAQ

所以，对于这种每次处理最高位的就老老实实用for循环就好了，千万不要取模

bzoj 1833

const
        num:array[1..13] of int64=(1,10,100,1000,10000,100000,1000000,10000000,100000000,1000000000,10000000000,100000000000,1000000000000);

var
        a,b,x           :int64;
        i               :longint;
        r,l,ans         :array[0..10] of int64;
procedure work(x:int64);
var
        s:string;
        len,t:longint;
        i,j:longint;
begin
   str(x,s);
   len:=length(s);
   for i:=1 to len do
   begin
      val(s[i],t);
      for j:=0 to t-1 do inc(ans[j],num[len-i+1]);
      inc(ans[t],x mod num[len-i+1]+1);
      for j:=0 to 9 do inc(ans[j],t*(len-i)*num[len-i+1] div 10);
   end;
   for i:=1 to len do dec(ans[0],num[i]);
end;

begin
   read(a,b);
   //
   work(b);
   r:=ans;
   fillchar(ans,sizeof(ans),0);
   work(a-1);
   l:=ans;
   for i:=0 to 8 do write(r[i]-l[i],' ');
   writeln(r[9]-l[9]);
end.

POJ2282的代码

const
    num:array[1..10] of longint=(1,10,100,1000,10000,100000,1000000,10000000,100000000,1000000000);
var
    a,b                 :longint;
    i                   :longint;
    l,ans,r,x           :array[0..10] of longint;
procedure swap(var a,b:longint);
var
    c:longint;
begin
   c:=a;a:=b;b:=c;
end;

procedure work(xx:longint);
var
    i,j:longint;
    l:longint;
    s:string;
begin
   fillchar(ans,sizeof(ans),0);
   str(xx,s);
   l:=length(s);
   for i:=1 to l do val(s[i],x[i]);
   for i:=1 to l do
   begin
      for j:=0 to x[i]-1 do inc(ans[j],num[l-i+1]);
      inc(ans[x[i]],xx mod num[l-i+1]+1);
      for j:=0 to 9 do inc(ans[j],x[i]*((l-i)*num[l-i+1] div 10));
   end;
   for i:=1 to l do dec(ans[0],num[i]);
end;
//
begin
   read(a,b);
   while (a<>0) and (b<>0) do
   begin
      if (a>b) then swap(a,b);
      work(a-1);
      l:=ans;
      work(b);
      r:=ans;
      for i:=0 to 8 do write(r[i]-l[i],' ');
      writeln(r[9]-l[9]);
      read(a,b);
   end;
end.

                        

  ——by Eirlys

转载请注明出处=w=