ANSYS 有限元分析 后处理 General Postproc

最新推荐文章于 2024-05-14 17:45:19 发布
最新推荐文章于 2024-05-14 17:45:19 发布
阅读量9.8k 收藏 57
点赞数 11
分类专栏： ANSYS 文章标签： ANSYS 后处理 应力云图
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/Hulunbuir/article/details/107033546
版权

目 录




Blog Links





一、前言


    后处理一般是由 ANSYS 后处理器或其他后处理程序实现的，后处理器读入二进制文件 (.rst文件)，可以用各种各样方式显示结果，如彩色等值线图、动画、应力云图、位移云图等。


  .rst文件为二进制文件，是结构与耦合分析结果数据的存储文件。


  ANSYS 提供了两个后处理器：通用后处理器 (POST1) 和 时间历程后处理器 (POST26)。

  通用后处理器 (POST1)：用来观察整个模型在某一时刻的结果。

  时间历程后处理器 (POST26)：用来观察整个模型在不同时间段或荷载步上的结果，常用于处理瞬态分析和动力分析结果。


  rst 文件内有许多数据组 (data set)，每一数据组代表一个时间点的反应输出值，/POST1 模块是用来处理某一数据组的。/POST1 是针对某一时间点，反应值在空间上的分布；/POST26 模块是针对某一空间点，反应值在时间上的变化。



  本文以某一法兰连接的计算结果为例，来介绍 ANSYS 中常见的通用后处理操作。法兰连接有限元模型创建与求解的全部命令见博客： ANSYS 有限元分析 命令流 实例 。依次运行该博客第二部分至第六部分的命令流便可得到如下图所示的 8 个计算结果文件。这 8 个计算结果文件分别为 BoltPreloadCase.rst、LoadCase1.rst ~ LoadCase7.rst 。其中，BoltPreloadCase.rst 为结构仅在螺栓预紧力作用下的计算结果文件，LoadCase1.rst ~ LoadCase7.rst 为结构在螺栓预紧力和附加外载共同作用下的计算结果文件。


在这里插入图片描述




二、变形形状


FINISH                                ! 退出当前处理器
/CLEAR,ALL                            ! 清除所有
FINISH                                ! Exits normally from a processor.
/PREP7                                ! 访问前处理器
*AFUN,DEG                             ! 设置角度单位为度
SHPP,OFF,,NOWARN                      ! 关闭单元形状检测警告

CDREAD,DB,'AllAsmbs','cdb',,'',''     ! 导入装配体模型

FINISH

/POST1

INRES,ALL   
FILE,'BoltPreloadCase','rst','.'      ! 读取BoltPreloadCase.rst文件
SET,LAST                              ! Read results >> Last Set


PLDISP, 2                             ! 显示结构变形形状且重叠显示结构变形前后的形状。

在这里插入图片描述


在这里插入图片描述

GUI操作 

CMSEL,S,BotFlangeElems                ! 选择组件
PLDISP, 2                             ! 显示结构变形形状且重叠显示结构变形前后的形状。

在这里插入图片描述



三、Contour Displays 云图显示


  General Postprocessor (POST1) ： /POST1模块是用来处理某一数据组的，是针对某一时间点，反应值在空间上的分布。


  Nodal Solution / Element Solution 结点解与单元解的区别详见： ANSYS 有限元分析 后处理 结点解与单元解 。


E


Contour displays show how a result item (such as stress, temperature, magnetic flux density, etc.) varies over the model. Four commands are available for contour displays:

  • PLNSOL – Displays solution results as continuous contours

  • PLESOL – Displays solution results as discontinuous element contours

  • PLETAB – Displays element table items

  • PLLS – Displays element table items as contoured areas along elements


  PLESOL 命令绘制的云图的等应力线 (contour lines) 呈锯齿状，PLNSOL 命令绘制的云图的等应力线平滑连续。


  PLNSOL (plot nodal solutions)

  PLESOL (plot element solutions)



3.1 显示连续云图 PLNSOL


The PLNSOL command produces contour lines that are continuous across the entire model. Use either for primary as well as derived solution data. Derived solution data, which are typically discontinuous from element to element, are averaged at the nodes so that continuous contour lines can be displayed.


   显示 y 方向的位移云图，命令流如下。


FINISH                                ! 退出当前处理器
/CLEAR,ALL                            ! 清除所有
FINISH                                ! Exits normally from a processor.
/PREP7                                ! 访问前处理器
*AFUN,DEG                             ! 设置角度单位为度
SHPP,OFF,,NOWARN                      ! 关闭单元形状检测警告

CDREAD,DB,'AllAsmbs','cdb',,'',''     ! 导入装配体模型

FINISH

/POST1

INRES,ALL   
FILE,'LoadCase4','rst','.'            ! 读取LoadCase4.rst文件
SET,LAST                              ! Read results >> Last Set


PLNSOL, U, Y,                         ! 绘制y方向位移云图
/EDGE,1,0                             ! 仅显示边缘轮廓(对于等值线显示)
/REPLOT

在这里插入图片描述


   显示，结点解的 Mises 应力云图，命令流如下。


PLNSOL, S, EQV                        ! 绘制Miese应力云图
!PLNSOL, S, X                         ! 绘制x方向连续正应力云图
/EDGE,1,1                             ! 显示所有单元面之间的公共线(对于等值线显示)
/REPLOT                               ! Replot

在这里插入图片描述



3.2 显示不连续云图 PLESOL


   显示，单元解的 Mises 应力云图，命令流如下。


PLESOL, S,  EQV                       ! 绘制Miese应力云图
/GLINE,1,-1                           ! 隐藏单元边线
/REPLOT                               ! Replot

在这里插入图片描述


3.3 梁单元应力云图的显示


  特别注意： 显示梁单元应力云图前一定要先显示梁的截面，否则无法显示其应力云图。


FINISH                                ! 退出当前处理器
/CLEAR,ALL                            ! 清除所有
FINISH                                ! Exits normally from a processor.
/PREP7                                ! 访问前处理器
*AFUN,DEG                             ! 设置角度单位为度
SHPP,OFF,,NOWARN                      ! 关闭单元形状检测警告

CDREAD,DB,'AllAsmbs','cdb',,'',''     ! 导入装配体模型

FINISH

/POST1

INRES,ALL   
FILE,'LoadCase5','rst','.'            ! 读取LoadCase4.rst文件
SET,LAST                              ! Read results >> Last Set


CMSEL,S,BoltElems                     ! 选择组件

/ESHAPE,1                             ! 显示梁截面

PLNSOL, S, EQV                        ! 绘制Miese应力云图

/GLINE,1,-1                           ! 隐藏单元边线
/REPLOT                               ! Replot

在这里插入图片描述



四、内力提取


4.1 梁单元内力的提取


  梁单元各内力的方向默认采用梁的局部坐标系，梁的局部坐标系是按如下方式确定的：轴线为局部x轴，局部z轴在建模时指定，局部y轴由右手系确定。通常，采用梁的默认坐标即可，无需特别指定结果坐标系。


  以下命令流将实现： 提取 8 个工况下各螺栓的内力，在此基础上计算每个螺栓的 Mises 应力，并输出计算结果到 txt 文件中。命令流如下：


FINISH                                ! 退出当前处理器
/CLEAR,ALL                            ! 清除所有
FINISH                                ! Exits normally from a processor. 
/PREP7                                ! 访问前处理器
*AFUN,DEG                             ! 设置角度单位为度
SHPP,OFF,,NOWARN                      ! 关闭单元形状检测警告

CDREAD,DB,'AllAsmbs','cdb',,'',''     ! 导入装配体模型


/com,******************** 1. 螺栓参数 ********************


pi = 3.14159265
As = 1120                             ! 应力面积
de = SQRT(As*4/pi)                    ! 有效直径
d = 42                                ! 公称直径
d2 = 39.08                            ! 螺纹中径
p = 4.5                               ! 螺纹螺距
num = 4                               ! 螺栓个数
loadCaseNum = 7                       ! 工况个数
preload=790*1000                      ! 预紧力

W = pi*(de**3)/32.0                   ! 抗弯截面模量
Wt = 2*W                              ! 抗扭截面模量

! 螺栓等效应力计算

/POST1

num = 55                              ! 螺栓总数
radius = 1000                         ! 法兰螺栓分度圆半径
tf = 40 $ tw = 5                      ! 分别为法兰厚度及垫片厚度
startPntZ = -(tf+tw)                  ! 在局部坐标系15下，梁轴线起点z坐标值。
midPntZ = 0                           ! 螺栓预紧力施加位置处(梁单元预紧位置点)
endPntZ= tf+tw                        ! 在局部坐标系15下，梁轴线终点z坐标值。
d0 = 40                               ! 螺栓孔直径/垫片内径
d1 = 70                               ! 垫片外径
calBoltNum = 4                        ! 模型中螺栓个数


*DEL,boltResults
*DIM,boltResults,ARRAY,calBoltNum,9   ! 矩阵维度：calBoltNum行9列1页；Table Array 名称为：boltResults。


torsion = preload*d2*(p/(pi*d2)+1.155*0.09)/2   ! 预紧扭矩 VDI2230-Part1
tau = torsion/wt                                ! 预紧扭转剪应力

/COPY, 'BoltPreloadCase','rst','','LoadCase0','rst',''  ! 复制预紧力工况结果文件


/com,************* 2. 内力提取并计算等效应力 *************


*DO,i,0,loadCaseNum,1 

    ! 工况循环

    FILE,LoadCase%i%,'rst'   ! .rst文件名
    INRES,ALL                ! 从结果文件中读取全部数据
    SET,LAST                 ! 从结果文件中读取最后一个荷载步的数据

    loadCaseNum = i
  
    *DO,j,1,calBoltNum,1

        ! 螺栓循环

        CSYS,17
        ESEL,S,ENAME,,189               ! 选择189单元
        ALLSEL,BELOW,ELEM               ! 选择单元附属结点
        startAngle = (360/num)*(j-1)-(360/num/2-1)
        endAngle = (360/num)*(j-1)+(360/num/2-1)
        NSEL,R,LOC,Y,startAngle,endAngle
        NSEL,R,LOC,Z,startPntZ+7.5-0.5,startPntZ+2*7.5+0.5
        ESLN,R,1                        ! 单元全部结点被选中该单元才被选中
        *GET,elenum,ELEM,,NUM,Min       ! 获取梁单元编号



        ETABLE,ForceX,SMISC,1           ! 梁单元始端截面轴向力
        ETABLE,MomentY,SMISC,2          ! 梁单元始端截面绕局部y轴弯矩
        ETABLE,MomentZ,SMISC,3          ! 梁单元始端截面绕局部z轴弯矩

        ! ETABLE,ForceX,SMISC,14        ! 梁单元终端截面轴向力
        ! ETABLE,MomentY,SMISC,15       ! 梁单元终端截面绕局部y轴弯矩
        ! ETABLE,MomentZ,SMISC,16       ! 梁单元终端截面绕局部z轴弯矩


        *GET,FxVal,ELEM,elenum,ETAB,ForceX       ! 获取梁单元终端截面轴向力数值
        *GET,MyVal,ELEM,elenum,ETAB,MomentY      ! 获取梁单元终端截面绕局部y轴弯矩数值
        *GET,MzVal,ELEM,elenum,ETAB,MomentZ      ! 获取梁单元终端截面绕局部z轴弯矩数值


        boltID = j                                      ! 螺栓编号

        MyzVal = SQRT( MyVal**2 + MzVal**2 )            ! 合弯矩

        sigmaN = ABS(FxVal/As)                          ! 拉压正应力绝对值
        sigmaM = MyzVal/W                               ! 弯曲正应力绝对值
        Sigma = sigmaN + sigmaM                         ! 最大正应力
        eqvStress = SQRT( Sigma**2 + 3*(0.5*tau)**2 )   ! VDI2230-Part1

        ALLSEL,ALL
        CSYS,17

        boltResults(j,1) = loadCaseNum
        boltResults(j,2) = boltID
        boltResults(j,3) = FxVal/1E3
        boltResults(j,4) = MyzVal/1E6
        boltResults(j,5) = sigmaN
        boltResults(j,6) = sigmaM
        boltResults(j,7) = sigma
        boltResults(j,8) = tau
        boltResults(j,9) = eqvStress

    *ENDDO

    !*
    !*  汇总计算结果输出
    !* 

    outFileName='BoltResultsLoadCase%i%'     ! 指定.txt文件名

    *CFOPEN,outFileName,'txt'                ! 打开文件LoadCase1BoltResults.txt

    *VWRITE,
    ('  LoadCaseNum    BoltNum    N (kN)    M (kN·m)    SigmaN (N/mm^2)    SigmaM (N/mm^2)    Sigma (N/mm^2)    Tau (N/mm^2)    EqvStress (N/mm^2)  ')

    *VWRITE,boltResults(1,1), boltResults(1,2),boltResults(1,3), boltResults(1,4), boltResults(1,5), boltResults(1,6), boltResults(1,7), boltResults(1,8), boltResults(1,9)
        (F9.1,F13.1, F12.2, F11.3, F16.2, F18.2, F19.2, F18.2, F19.2)

    *CFCLOS   

*ENDDO

  特别注意，以上命令流不要输入到 ANSYS Command Prompt 中执行，而是要采用 Read Input from . . . 方式运行，如下图所示，否则，无法全部顺利执行，原因是在数据输出时，指定了输出格式如 F9.1、F12.2等，这些格式为 Fortran 语言的数据格式，必须采用 Read Input from . . . 方式运行。


在这里插入图片描述



  该命令流运行后，将得到 8 个 .txt 文件，文件内存储这每个工况下，每个螺栓的计算结果数据，如下图所示。


在这里插入图片描述


在这里插入图片描述



4.2 截面内力的提取


  见博客： ANSYS 静力分析实例 悬臂梁 >> 五、截面内力提取 。



4.3 支座反力的提取


  见博客： ANSYS 静力分析实例 悬臂梁 >> 六、支座反力提取 。




五、结果查询


在这里插入图片描述



六、动画


在这里插入图片描述




七、尾声


  以上，便是 ANSYS 通用后处理 的简单介绍。

  因篇幅有限，某些内容未做详细介绍，如有疑问，欢迎邮件交流。

  Email： liyang@alu.hit.edu.cn 。

  仅以此文为我 ANSYS 及有限元相关理论的学习做一个总结。

  与此同时，也希望能够为初学者/有需要的人提供多一点参考。

  本文仅用于个人学习，除此之外，无其他任何用途。

  因个人水平有限，文中难免有所疏漏，还请各位大神不吝批评指正。

  胸藏文墨怀若谷，腹有诗书气自华，希望各位都能在知识的 pāo 子里快乐徜徉。

  本文逻辑清楚，内容详实，引例丰富。

  欢迎大家点赞、评论及转载，转载请注明出处！

  为我打call，不如为我打款！

  最后，祝各位攻城狮们，珍爱生命，保护发际线！



在这里插入图片描述




八、参考文献


[01]. 有限单元法. 王勖成 编著. 北京. 清华大学出版社. 2003.

[02]. 有限单元法教程. 王焕定 王伟 编著

[03]. Ansys中的节点解和单元解. 坐倚北风.

[04]. 节点解、单元解以及单元节点解. 长安CAE.

[05]. 有限元计算的节点解与单元解. 长安CAE.

[06]. 有限元计算的节点解与单元解的讨论续. 长安CAE.

[07]. 有限元计算的节点解与单元解的讨论再续 . 长安CAE.

[08]. 高斯积分点以及有限元中应用

[09]. Ansys高斯点（积分点）上的应力和软件插值后得到的应力比较. 坐倚北风.

[10]. 有限元原理与应用. 潘文.

[10]. ANSYS工程分析-基础与观念. 李辉煌





Hulunbuir
关注
  • 11
    点赞
  • 踩
  • 57
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 1
    评论
专栏目录
ANSYS——ANSYS后处理操作技巧与各类问题良心大总结
python_AI_fans的博客
05-26 2万+
目录 1.ANSYS后处理时如何按灰度输出云图？ 2 将云图输出为JPG 3.怎么在计算结果实体云图中切面? 4.非线性计算过程中收敛曲线实时显示 5.运用命令流进行计算时,一个良好的习惯是: 6.应力图中左侧的文字中，SMX与SMN分别代表最大值和最小值 7.在非线性分析中，如何根据ansys的跟踪显示来判断收敛？ 8.两个单元建成公共节点，就成了刚性连接，不是接触问题了。 9.接触单元 10.怎样检查接触单元的normal direction?是不是打开plotctrls/symbo
ansys后处理应用
08-06
这篇文章很好描述了nasys后处理的详细方法，对于入门者很有帮助
ANSYS学习4——后处理
loufand的博客
02-27 5139
通用后处理器只能显示某一步载荷 GUI：main menu>general poster 结果观察器GUI：main menu>general postroc>results viewer 时间历程后处理器post26模型当中指定点的分布结果与时间频率等的函数关系 报告生成器
ANSYS Workbench如何利用Python代码批量提取瞬态分析节点数据结果
最新发布
weixin_42305372的博客
05-14 1230
使用python脚本批量提取结果数据，轻松加愉快~
ansys后处理
weixin_30385925的博客
05-05 3275
1.ANSYS后处理时如何按灰度输出云图？1）你可以到utilitymenu-plotctrls-style-colors-window colors试试2）直接utilitymenu-plotctrls－redirect plots 2 将云图输出为JPG菜单->PlotCtrls->Redirect Plots->To JPEG Files 3.怎么...
ANSYS二次开发：后处理使用APDL命令流解析结果文件
爱看书的小沐
02-14 1万+
文章目录前言1、加载结果文件2、查看结果数据的总体情况3、绘制结果图4、输出动画5、 获取所有节点的数据6、获取所有单元的数据7、获取所有节点和单元的数据8、获取所有频率时刻点的节点和单元数据后记 前言 ANYS提供两种工作方式，GUI图形用户界面(GraphicalUser Interface又称图形用户接口)操作和命令流。 ANYS命令流方式，融合GUI方式、APDL、UPFs、UIDL、MAC，甚至TCL/TK于一个文本文件中，可通过/input命令(或UtilityMenu>File&
ansys疲劳分析方法与应用
08-18
此外，通过参考文献[1]商跃进的《有限元原理与ANSYS应用指南》、[2]张应迁和张洪才的《ANSYS有限元分析从入门到精通》以及[3]刘伟、高维成和于广滨的《ANSYS 12.0宝典》，可以进一步深入学习和掌握ANSYS疲劳分析的...
ansys 模态谐响应分析
03-30
ANSYS是一款强大的有限元分析软件，广泛应用于各个领域的结构分析、热分析以及流体动力学分析等。在进行模态谐响应分析时，ANSYS提供了全面的工具和方法，帮助用户高效地完成任务。 #### 二、ANSYS模态谐响应分析的...
ANSYS疲劳分析
11-30
ANSYS是一款广泛应用于工程领域的高级有限元分析软件，其疲劳分析模块基于ASME锅炉和压力容器规范来进行计算，采用了简化弹塑性假设和Miner累积损伤准则。除了ASME规范之外，用户还可以通过编写宏指令或者选择第三方...
ansys apdl 批量提取节点位移并写入TXT文件的方法
10-18
在使用ansys进行分析后，需要批量提取某些节点的位移数据，可以将这些节点写到txt文件中，然后通过编写循环来提取某时间段内的位移数据。同样原理可以扩展到提取杆件应力等问题，但是循环提取的过程是比较慢的，如果结构比较复杂，在提取阶段会导致ansys卡主，这是正常现象，看黑框里还是在动的，就是在提取数据了。如果有更好更快的方法，欢迎交流！注意此方法是用静力的方法提取，如果计算过程是动力分析，不太建议用，因为提取会很慢，更建议在/post26动力后处理中使用。
ansys实体单元求截面内力
03-09
ansys 实体单元求截面的内力，弯矩，剪力，轴力等等！!!!
【ANSYS命令流】通用后处理技术（二）：图形显示结果与数据输出
路边小M's Blog
04-30 1万+
目录输出控制图形显示结果显示结构变形图显示节点结果 输出控制 定义结果数据平均处理AVRES 该命令对公共区域的结果数据进行平均，仅适用于PoweGraphics模式。 定义数据输出格式 该命令用于数据表的输出控制 /format,ndigit,ftype,nwidth,dsignf,line,char ndigit——数据第一栏的位数，缺省为7，通常第一栏为节点或单元号。 Ftype,...
ANSYS——后处理中单元表（ELEMENT table）的作用、创建、使用
python_AI_fans的博客
05-31 6542
ANSYS——后处理中单元表（ELEMENT table）的使用，讲解了单元表的作用、创建、使用
读取ANSYS结果文件中的数据C语言,Ansys后处理读取非默认的结果文件数据 | 坐倚北风...
weixin_39969568的博客
05-25 1142
在进行后处理时，Ansys默认读取当前目录下的默认求解结果文件。Ansys的求解结果文件有以下几种：(1).RST –结构分析或耦合场分析结果；(2).RTH –热分析和扩散分析结果；(3).RMG –磁场分析结果；(4).RFL –FLOTRAN分析结果。在Ansys中可通过如下方法读取非默认的结果文件数据：(1)GUI：General Postproc - Data&File ...
【ANSYS命令流】通用后处理技术（一）：读取结果文件
路边小M's Blog
04-27 1万+
在`ANSYS`完成求解后，需要进入**后处理**分析求解结果。`ANSYS`有两个后处理器，即通用后处理器`POST1`和时间历程后处理器`POST26`。
ANSYS APDL学习(12)：如何将ansys求解后的数据(点位移/应力/应变等)导出到txt文件
热门推荐
娱乐至上的博客
04-30 2万+
通过命令流快速将 ANSYS 求解后的数据，包括点位移/应变/应力等，导出txt文件中。介绍了命令流的用法，展示了结果
FFmpeg库postproc
07-25
FFmpeg库postproc是FFmpeg中的一个库，用于视频后处理。它提供了一些功能，如去隔行、去噪、锐化等，可以改善视频的质量。要在FFmpeg中启用postproc库，可以在配置时使用--enable-postproc选项。\[1\]在FFmpeg的源代码中，ffmpeg.c文件是主要的实现文件，其中包含了调用postproc库函数的方法和API的使用方法。因此，如果你想了解如何调用postproc库的函数和使用方法，可以参考ffmpeg.c文件。\[2\]要安装FFmpeg并启用postproc库，你可以首先下载FFmpeg的源代码，然后解压文件并进入解压后的文件夹。接下来，执行配置命令时，使用--enable-postproc选项来启用postproc库。最后，编译和安装FFmpeg即可使用postproc库的功能。\[3\] #### 引用[.reference_title] - *1* *3* [ubuntu21.04 安装ffmpeg库并在Clion中编写cpp使用ffmpeg](https://blog.csdn.net/qq_45953454/article/details/128509757)[target="_blank" data-report-click={"spm":"1018.2226.3001.9630","extra":{"utm_source":"vip_chatgpt_common_search_pc_result","utm_medium":"distribute.pc_search_result.none-task-cask-2~all~insert_cask~default-1-null.142^v91^control_2,239^v3^insert_chatgpt"}} ] [.reference_item] - *2* [FFmpeg的API库介绍](https://blog.csdn.net/yinshipin007/article/details/125791527)[target="_blank" data-report-click={"spm":"1018.2226.3001.9630","extra":{"utm_source":"vip_chatgpt_common_search_pc_result","utm_medium":"distribute.pc_search_result.none-task-cask-2~all~insert_cask~default-1-null.142^v91^control_2,239^v3^insert_chatgpt"}} ] [.reference_item] [ .reference_list ]
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

Hulunbuir

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值