目 录
Blog Links
一、前言
复杂模型由 HyperMesh 直接生成，简单模型由 ANSYS 创建，本部分主要介绍 ANSYS 直接创建的简单模型。
通常，我们利用 ANSYS 创建一些规则简单的几何或网格，复杂的几何或网格利用 HyperMesh 处理更为方便。
HperMesh使用指南详见博客： HyperMesh 使用指南 。
因此，该部分只介绍一些常见的规则的几何或网格的创建，如规则的六面体单元，梁单元等。
有限元模型的网格可以通过几何模型的切分生成。也可以通过，低维网格的拉伸，经镜像，阵列等操作生成。
| Software | 几何 / Geometry | 网格 / Mesh |
|---|---|---|
| ANSYS | Keypoints，Lines，Areas，Volumns 分别对应几何点、线、面、体 。 | Node，Edge，Element 分别对应网格结点、边、单元 。 |
| Abaqus | Point，Wire，Face，Solid 分别对应几何点、线、面、体 。 | Node，Edge，Mesh face，Element 分别对应网格结点、边、网格面、单元 。 |
本系列博客以一法兰连接为例介绍 ANSYS 有限元分析流程，按照命令流下的标注的顺序，如 命令流 No.1 ，输入到 ANSYS Command Prompt 中，便可顺利实现本系列博客涉及的有限元模型的创建。没有标注序号命令流或以英文字母为序号的命令流如 命令流 No.A，则表示该命令流仅为解释某一功能而单独创建的实例。
法兰连接的有限元模型如下图所示，该有限元模型包括：法兰模型、垫片模型及栓杆模型。模型创建完成后需要建立各部件间的接触关系，诸如上下法兰间的接触、法兰与垫片间的接触，螺栓杆与垫片和法兰螺栓孔间的接触。随后，还需要设置边界条件、施加载荷及提交计算。最终，进行计算结果的后处理。这就完成了一个标准的 ANSYS 有限元分析流程。
该法兰连接有限元分析的完整命令流详见： ANSYS 有限元分析 命令流 实例 。
FINISH ! 退出当前处理器
/CLEAR,ALL ! 清除所有
/PREP7 ! 进人前处理器
*AFUN,RAD ! 指定角度单位为弧度(非必要步骤)
pi = ACOS(-1) ! 获取圆周率pi的数值(非必要步骤)
*AFUN,DEG ! 将角度单位切换为度(非必要步骤)
CSYS,0 ! 激活总体直角坐标系统
xc = 500 $ yc = 0 $ zc = 0 ! 局部坐标系原点位置(相对应当前激活坐标系)
thxy = 0 $ thyz = 0 $ thzx = 90 ! 局部坐标轴旋转角度度(相对应当前激活坐标系)
LOCAL,15,0,xc,yc,zc,thxy,thyz,thzx ! 创建局部直角坐标系15
CSYS,15 ! 激活局部坐标系15
xc = 1000 $ yc = 0 $ zc = 0 ! 局部坐标系原点位置(相对应当前激活坐标系)
thxy = 0 $ thyz = 0 $ thzx = 0 ! 局部坐标轴旋转角度度(相对应当前激活坐标系)
CLOCAL,16,1,xc,yc,zc,thxy,thyz,thzx ! 根据激活的局部坐标系15定义新的局部柱坐标系16
二、关键点/Keypoints
- K
使用功能： Defines a keypoint.
使用格式： K，NPT，X，Y，Z 。
参数说明： NPT —— Reference number for keypoint. If zero, the lowest available number is assigned.
X，Y，Z —— Keypoint location in the active coordinate system (may be R, θ, Z or R, θ, Φ).
Remarks：
(1). K，关键点编号，x坐标，y坐标， z坐标。坐标值缺省时为0。创建关键点时，可指定关键点的编号。
- GUI 操作：
三、几何线/Lines
3.1 创建线
- L
使用功能： Defines a line between two keypoints.
使用格式： L，P1，P2，NDIV，SPACE ，XV1 ，YV1 ，ZV1 ，XV2 ，YV2 ，ZV2 。
参数说明： P1 —— Keypoint at the beginning of line.
P2 —— Keypoint at the end of line.
参考实例： 创建螺栓周围法兰几何轮廓线。
CSYS,16 ! 激活局部柱坐标系16
WPCSYS,-1 ! 根据当前坐标系定义工作平面
d0 = 40 ! 螺栓孔直径为40
K,1,d0/2,0 $ K,2,d0/2,45 $ K,3,d0/2,90 $ K,4,d0/2,135 $ K,5,d0/2,180
L,1,2 ! 由两个关键点创建一条线(可以是直线或是弧线取决于坐标系)
*REPEAT,4,1,1 ! 上一条命令重复执行4次，始末关键点编号增量为1。
CSYS,15 ! 激活局部坐标系15
CLOCAL,17,1 ! 根据激活的局部坐标系15定义新的局部柱坐标系17
WPCSYS,-1, ! 根据当前坐标系定义工作平面
width = 88 ! 环带宽度为88
num = 55 ! 螺栓总数
Ds = 2000 ! 螺栓分度圆直径
K,6,Ds/2+width/2 $ K,7,Ds/2+width/2,180/num $ K,8,Ds/2,180/num
K,9,Ds/2-width/2,180/num $ K,10,Ds/2-width/2,0
L,6,7
*REPEAT,4,1,1
L,1,6
*REPEAT,5,1,1
/PNUM,KP,1 ! 显示关键点编号
/PNUM,LINE,1 ! 显示线编号
/REPLOT ! Replot
GPLOT ! Multi-Plots
由 命令流 No.1 和 命令流 No.2 创建的几何点线如下图所示：
Remarks ：
(1). 创建线时，系统自动为线分配编号。
(2). *REPEAT
L,1,2
*REPEAT,4,1,1
! 以上两行命令相当于：
L,1,2
L,2,3
L,3,4
L,4,5
3.2 方向关键点
注意： 方向关键点是线的属性而不是单元属性。设置线的方向关键点，用于确定梁截面局部 z 轴的指向，相当于 Abaqus 中的 Assign Beam Orientation ，如下图所示：
在 Abaqus 中，通过设置 n1 direction 的方式，来指定梁截面的方向，n1 direction 用于确定局部 1 轴的指向，即根据所输入的向量来确定局部 1 轴的指向。
Abaqus 梁截面的局部 1 轴即为 ANSYS 梁截面的局部 z 轴。
参考资料： ANSYS中梁单元的使用（一）。
- LATT
使用功能： 给所有选择且未划分网格的线设置划分单元的属性。
使用格式： LATT，MAT，REAL，TYPE，–，KB，KE，SECNUM 。
参数说明： MAT，REAL，TYPE ，SECNUM 给所选择且未划分网格的线指定的材料号、实常数、单元类型号、截面编号。
注：BEAM188 和 BEAM189 不需要指定实常数。
KB，KE 分别为所选择且未划分网格的线起点和终点的方向关键点方向。
在 ANSYS 中，使用关键点的位置确定梁划分网格时梁截面的方向。通过指定一个方向点即 KB，沿着线能够生成一个具有恒定值方向的梁单元，通过选择线上各端点具有不同方向的关键点，能够生成一个预扭曲的梁。
由于 KB (Keypoint Beginning) 和 KE (Keypoint ending) 指定的值仅用于所选的线。也就是说，由这些线通过复制或其他命令生成的线不具有这些属性，且 KB 和 KE 的值只能通过命令 “LATT” 在划分网格前指定。
起点和终点方向关键点与所选择且未划分网格的线相关联。ANSYS 利用这两个方向关键点的位置来确定梁在网格划分时，其横截面的方向指向。对于梁的轴线，其起点和终点分别为关键点 KP1 和 KP2。那么，梁始端截面的方向向量为关键点 KP1 到 KB 的指向。同样地，在梁的终端截面，终端截面的方向向量为关键点 KP2 到 KE 的指向。截面的方向向量指向，即截面局部 z 轴的指向。
建议：在设置梁截面方向时，为了避免出现不必要的错误，应为每个梁创建局部坐标系，在局部坐标系下，创建方向关键点，起点终点的方向关键点应与梁的起点和终点严格对应，即方向关键点应位于梁横截面所在的平面内。(别问为什么，我只能告诉你这么建模肯定不会出错，其余方法不保证。)
在材料力学中，杆的轴线为 x 轴、水平轴为 z 轴，竖直轴为 y 轴。
在 ANSYS 中，实际上，由梁轴线的起点 I、终点 J 与方向关键点 KB/KE 三个点可唯一确定一平面，梁截面的局部 1 轴 (z轴)，位于该平面内且与梁的轴线垂直，根据梁轴线方向向量，局部 1 轴 (z轴) 方向向量，利用线性代数向量叉乘概念即可得到梁截面局部 2 轴 (y轴) 方向，至此，梁截面的方向便唯一确定下来。梁具有恒定方向向量时，梁截面的局部z轴指向按此规则确定。当梁方向向量截面沿轴存在变化时，应严格定义梁起点和终点处的方向关键点，即保证起始方向关键点应分别位于梁起始横截面所在的平面内。
在 Abaqus 中，由梁轴线的起点 1 和 终点 2 可确定一方向向量 t， n1 由用户指定，用户输入的向量，与梁轴线向量 t 可唯一确定一平面，n1 的方向即为在该平面被与 t 相垂直的方向，并符合右手系。n2 由系统根据线性代数知识自动计算得到 (t 与 n1 作叉乘运算)。
参数实例： 创建一H型钢梁，其截面规格为 H200×100×5×10 ，并指定不同的方向。
FINISH ! 退出当前处理器
/CLEAR,ALL ! 清除所有
/PREP7 ! 进人前处理器
! 1.定义材料
*GET,mtmax,MAT,,NUM,MAX
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,mtmax+1,,2e5
MPDATA,PRXY,mtmax+1,,0.28
MPDATA,DENS,mtmax+1,,2700
! 2.定义单元类型
*GET,etmax,ETYP,,NUM,MAX
ET,etmax+1,BEAM189
! 3.定义截面类型
*GET,scmax,SECP,,NUM,MAX
SECTYPE,scmax+1,BEAM,I
SECOFFSET,CENT
H = 200 $ B = 100 $ t1 = 5 $ t2 = 10
SECDATA,B,B,H,t2,t2,t1
! 4.创建几何
K,1,0,0,0 ! 1号梁轴线起点
K,2,1000,0,0 ! 1号梁轴线终点
K,3,0,0,500 ! 2号梁轴线起点
K,4,1000,0,500 ! 2号梁轴线起点
L,1,2 ! 创建1号梁几何
L,3,4 ! 创建2号梁几何
! 5.定义方向关键点
K,5,0,0,100 ! 1号梁起点处的方向关键点(指向整体z轴)
K,6,0,0,0 ! 2号梁起点处的方向关键点(指向整体-z轴)
K,7,1000,500,500 ! 2号梁终点处的方向关键点(指向整体+y轴)
! 6.分配属性
LSEL,S,LINE, ,1 ! 选择1号线
LATT,mtmax+1,,etmax+1,,5,5,scmax+1 ! 1号梁的起止点处的方向关键点均为点5
LSEL,S,LINE, ,2 ! 选择2号线
LATT,mtmax+1,,etmax+1,,6,7,scmax+1 ! 2号梁的起止点处的方向关键点分别为点6、点7。
! 7.划分网格
ALLSEL,ALL,LINE ! 选择全部线
LESIZE,ALL, , ,10, , , , ,0 ! 线被分为10段
LMESH,ALL ! 执行网格划分
/ESHAPE,1 ! 显示梁截面
EPLOT ! Elements plots
/PNUM,KP,1 ! 显示关键点编号
GPLOT ! Multi-Plots
由上述命令流创建的横截面具有特定指向的梁如下图所示
四、几何面/Areas
4.1 围线成面
- AL
使用功能： 通过已定义的边界线生成一个面 / Area from lines 。
使用格式： AL，L1，L2，L3，L4，L5，L6，L7，L8，L9，L10 。
参数说明： L1，L2， . . . . . .，L10 为线的编号，至少需要3条线才能生成一个面。
参考实例： 由轮廓线生成几何面。
AL,1,10,5,9 ! 创建平面，平面由边界线围成，边界线的编号分别为1、10、5、9。
*REPEAT,4,1,1,1,1 ! 上一条命令重复执行4次，各边界线编号增量均为1。
/PNUM,KP,0 ! 关闭关键点编号显示
/PNUM,LINE,0 ! 关闭线编号显示
/PNUM,AREA,1 ! 显示面的编号
/REPLOT ! Replot
GPLOT ! Multi-Plots
由 命令流 No.3 创建的几何面如下图所示：
4.2 创建圆面/环面
- CYL4
使用功能： 在工作平面上生成一个圆面或圆柱体 / Creates a circular area or cylindrical volume anywhere on the working plane 。
使用格式： CYL4，XCENTER，YCENTER，RAD1，THETA1，RAD2，THETA2,，DEPTH 。
参数说明： XCENTER，YCENTER 分别为圆心在工作平面 x 和 y 方向的坐标值。
RAD1，RAD2 分别为内、外半径；THETA1，THETA2 分别为开始、结束角度。
DEPTH 为柱体高度。DEPTH = 0 时，创建圆面/环面。
参考实例： 创建内径50，外径70，起端角度30度，终端角度135度的环面。
FINISH ! 退出当前处理器
/CLEAR,ALL ! 清除所有
/PREP7 ! 进人前处理器
*AFUN,DEG ! 将角度单位切换为度
CSYS,0 ! 激活全局直角坐标系
WPCSYS,-1 ! 根据当前坐标系定义工作平面
CYL4,0,0,50,30,70,135,0 ! 内径50，外径70，起端角度30度，终端角度135度。
/PNUM,AREA,1 ! 显示面的编号
/REPLOT ! Replot
GPLOT ! Multi-Plots
/VIEW,1,,,1
/ANG,1
/REP,FAST
由上述命令流创建的圆环面如下图所示：
五、几何体/Volumes
5.1 由面拉伸为体
命令流 No.4 ~ 命令流 No.7 为属性定义及面网格的划分，这是体网格及附属体创建的基础，该部分与本文介绍主要介绍的几何创建相比，为次要内容，本处不做详细说明，详见博客：ANSYS 有限元分析 网格划分 。
本文主要介绍，由面网格直接拉伸成体网格，随之附属创建相对应的体。具体操作，见 命令流 No.8 。
- 1. 定义材料属性
ALLSEL,ALL ! *GET前最好全选，以免出现意向不到的错误。
*GET,mtmax,MAT,,NUM,MAX ! 获取当前定义的最大单元类型编号并将其赋予变量mtmax。
MPTEMP,,,,,,,, ! 为材料属性定义温度表
MPTEMP,1,0 ! 为材料属性定义温度表
MPDATA,EX,mtmax+3,,2e5 ! 定义mtmax+1号材料属性弹性模量
MPDATA,PRXY,mtmax+3,,0.28 ! 定义mtmax+1号材料属性泊松比
MPDATA,DENS,mtmax+3,,2700 ! 定义mtmax+1号材料属性密度
- 2. 定义单元属性
! MESH200单元
*GET,etmax,ETYP,,NUM,MAX ! 获取当前定义的最大单元类型编号并将其赋予变量etmax (etmax=0)。
ET,etmax+2,MESH200 ! 定义单元类型为Mesh200，其单元识别号为etmax+2。
KEYOPT,etmax+2,1,7 ! 设置单元etmax+2的关键选项，即令 Keyoption(1)=7。
! SOLID186单元
ET,etmax+3,SOLID186 ! 定义单元类型为SOLID186，其单元识别号为etmax+3。
KEYOPT,etmax+3,2,1 ! 设置单元关键选项，将单元类型参考号为etmax+1的单元设置为完全积分单元。
- 3. 布种子
LESIZE,9, , ,2, , , , ,0 ! 设置组成面的边(线)的网格大小，编号为9的线被分成2段。
*REPEAT,5,1 ! 上一条命令重复执行5次
LESIZE,1, , ,2, , , , ,0 ! 设置线的网格大小，编号为1的线被分成2段。
*REPEAT,4,1 ! 上一条命令重复执行4次
LESIZE,8, , ,2, , , , ,0 ! 设置线的网格大小，编号为8的线被分成2段。
- 4. 2D面网格创建
MAT,mtmax+3 ! 给随后生成的单元激活一个材料号
TYPE,etmax+2 ! 给随后生成的单元激活一个单元类型号
MSHAPE,0,2D ! 指定划分单元的形状，生成四边形单元。
MSHKEY,1 ! 采用映射网格划分方式划分网格
AMESH,ALL ! 将所有面划分网格
/PNUM,ELEM,1 ! 显示单元编号
/REPLOT ! Replot
EPLOT ! Elements plots
/VIEW,1,-1 ! Left View
/ANG,1
/REP,FAST
- EXTOPT
使用功能： 由面单元生成体单元的相关控制选项。
使用格式： EXTOPT，Lab，Val1，Val2，Val3 。
参数说明： Lab 为识别控制选项的标签；Val1，Val2，Val3 将根据 Lab 的不同而变化。
- VEXT
使用功能： 通过给定偏移量由面生体。
使用格式： VEXT，NA1，NA2，NINC，DX，DY，DZ，RX，RY，RZ 。
参数说明： NA1，NA2，NINC：设置将要被拖拉面的范围，即按增量 NINC 从 NA1 增大到 NA2。
其中，NA1 也可以为 ALL、P 或元件名。
DX，DY，DZ：为在激活坐标系中，作用于关键点坐标值在X，Y和Z方向的增量 (其他坐标系下类似)。
RX*，RY，RZ：为在激活坐标系中，作用于关键点坐标值在X，Y和Z方向的缩放因子。
以下拉伸操作将同时创建几何实体及体网格，对单元进行旋转、阵列等操作时，最好对体进行旋转及阵列操作，体附属的单元自动跟随其进行旋转、阵列。尽量不要直接对单元进行旋转及阵列，以免出现未知错误。(建模建议)
MAT,mtmax+3 ! 给随后生成的单元激活一个材料号
TYPE,etmax+3 ! 给随后生成的单元激活一个单元类型号
! 执行拉伸
EXTOPT,ESIZE,8,1, ! EXTOPT：由面单元生成体单元的控制选项；
! 8表示在体生成或体扫略方向上单元分割数量为8；
! 1表示在体生成或体扫略方向上的间隔率为1（默认）。
EXTOPT,ACLEAR,1 ! 体单元网格生成后清除面单元网格即MESH200。
tf = 40 ! 法兰厚度为40
VEXT,ALL, , ,0,0,tf ! 通过给的偏移量由面生体
EPLOT ! Elements plots
/REPLOT ! Replot
下接 命令流 No.9 ，命令流 No.9 见博客： ANSYS 有限元分析 修改与编辑 >> 三、镜像 >> 3.1 镜像几何体 。
由 命令流 No.4 ~ 命令流 No.8 经由拉伸创建的体网格及其对应的几何体如下图所示：
5.2 创建(空心)圆柱体
- CYL4
使用功能： 在工作平面上生成一个圆面或圆柱体 / Creates a circular area or cylindrical volume anywhere on the working plane 。
使用格式： CYL4，XCENTER，YCENTER，RAD1，THETA1，RAD2，THETA2,，DEPTH 。
参数说明： XCENTER，YCENTER 分别为圆心在工作平面 x 和 y 方向的坐标值。
RAD1，RAD2 分别为内、外半径；THETA1，THETA2 分别为开始、结束角度。
DEPTH 为柱体高度。DEPTH = 0 时，创建圆面/环面。
- GUI 操作：
参考实例： 创建垫片几何体。
上接 命令流 No.11 ，命令流 No.11 见博客： ANSYS 有限元分析 修改与编辑 >> 六、合并与压缩。
FINISH ! 退出当前处理器
/CLEAR,ALL ! 清除所有
/PREP7 ! 进人前处理器
*AFUN,RAD ! 指定角度单位为弧度(非必要步骤)
pi = ACOS(-1) ! 获取圆周率pi的数值(非必要步骤)
*AFUN,DEG ! 将角度单位切换为度(非必要步骤)
CSYS,0 ! 激活总体直角坐标系统
xc = 500 $ yc = 0 $ zc = 0 ! 局部坐标系原点位置(相对应当前激活坐标系)
thxy = 0 $ thyz = 0 $ thzx = 90 ! 局部坐标轴旋转角度度(相对应当前激活坐标系)
LOCAL,15,0,xc,yc,zc,thxy,thyz,thzx ! 创建局部直角坐标系15
CSYS,15 ! 激活局部坐标系15
xc = 1000 $ yc = 0 $ zc = 0 ! 局部坐标系原点位置(相对应当前激活坐标系)
thxy = 0 $ thyz = 0 $ thzx = 0 ! 局部坐标轴旋转角度度(相对应当前激活坐标系)
CLOCAL,16,1,xc,yc,zc,thxy,thyz,thzx ! 根据激活的局部坐标系15定义新的局部柱坐标系16
CSYS,16
tf = 40 ! 法兰盘厚度
CLOCAL,18,0,0,0,tf ! 创建局部直角坐标系18
*GET,vlmax,VOLU,,NUM,MAX ! 获取当前定义的最大几何体编号并将其赋予变量vlmax。
WPCSYS,-1, ! 定义工作平面，工作平面为局部直角坐标系18的xoy平面。
d0 = 40 ! 螺栓孔直径为40
d1 = 70 $ tw = 5 ! 垫片外径为70，垫片厚度为5。
CYL4,0,0,d0/2,0,d1/2,90,tw ! 创建四分之一垫片，其编号为V1，见下图。
CYL4,0,0,d0/2,90,d1/2,180,tw ! 创建四分之一垫片，其编号为V2，见下图。
CYL4,0,0,d0/2,180,d1/2,270,tw ! 创建四分之一垫片，其编号为V3，见下图。
CYL4,0,0,d0/2,270,d1/2,360,tw ! 创建四分之一垫片，其编号为V4，见下图。
VPLOT ! Volumes plots
/PNUM,AREA,0 ! 关闭几何面编号显示
/PNUM,VOLU,1 ! 显示几何体编号
/REPLOT ! Replot
由 命令流 No.12 创建的单个垫片几何体 (V1、V2、V3 和 V4)，如下图所示：
六、布尔操作
6.1 Merge
- VGLUE
使用功能： 体粘接。
使用格式： VGLUE，NV1，NV2，NV3，NV4，NV5，NV6，NV7，NV8，NV9。
参数说明： NV1，NV1， . . . . . . . ，NV9 为要粘接的体号，NV1也可以为 ALL、P 或组件名。
RAD1，RAD2 分别为内、外半径；THETA1，THETA2 分别为开始、结束角度。
参考实例： 合并垫片 4 个四分之相互独立的几何体为一个有联系的几何体。
VGLUE,1,2,3,4 ! 粘接1号、2号、3号和4号几何体。
! VGLUE,ALL ! 粘接全部几何体。
下接 命令流 No.14 ，命令流 No.14 见博客： ANSYS 有限元分析 网格划分 >> 六、创建网格 >> 6.2 创建体网格 >> 6.2.2 扫掠。
由 命令流 No.13 粘接后的单个垫片几何体 (V1、V5、V6 和 V7)，如下图所示：
合并各体的公共点，公共边，实际上就是布尔操作，合并体，保留边界线，即 Abaqus 中 Merge >> Retain 。
体粘接前重合的边有各自独立的编号，粘接后公共边合并，只有一个编号，如上图所示，左图为合并前。
体粘接后仍然有各自的体编号，但各体公共边界是两个体共享的，由之前独立的体转化为有联系的几何体，如下图所示，体合粘接前，四个体的编号分别为 1、2、3 和 4，执行体粘接命令后，各体的编号变为 1、5、6 和 7，如下图所示：
6.2 Cut
七、尾声
以上，便是 ANSYS 几何建模 部分的简单介绍。
仅以此文为我 ANSYS 的相关学习做一个备忘，同时也为有需要的人提供多一点参考。
胸藏文墨怀若谷，腹有诗书气自华，希望各位都能在知识的 pāo 子里快乐徜徉。
因个人水平有限，文中难免有所疏漏，还请各位大神不吝批评指正。
最后，祝各位攻城狮们，珍爱生命，保护发际线！
欢迎大家点赞、评论及转载，转载请注明出处！
为我打call，不如为我打款！
八、参考文献
[1]. ANSYS 15.0 有限元分析完全自学手册. 郝勇 钟礼东 等编著.
[2]. ANSYS 参数化编程与命令手册. 龚曙光 谢桂兰 黄云清 编著.
[3]. ANSYS Mechanical APDL Command Reference. Release 18.2.
[4]. ANSYS Mechanical APDL Element Reference. Release 18.2.
805
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
