1490. 士兵（jzoj）

题目：

题目描述

在Gridland国家，有N个处于不同位置的士兵。该国上的地方都用两个坐标（X，Y）来表示。士兵能进行一次移动，每个士兵都可向上、向下、向左、或向右移动一个单位长，这样他就能把自己的X或Y改变1或-1。

士兵们想进入一个水平线，彼此靠近，这样他们的最后位置就是（X，Y）、（X+1，Y），…，（X+N，Y））。水平线上的士兵的最后顺序以及整数X和Y，都是任意的。

现在目标是求如此配置士兵的最少移动数。

两个或两个以上的士兵在同一时间不处于同一位置。

输入

输入文件soldiers.in的第一行含有一个整数N，1 <= N <=10000,N为士兵的数量。输入文件以后的N行应含有士兵的初始位置，对于每一个i, 1<= i <= N,输入文件的第I+1行含有两个用空格分开的整数x[i],y[i]，他们表示第I个士兵的坐标，-10000<=x[i],y[i] <=10000.

输出

输出文件soldiers.out仅有一行，它的值为使士兵移动到水平线彼此相邻的最小移动次数。

样例输入

5
1 2
2 2
1 3
3 -2
3 3

作者思路：排序，确定位置（要移动到的位置）计算多少步。

代码：

type arr=array[0..10001] of longint;
var x,y:arr;
    n,i,s1,s2:longint;
procedure qsort(l,r:longint;var a:arr);
var i,j,mid,t:longint;
begin
  if l>=r then exit;
  i:=l; j:=r; mid:=a[(l+r) div 2];
  repeat
    while a[i]<mid do inc(i);
    while a[j]>mid do dec(j);
    if i<=j then
    begin
      t:=a[i];a[i]:=a[j];a[j]:=t;
      inc(i); dec(j);
    end;
  until i>j;
  qsort(l,j,a);
  qsort(i,r,a);
end;

begin
  assign(input,'soldiers.in');
  assign(output,'soldiers.out');
  reset(input);
  rewrite(output);
  read(n);
  for i:=1 to n do read(x[i],y[i]);
  qsort(1,n,x);
  qsort(1,n,y);
  for i:=1 to n do x[i]:=x[i]-i+1;
  qsort(1,n,x);
  for i:=1 to n do
  begin
    s1:=s1+abs(x[i]-x[(n+1) div 2]);
    s2:=s2+abs(y[i]-y[(n+1) div 2]);
  end;
  //for i:=1 to n do if i<>m
  write(s1+s2);
  close(input);
  close(output);
end.