1)install_node.bat 文件内容如下
- 只需要修改 NODE_VERSION、INSTALL_DIR 这2个变量为自己要安装的版本和安装目录即可使用
- 启动该脚本需要右键以管理员身份运行
@echo off
setlocal enabledelayedexpansion
set NODE_VERSION=20.13.1
set INSTALL_DIR=D:\develop
set NODE_FILENAME=node-v%NODE_VERSION%-win-x64
set DOWNLOAD_URL=https://nodejs.org/dist/v%NODE_VERSION%/%NODE_FILENAME%.zip
set NODE_HOME=%INSTALL_DIR%\%NODE_FILENAME%
set NODE_GLOBAL=%NODE_HOME%\node_global
set NODE_CACHE=%NODE_HOME%\node_cache
:: 1. 下载 zip 包
echo 正在下载 Node.js %NODE_VERSION%...
powershell -Command "Invoke-WebRequest -Uri %DOWNLOAD_URL% -OutFile %~dp0%NODE_FILENAME%.zip"
:: 2. 解压 zip 包
echo 正在解压 Node.js 压缩包...
powershell -Command "Expand-Archive -Path %~dp0%NODE_FILENAME%.zip -DestinationPath %INSTALL_DIR%"
:: 3. 创建 node_global 和 node_cache 文件夹
echo 创建 node_global 和 node_cache 文件夹...
mkdir %NODE_GLOBAL%
mkdir %NODE_CACHE%
:: 4. 配置环境变量
echo 配置环境变量...
setx PATH "%PATH%;%NODE_HOME%;%NODE_GLOBAL%" /M
:: 5. 配置 npm 下载和缓存路径为家目录
echo 配置 npm 下载和缓存路径为家目录...
%NODE_HOME%\node.exe %NODE_HOME%\node_modules\npm\bin\npm-cli.js config set prefix "%NODE_GLOBAL%"
%NODE_HOME%\node.exe %NODE_HOME%\node_modules\npm\bin\npm-cli.js config set cache "%NODE_CACHE%"
:: 6. 删除已下载的压缩包
echo 删除已下载的压缩包...
del %~dp0%NODE_FILENAME%.zip
echo Node.js %NODE_VERSION% 已成功安装和配置。
pause
2)打开 cmd 窗口人工验证
node -v # 验证 node 命令和版本
npm -v # 验证 npm 命令和版本
npm config list # 查看 cache 和 prefix 目录是否正确
3)修改镜像(可选)
- 修改为淘宝镜像
npm config set registry https://registry.npmmirror.com
npm config get registry
# 安装 cnpm,可选
npm install -g cnpm
- 还原为官方镜像
npm config set registry https://registry.npmjs.org
npm config get registry