ANSYS 有限元分析 修改与编辑

Blog Links

• DalNur | 博客总目录

• ANSYS 有限元分析 概述

• ANSYS 有限元分析 坐标系/工作平面

• ANSYS 有限元分析 几何建模

• ANSYS 有限元分析 网格划分

• ANSYS 有限元分析 选择与组件

• ANSYS 有限元分析 修改与编辑

• ANSYS 有限元分析 接触分析

• ANSYS 有限元分析 加载/求解/输出

• ANSYS 有限元分析 后处理 General Postproc

• ANSYS 有限元分析 后处理 结点解与单元解

• ANSYS 有限元分析 命令流 实例

• ANSYS 静力 分析实例 悬臂梁

• nCodeDL 高周疲劳 分析实例 悬臂梁

一、前言

二、删除

2.1 删除结点

1. 删除结点

  GUI： Main Menu >> Preprocessor >> Modeling >> Delete 。

2.2 删除组件

CMDELE,WasherVols                  ! 删除组件WasherVols

三、镜像

3.1 镜像几何体

• VSYMM

使用功能： 通过对坐标轴对称镜像生成体。

使用格式： VSYMM，Ncomp，NV1，NV2，NINC，KINC，NOELEM，IMOVE 。

参数说明： Ncomp 为对称控制选项，Ncomp = X，Y 或 Z，镜像平面的法线方向。

      NV1，NV2，NINC 为按增量 NINC 从 NV1 到 NV2 将要进行对称镜像的体编号的范围，其中 NV1 也可以为 ALL、P 或元件名。

      IMOVE： 设置是否删除/新定义体，若为 0，保留原来的体，生成额外的体，若为 1，删除原来的体，创建新的体。

类似命令： KSYMM、LSYMM、ARSYM 。

参考实例： 体关于局部坐标直角坐标系 15 的 xoz 平面镜像，并保留原体。

---

  上接 命令流 No.8 ，命令流 No.9 见博客： ANSYS 有限元分析 几何建模 >> 五、几何体 >> 5.1 由面拉伸为体。

---

CSYS,15                           ! 激活局部直角坐标系15
VSYMM,Y,ALL, , , ,0,0             ! 对所有几何体进行镜像操作，镜像平面为xoz平面。

命令流 No.9

  由 命令流 No.9 创建的镜像体如下图所示：

  值得注意的是，镜像体的同时，体的附属网格也随之实现镜像，如下图所示：

3.2 镜像单元

四、阵列

  ANSYS中没有直接实现矩形阵列或环形阵列的命令，而是通过在不同局部坐标系下进行阵列来实现的，例如：在局部直角坐标系下能实现矩形阵列，在局部柱坐标系能实现环形阵列。

4.1 阵列几何线

• LGEN

使用功能： 对几何线进行复制操作，在不同的坐标系中可实现平移阵列和环形阵列。

使用格式： LGEN，ITIME，NV1，NV2，NINC，DX，DY，DZ，KINC，NOELEM，IMOVE 。

参数说明： ITIME 为重复生成的次数，默认值为2，若设置为 n，则另外生成 n-1 条线。

      NV1，NV2，NINC 为按增量 NINC 从 NV1 到 NV2 将要进行复制的线编号的范围。

      其中 NV1 也可以为 ALL、P 或元件名。

      DX，DY，DZ 为在当前激活坐标系中，线中各关键点坐标值的偏移量。

      KINC 为要生成关键点编号的增量，如果其值为 0，由系统自动给定。

      NOELEM 为是否也生成单元和节点的控制键，若为 0，如果存在相关的节点和单元，也生成相关的节点和单元；

      若为 1，不生成节点和单元。

      IMOVE： 设置是否删除/新定义线，若为 0，保留原来的线，生成额外的线，若为 1，删除原来的线，创建新的线。

参考实例： 在局部柱坐标系 17 下阵列螺栓杆几何及其附属单元。

---

  上接 命令流 No.16 ，命令流 No.16 见博客： ANSYS 有限元分析 网格划分 >> 六、创建网格 >> 6.1 创建梁单元。

---

CSYS,15                               ! 激活局部坐标系15
CLOCAL,17,1                           ! 根据激活的局部坐标系15定义新的局部柱坐标系17
CSYS,17                               ! 激活局部柱坐标系17
num = 55                              ! 螺栓总数
!LSEL,S,LINE, ,ALL                    ! 选择全部线
LGEN,4,ALL, , , ,360/num, , ,0        ! 执行阵列，额外阵列数为3。


ALLSEL,ALL

NUMMRG,ALL                            ! 对实体进行合并
NUMCMP,ALL                            ! 压缩所定义项的编号

/ESHAPE,0                             ! 关闭梁截面显示
/REPLOT                               ! Replot

ALLSEL,ALL,ELEM                       ! Selects all elements.
CM,BoltElems,ELEM                     ! 由所选实体生成一个组件
                                      ! 元件名称：BoltElems；元件中的数据类型：单元。

命令流 No.17

---

  下接 命令流 No.18 ，命令流 No.18 见博客： ANSYS 有限元分析 网格划分 >> 六、创建网格 >> 6.4 创建预紧单元。

---

  由 命令流 No.17 经阵列创建的螺栓杆梁单元如下图所示：

4.2 阵列几何体

• VGEN

使用功能： 对体进行复制操作，在不同的坐标系中可实现平移阵列和环形阵列。

使用格式： VGEN，ITIME，NV1，NV2，NINC，DX，DY，DZ，KINC，NOELEM，IMOVE 。

参数说明： ITIME 为重复生成的次数，默认值为2，若设置为 n，则另外生成 n-1 个体。

      NV1，NV2，NINC 为按增量 NINC 从 NV1 到 NV2 将要进行复制的体编号的范围。

      其中 NV1 也可以为 ALL、P 或元件名。

      DX，DY，DZ 为在当前激活坐标系中，体中各关键点坐标值的偏移量。

      KINC 为要生成关键点编号的增量，如果其值为 0，由系统自动给定。

      NOELEM 为是否也生成单元和节点的控制键，若为 0，如果存在相关的节点和单元，也生成相关的节点和单元；

      若为 1，不生成节点和单元。

      IMOVE： 设置是否删除/新定义体，若为 0，保留原来的体，生成额外的体，若为 1，删除原来的体，创建新的体。

参考实例： 在局部柱坐标系 17 下阵列法兰几何体，保留原有体并生成相关结点和单元。

CSYS,17                                      ! 激活局部柱坐标系17
num = 55                                     ! 螺栓总数
VGEN,4,ALL, , , ,360/num, , ,0               ! 复制体，重复生成次数4，复制全部体。
                                             ! 当前激活坐标系下，关键点坐标值的偏移量为（--，360/num,0）
                                             ! 单个偏转角度为360/num

/PNUM,ELEM,0                                 ! 关闭单元编号显示
/REPLOT                                      ! Replot
EPLOT                                        ! Elements plots

命令流 No.10

  由 命令流 No.10 经阵列创建的法兰几何体及附属单元如下图所示：

阵列生成的法兰几何体及其附属网格

参考实例 2： 在局部柱坐标系 17 下阵列垫片几何体，保留原有体并生成相关结点和单元。

---

  上接 命令流 No.14 ，命令流 No.14 见博客： ANSYS 有限元分析 网格划分 >> 六、创建网格 >> 6.3 创建体网格 >> 6.3.2 扫掠。

---

CSYS,18                               ! 激活局部直角坐标系18
tw = 5 $ tf = 40                      ! 分别为垫片厚度和法兰厚度
VSEL,S,VOLU, ,ALL                     ! 选择所有几何体
VGEN,2,ALL, , , 0,0, -(tw+2*tf)       ! 沿局部轴z轴阵列，坐标增量为-(tw+2*tf)，生成相关结点和单元。


CSYS,15                               ! 激活局部坐标系15
CLOCAL,17,1                           ! 根据激活的局部坐标系15定义新的局部柱坐标系17
CSYS,17                               ! 激活局部柱坐标系17
num = 55                              ! 螺栓总数
VSEL,S,VOLU, ,ALL                     ! 选择所有几何体
VGEN,4,ALL, , , ,360/num              ! 复制体，重复生成次数4。
                                      ! 当前激活坐标系下，关键点坐标值的偏移量为（--，360/num,0）
                                      ! 单个偏转角度为360/num


NUMMRG,ALL                            ! 对实体进行合并
NUMCMP,ALL                            ! 压缩所定义项的编号

ALLSEL,ALL,ELEM                       ! Selects all elements.
CM,WasherElems,ELEM                   ! 由所选实体生成一个组件
                                      ! 元件名称：WasherElems；元件中的数据类型：单元。

ALLSEL,ALL                            ! 全选 select all entities
CDWRITE,DB,'PartWasher','cdb',,'',''  ! 当前模型另存为 PartWasher.cdb 文件。

命令流 No.15

---

  下接 命令流 No.16 ，命令流 No.16 见博客： ANSYS 有限元分析 网格划分 >> 六、创建网格 >> 6.1 创建梁单元。

---

  由 命令流 No.15 经阵列创建的垫片几何体及附属单元如下图所示：

五、体切分

  可以用坐标平面/工作平面切分体。

六、合并与压缩

  几何及网格经镜像和阵列后，重合部分需要合并，为了节约计算资源，相应的结点编号及单元编号需要压缩为连续编号形式。

NUMMRG,ALL                                   ! 对实体进行合并
NUMCMP,ALL                                   ! 压缩所定义项的编号


! 以下为创建组件，输出.cdb文件，为后续建模做准备。


ALLSEL,ALL,ELEM                              ! Selects all elements.
CM,TopFlangeElems,ELEM                       ! 由所选实体生成一个组件
                                             ! 元件名称：TopFlangeElems；元件中的数据类型：单元。


CSYS,16                                      ! 激活局部柱坐标系16
CLOCAL,19,0                                  ! 创建局部直角坐标系19

VSYMM,Z,ALL, , , ,0,0                        ! 对所有几何体进行镜像操作，镜像平面为局部坐标系19的xoY平面。


ALLSEL,ALL,ELEM                              ! Selects all elements.
CMSEL,U,TopFlangeElems                       ! 上一选择集中除去组件TopFlangeElems内的单元
CM,BotFlangeElems,ELEM                       ! 由所选实体生成一个组件
                                             ! 元件名称：BotFlangeElems；元件中的数据类型：单元。


ALLSEL,ALL                                   ! 全选 select all entities
CDWRITE,DB,'PartFlange','cdb',,'',''         ! 当前模型另存为 PartFlange.cdb 文件。

命令流 No.11

---

  接下来，将进行垫片部分的创建，下接 命令流 No.12 ，命令流 No.12 见博客： ANSYS 有限元分析 几何建模 >> 五、几何体 >> 5.2 创建(空心)圆柱体 。

---

  命令流 No.1 ~ 命令流 No.11 完成了法兰单元的创建，如下图所示：

  组件的创建，详见博客： ANSYS 有限元分析 选择与组件 。

  .odb 文件的输出，详见博客： ANSYS 有限元分析 概述 。

  创建的 PartFlange.cdb 相当于 Abaqus 中的 Part，创建的名为 FlangeElems 的 Component 相当于 Part 内的一个集合，集合由单元组成。按此种方式建模，有利于降低错误的发生率及方便后续引用。一个 Part 一个 Part 的创建，最后再统一装配。

  编号压缩命令执行前后，材料编号及单元类型号的变化如下图所示：

左侧材料编号 右侧单元类型号

• NUMMRG

使用功能： 对实体进行合并 / Merges coincident or equivalently defined items 。

使用格式： NUMCMP，Labels，TOLER，GTOLER，Action，Switch。

参数说明： Labels 为合并操作选项。

  合并操作选项可以为：NODE(节点)、ELEM(单元)、KP(关键点)、MAT(材料编号)、TYPE(单元类型)、REAL(实常数)、CP(耦合)、CE(约束方程) 或 ALL(以上全部)。体合并亦可采用命令 VGLUE，详见： ANSYS 有限元分析 几何建模 >> 六、布尔操作 >> 6.1 Merge 。

• NUMCMP

使用功能： 压缩所定义项的编号 / Compresses the numbering of defined items 。

使用格式： NUMCMP，Labels。

参数说明： Labels 为合并操作选项，具体含义同上。

七、尾声

  以上，便是 ANSYS 修改与编辑 部分的简单介绍。

  仅以此文为我 ANSYS 的相关学习做一个备忘，同时也为有需要的人提供多一点参考。

  胸藏文墨怀若谷，腹有诗书气自华，希望各位都能在知识的 pāo 子里快乐徜徉。

  因个人水平有限，文中难免有所疏漏，还请各位大神不吝批评指正。

  最后，祝各位攻城狮们，珍爱生命，保护发际线！

  欢迎大家点赞、评论及转载，转载请注明出处！

  为我打call，不如为我打款！

---

八、参考文献

[1]. ANSYS 15.0 有限元分析完全自学手册. 郝勇 钟礼东 等编著.

[2]. ANSYS 参数化编程与命令手册. 龚曙光 谢桂兰 黄云清 编著.

[3]. ANSYS Mechanical APDL Command Reference. Release 18.2.

[4]. ANSYS Mechanical APDL Element Reference. Release 18.2.