ABAP ALV自定义F4搜索帮助

已于 2024-03-20 19:22:47 修改
阅读量1.1k 收藏 11
点赞数 2
分类专栏： ABAP笔记 文章标签： javascript 开发语言 ecmascript
于 2023-08-09 21:19:10 首次发布
by_Jshi
本文链接：https://blog.csdn.net/JZYDDFZJ/article/details/132188811
版权

前言

我们ALV选择自定义值的方法有下拉列表，搜索帮助等。

ALV单元格下拉列表：（历史博文）https://blog.csdn.net/JZYDDFZJ/article/details/129492159?spm=1001.2014.3001.5502

接下来本文是自定义ALV单元格F4搜索帮助，为了使文章更加清晰，参考了寒武青锋_ABAP-CSDN博客寒武青锋老师的博客，希望能帮助到大家

一、介绍

具体方法如下：

1.FIELDCAT--F4AVAILABL = ABAP_TRUE；

2.触发F4搜索帮助事件：CL_GUI_ALV_GRID的ONF4事件;
3.响应事件

DATA: gr_event_handler TYPE REF TO lcl_event_handler .
  CREATE OBJECT gr_event_handler.

  DATA:lt_f4 TYPE lvc_t_f4,
       ls_f4 TYPE lvc_s_f4.

  ls_f4-fieldname = 'F4HELP'.   "需要定义F4帮助的字段
  ls_f4-register   = 'X'.
  ls_f4-getbefore  = 'X'.
  ls_f4-chngeafter = 'X'.
  INSERT ls_f4 INTO TABLE lt_f4.

  SET HANDLER gr_event_handler->handle_onf4 FOR go_grid.
  CALL METHOD go_grid->register_f4_for_fields
    EXPORTING
      it_f4 = lt_f4.

4.最后F4的PERFORM调用函数 F4IF_INT_TABLE_VALUE_REQUEST 生成搜索帮助，最后代码是ALV的写入与刷新。

二、实现步骤

1.代码展示

代码如下（示例）：

*&---------------------------------------------------------------------*
*& 程 序 名：YTEST_001
*& 程序描述：ABAP ALV自定义F4搜索帮助
*& 创 建 者：爱吃鱼香肉丝的abaper
*& 创建日期：2023/08/09
*&---------------------------------------------------------------------*
*& 版本     修改者(公司)     日期         修改描述
*& 1.0.0    XXXX           YYYYMMDD      创建程序
*&---------------------------------------------------------------------*
REPORT ytest_001.

*&---------------------------------------------------------------------*
* TYPES
*&---------------------------------------------------------------------*
TABLES:sflight.
TYPES:
  BEGIN OF ty_alv,
    carrid     TYPE sflight-carrid,     " 航线代码
    fldate     TYPE sflight-fldate,     " 航班日期
    price      TYPE sflight-price,      " 航空运费
    planetype  TYPE sflight-planetype,  " 飞机类型
    paymentsum TYPE sflight-paymentsum, " 当前预定总数
    f4help     TYPE auart,              " 搜索帮助(销售凭证类型)
  END OF ty_alv,
  tt_alv TYPE STANDARD TABLE OF ty_alv.
*&---------------------------------------------------------------------*
* CONSTANTS
*&---------------------------------------------------------------------*
CONSTANTS:
  BEGIN OF c_ucomm,
    action01 TYPE sy-ucomm VALUE '&ZALL',text01 TYPE text VALUE '全选    ',
    action02 TYPE sy-ucomm VALUE '&ZSAL',text02 TYPE text VALUE '取消全选',
  END OF c_ucomm,
  BEGIN OF c_fcat,
    name01 TYPE fieldname VALUE 'CARRID     ',text01 TYPE fieldtext VALUE '航线代码',
    name02 TYPE fieldname VALUE 'FLDATE     ',text02 TYPE fieldtext VALUE '航班日期',
    name03 TYPE fieldname VALUE 'PRICE      ',text03 TYPE fieldtext VALUE '航空运费',
    name04 TYPE fieldname VALUE 'PLANETYPE  ',text04 TYPE fieldtext VALUE '飞机类型',
    name05 TYPE fieldname VALUE 'PAYMENTSUM ',text05 TYPE fieldtext VALUE '当前预定总数',
    name06 TYPE fieldname VALUE 'F4HELP     ',text06 TYPE fieldtext VALUE '搜索帮助(销售凭证类型)',
  END OF c_fcat.
*&---------------------------------------------------------------------*
* DEFIEN ALV
*&---------------------------------------------------------------------*
DATA:go_container TYPE REF TO cl_gui_docking_container,
     go_grid      TYPE REF TO cl_gui_alv_grid,
     gt_exclude   TYPE ui_functions,
     gt_fieldcat  TYPE lvc_t_fcat,
     gs_layout    TYPE lvc_s_layo,
     gs_variant   TYPE disvariant,
     gv_save,
     ok_code      TYPE sy-ucomm,
     save_code    TYPE sy-ucomm.
*&---------------------------------------------------------------------*
* GLOBAL INTERNAL TABLES
*&---------------------------------------------------------------------*
DATA:
  gt_out TYPE tt_alv.
*&---------------------------------------------------------------------*
* GLOBAL MACROS
*&---------------------------------------------------------------------*
DEFINE macro_fcat.
  ls_fieldcat-fieldname  = &1.
  ls_fieldcat-reptext    = &2.
  APPEND ls_fieldcat TO ct_fieldcat.
  CLEAR ls_fieldcat.
END-OF-DEFINITION.
*----------------------------------------------------------------------*
*       CLASS LCL_EVENT_HANDLER DEFINITION
*----------------------------------------------------------------------*
CLASS lcl_event_handler DEFINITION.
  PUBLIC SECTION.
    METHODS:
*-----F4
      handle_onf4 FOR EVENT onf4 OF cl_gui_alv_grid
        IMPORTING e_fieldname es_row_no er_event_data.
ENDCLASS.
*----------------------------------------------------------------------*
*       CLASS LCL_EVENT_HANDLER IMPLEMENTATION
*----------------------------------------------------------------------*
CLASS lcl_event_handler IMPLEMENTATION.
*--F4
  METHOD handle_onf4.
    PERFORM frm_onf4_help USING e_fieldname es_row_no er_event_data .
  ENDMETHOD.
ENDCLASS.
*&---------------------------------------------------------------------*
* SELECTION-SCREEN
*&---------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK b01 WITH FRAME TITLE TEXT-001.
SELECT-OPTIONS:
  s_carrid FOR sflight-carrid.
SELECTION-SCREEN END OF BLOCK b01.
*&----------------------------------------------------------------------
*& INITIALIZATION.
*&----------------------------------------------------------------------
INITIALIZATION.
* 初始化
  PERFORM frm_initial_data.
*&----------------------------------------------------------------------
*& AT SELECTION-SCREEN OUTPUT
*&----------------------------------------------------------------------
AT SELECTION-SCREEN OUTPUT.
*&----------------------------------------------------------------------
*& AT SELECTION-SCREEN
*&----------------------------------------------------------------------
AT SELECTION-SCREEN.
*&----------------------------------------------------------------------
*& START-OF-SELECTION
*&----------------------------------------------------------------------
START-OF-SELECTION.
* 数据处理
  PERFORM frm_get_data.
  PERFORM frm_show_alv.
*&---------------------------------------------------------------------*
*& Form FRM_INITIAL_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_initial_data .
  CLEAR gt_out.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_GET_DATA
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_get_data .

  SELECT
    carrid,
    fldate,
    price,
    planetype,
    paymentsum
    FROM sflight
    WHERE carrid IN @s_carrid
    INTO CORRESPONDING FIELDS OF TABLE @gt_out
    UP TO 20 ROWS.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_SHOW_ALV
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_show_alv .

  CALL SCREEN 9000.

ENDFORM.
*&---------------------------------------------------------------------*
*& Module STATUS_9000 OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE status_9000 OUTPUT.

  DATA:lv_title TYPE string.
  CLEAR lv_title.

  lv_title = 'ABAP ALV自定义F4搜索帮助'.

  SET PF-STATUS '9000'.               " 定义gui状态
  SET TITLEBAR '9000'  WITH lv_title. " 定义gui标题

ENDMODULE.
*&---------------------------------------------------------------------*
*& Module ALV_DES OUTPUT
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
MODULE alv_des OUTPUT.

  DATA:lt_sort TYPE lvc_t_sort.

  IF go_grid IS INITIAL .
    CREATE OBJECT go_container
      EXPORTING
        repid     = sy-repid
        dynnr     = '9000'
        extension = 2050
        side      = cl_gui_docking_container=>property_floating.
    CREATE OBJECT go_grid
      EXPORTING
        i_parent = go_container.

*   获取字段目录
    PERFORM prepare_field_catalog CHANGING gt_fieldcat .

*   获取样式
    PERFORM prepare_layout CHANGING gs_layout .

*   取消没用的按钮
    PERFORM exclude_tb_functions CHANGING gt_exclude.

*   响应事件
    PERFORM eventload.

*   锚定ALV变式标记
    CLEAR gs_variant.
    gs_variant = sy-repid.
    gv_save = 'A'.
    gs_variant-report = |{ sy-repid }{ sy-dynnr }|.

*-----显示ALV-------------------------------------------
    PERFORM frm_alv_display USING gt_out.
  ELSE .
*----------------------------刷新ALV----------------------
    " 刷新ALV
    PERFORM frm_refresh_alv.
  ENDIF .
ENDMODULE.
*&---------------------------------------------------------------------*
*&      Form  PREPARE_LAYOUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->PS_LAYOUT  text
*----------------------------------------------------------------------*
FORM prepare_layout
  CHANGING ps_layout TYPE lvc_s_layo.
  ps_layout-cwidth_opt      = 'X'.               " 优化行宽度
  ps_layout-zebra           = 'X'.               " 斑马纹
  ps_layout-sel_mode        = 'D'.               " 选择方式
  ps_layout-box_fname       = 'SEL'.             " 指定行选择字段

ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_ALV_DISPLAY
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      --> GT_OUT
*&---------------------------------------------------------------------*
FORM frm_alv_display
  USING pt_table.

  CALL METHOD go_grid->set_table_for_first_display
    EXPORTING
      is_layout            = gs_layout
      it_toolbar_excluding = gt_exclude
      is_variant           = gs_variant
      i_save               = gv_save
    CHANGING
      it_outtab            = pt_table
      it_fieldcatalog      = gt_fieldcat.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_REFRESH_ALV
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_refresh_alv .

  DATA:ls_stable TYPE lvc_s_stbl.
  "刷新ALV
  ls_stable-row = 'X'.
  ls_stable-col = 'X'.
  CALL METHOD go_grid->refresh_table_display
    EXPORTING
      is_stable = ls_stable.
ENDFORM.
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_9000  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_9000 INPUT.
  save_code = ok_code.
  CLEAR ok_code.
  CASE save_code.
*   定义返回按钮
    WHEN 'BACK'.
      LEAVE TO SCREEN 0.
    WHEN 'EXIT' OR 'EXIT2'.
      LEAVE PROGRAM.
    WHEN 'SAVE'.
    WHEN OTHERS.
      CALL METHOD go_grid->set_function_code
        CHANGING
          c_ucomm = save_code.
  ENDCASE.
ENDMODULE.
*&---------------------------------------------------------------------*
*& Form PREPARE_FIELD_CATALOG
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      <-- GT_FIELDCAT
*&---------------------------------------------------------------------*
FORM prepare_field_catalog
  CHANGING ct_fieldcat TYPE lvc_t_fcat.
  DATA:
    ls_fieldcat TYPE lvc_s_fcat.
  macro_fcat:
    c_fcat-name01 c_fcat-text01,
    c_fcat-name02 c_fcat-text02,
    c_fcat-name03 c_fcat-text03,
    c_fcat-name04 c_fcat-text04,
    c_fcat-name05 c_fcat-text05,
    c_fcat-name06 c_fcat-text06.

  LOOP AT ct_fieldcat ASSIGNING FIELD-SYMBOL(<fs_fieldcat>)
                                       WHERE fieldname = 'F4HELP'.
    <fs_fieldcat>-f4availabl = abap_true." F4 help
    <fs_fieldcat>-edit       = abap_true." 可编辑
  ENDLOOP.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form FRM_BUTTEN_CLICK
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      --> ES_COL_ID
*&      --> ES_ROW_NO
*&---------------------------------------------------------------------*
FORM frm_onf4_help
  USING pv_fieldname                                  " ALV列字段名称
        ps_row_no     TYPE lvc_s_roid                 " 行号
        pr_event_data TYPE REF TO cl_alv_event_data .
  DATA:lt_ddshretval TYPE TABLE OF ddshretval.

  SELECT
    auart AS f4help, " 字段一定要和ALV展示数据的字段一致 否则会错乱
    bezei
    FROM tvakt
    WHERE spras = '1'
    INTO TABLE @DATA(lt_auart).

  CASE pv_fieldname.
    WHEN 'F4HELP'.

      READ TABLE gt_out INTO DATA(ls_out) INDEX ps_row_no-row_id.

      CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
        EXPORTING
          retfield         = 'F4HELP'           " ALV-F4字段
          dynpprog         = sy-repid           " 当前程序
          dynpnr           = sy-dynnr           " 当前屏幕
          value_org        = 'S'                " 默认为C但是此处不用S不行
          callback_program = sy-repid
          callback_form    = 'FRM_CM_FORM'      " 用于返回多个值
        TABLES
          value_tab        = lt_auart           " F4帮助值的表
          return_tab       = lt_ddshretval
        EXCEPTIONS
          parameter_error  = 1
          no_values_found  = 2
          OTHERS           = 3.
      IF sy-subrc = 0.
*       将选的值填入ALV字段中
        READ TABLE gt_out INTO ls_out INDEX ps_row_no-row_id.
        IF sy-subrc = 0.
          READ TABLE lt_ddshretval INTO DATA(ls_ddshretval) INDEX 1.
          IF ls_ddshretval-fieldval IS NOT INITIAL.
            ls_out-f4help = ls_ddshretval-fieldval.
          ENDIF.
          MODIFY gt_out FROM ls_out INDEX ps_row_no-row_id TRANSPORTING f4help.
        ENDIF.
      ENDIF.

    WHEN OTHERS.
  ENDCASE.
* "X表示事件已经处理，不会去调取系统标准搜索帮助，（不填写参考字段参考表，也可以忽略这个标识）
  pr_event_data->m_event_handled = 'X'.
* ALV刷新
  PERFORM frm_refresh_alv.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form EVENTLOAD
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM eventload .

* 事件响应
  DATA: gr_event_handler TYPE REF TO lcl_event_handler .
  CREATE OBJECT gr_event_handler.

  DATA:lt_f4 TYPE lvc_t_f4,
       ls_f4 TYPE lvc_s_f4.

* 设置事件-回车
  CALL METHOD go_grid->register_edit_event
    EXPORTING
      i_event_id = cl_gui_alv_grid=>mc_evt_enter
    EXCEPTIONS
      error      = 1
      OTHERS     = 2.

  " 单元格失去焦点触发
  CALL METHOD go_grid->register_edit_event
    EXPORTING
      i_event_id = cl_gui_alv_grid=>mc_evt_modified
    EXCEPTIONS
      error      = 1
      OTHERS     = 2.

  ls_f4-fieldname = 'F4HELP'.   "需要定义F4帮助按钮的字段
  ls_f4-register   = 'X'.
  ls_f4-getbefore  = 'X'.
  ls_f4-chngeafter = 'X'.
  INSERT ls_f4 INTO TABLE lt_f4.

  SET HANDLER gr_event_handler->handle_onf4 FOR go_grid.
  CALL METHOD go_grid->register_f4_for_fields
    EXPORTING
      it_f4 = lt_f4.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form EXCLUDE_TB_FUNCTIONS
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*&      <-- GT_EXCLUDE
*&---------------------------------------------------------------------*
FORM exclude_tb_functions
  CHANGING pt_exclude TYPE ui_functions .

  DATA ls_exclude TYPE ui_func.
  ls_exclude = cl_gui_alv_grid=>mc_fc_maximum .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_delete_row .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_copy_row .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_append_row .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_copy .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_cut .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_insert_row .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_move_row .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_paste .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_paste_new_row .
  APPEND ls_exclude TO pt_exclude.
  ls_exclude = cl_gui_alv_grid=>mc_fc_loc_undo .
  APPEND ls_exclude TO pt_exclude.

ENDFORM.
* 这里不多解释DEBUG看去吧 lt_ddshretval决定表的返回值

*****&---------------------------------------------------------------------*
*****&      Form  FRM_CM_FORM
*****&---------------------------------------------------------------------*
****FORM frm_cm_form
****  TABLES   lt_record_tab  STRUCTURE seahlpres
****  CHANGING ls_shlp        TYPE      shlp_descr_t
****                    callcontrol LIKE      ddshf4ctrl.
****  DATA: ls_interface LIKE LINE OF ls_shlp-interface.
****  READ TABLE ls_shlp-interface INTO ls_interface INDEX 1.
*****  ls_interface-shlpfield+4(1) = '1'.
*****  ls_interface-valfield = 'WERKS'.
*****  APPEND ls_interface TO ls_shlp-interface.
****  ls_interface-shlpfield+4(1) = '2'.
****  ls_interface-valfield = 'LGORT'.
****  APPEND ls_interface TO ls_shlp-interface.
*****  ls_interface-shlpfield+4(1) = '3'.
*****  ls_interface-valfield = 'LGOBE'.
*****  APPEND ls_interface TO ls_shlp-interface.
****ENDFORM.                    "bo_callback_form

2.效果如下

效果展示：

 双击，数据填充，刷新ALV

总结

希望能帮助需要的人！

小皮卡沃尼
关注
  • 2
    点赞
  • 踩
  • 11
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
ABAP-ALV-列：F4搜索帮助
qq_34561745的博客
12-15 1230
ABAP-ALV-列：F4搜索帮助
ALV通过F4事件，实现自定义搜索帮助F4
少年休闲海
09-22 7766
ALV通过参考可以直接获取表中搜索帮助，但是表中字段没有搜索帮助或者不合要求就需要通过F4事件完成了。 1、定义OOALV类 CLASS lcl_event_receiver DEFINITION DEFERRED. DATA:gt_fieldcat TYPE lvc_t_fcat, gs_fieldcat TYPE lvc_s_fcat, go_grid
ABAP-ALV-选择屏幕：F4搜索帮助
qq_34561745的博客
12-19 931
ABAP-ALV-选择屏幕：F4搜索帮助
ABAP_实现F4帮助联动
04-20
ABAP_实现F4帮助联动 该文档中的代码可以实现F4搜索帮助的联动效果
ABAP ALV中自定义搜索帮助
寒武青锋的博客
11-08 3502
1.事件的使用是OOALV中使用的，我的是functionalv转OOALV，它的好处就是可以兼顾functionalv的便利和OOalv的事件。2.要把里面的自定义表换成你的搜索帮助表。2.实现handle_f4 方法。4.fieldcat的配置。
ALV 自定义搜索帮助 F4 详解
VRZHENG的博客
09-30 913
SAP ABAP ALV 自定义F4 定义事件 详解 搜索帮助 我去好多废话
ABAP ALV(LVC)下拉框或者F4搜索帮助
'尤其是十月的风'的博客
05-25 2876
先上结果图： 代码： REPORT ZDCH_09_TEST2. ************************************************************************ * DATEN DEFINITION * ************************************************************************ TYP
ABAP ALV— F4 帮助 插入 复制 删除 编辑 （源码）
Pegasus666的博客
06-27 1218
一、功能展示： 1.ALV展示画面 插入功能 复制行功能展示 删除行功能展示 二、源代码（数据均是通过代码添加至内表，不涉及取数，所以任何系统均可执行此代码）。 *&---------------------------------------------------------------------* *&功能背景：实现取数 *&->ALV显示 *&->ALV可编辑（新增，修改，删除，F4帮助） ...
SAP ABAP ALV 详解
12-11
SAP ABAP ALV 详解 SAP ABAP 中的 ALV（ABAP List Viewer）是一种列表输出方式，在 R/3 4.6C 之前称为 ABAP List Viewer，后来更名为 SAP List Viewer。ALV 是以表格控件的形式出现在用户屏幕中实现的，具体有两种...
abap-ALV.rar_ABAP系统ALV_abap_abap开发alv
09-21
ABAP（Advanced Business Application Programming）是SAP公司用于其R/3系统的一种编程语言，用于构建企业级的应用程序。...这份文档将帮助你理解和实践ABAP ALV开发，从而提升你在ABAP领域的专业技能。
ABAP开发ALV中自定义按钮实现
06-02
在ABAP开发中，ALV（Accelerated List Viewer）是一种常用的数据展示工具，它提供了灵活的表格布局和交互性。用户通常需要对ALV进行定制，以满足特定的需求，例如添加自定义按钮来实现数据的打印或导出到Excel。本篇...
ABAP ALV 报表基础模板(两种)
03-01
ABAP ALV 报表基础模板(两种)
matinal：SAP ABAP ALV可编辑，搜索帮助的实现
matinal 當冬夜漸暖 。公众号：matinal
09-26 624
DATA: gt_event TYPE slis_t_event.
ABAP：ALV中自定义搜索帮助
少年休闲海
08-11 6287
如果希望ALV中某字段具有搜索帮助，第一种办法当然是对表中某字段的引用，设置ref_table、ref_field，将自动触发该字段所带的搜索帮助。 可不可以直接设置Searh Help呢？应该不可以，找遍了field catalog的结构也没发现有可以设置的字段。   第
ALV中如何添加搜索帮助
beyond911的专栏
09-18 537
alv 搜索帮助
FUNTION ALV 实现F4 自定义搜索帮助--“保姆级“笔记
weixin_43564972的博客
11-16 1119
练习本实例所需要具备的ABAP知识：FUNCTION ALV (FM_ALV) 程序的熟练编写：字段目录、布局样式、事件处理ABAP 面向对象编程的基本知识，了解类的定义，实施方式，事件的处理。OOALV 除事件处理外，可自己独立实现OOALV的展示……在此知识基础上，练习本实例才有可能比较容易的顺利理解……否则，建议先打好基础知识的底子，以提高学习的效率……参考网址。
【ABAP】在ALV 使用On_F4的事件例程
Mac的SAP专栏
07-10 3390
 这里并不介绍类cl_gui_alv_grid的用法，所以此博文的先决条件是会使用基本的cl_gui_alv_grid显示ALV。  Sample code：  Definition：   CLASS lcl_event_receiver DEFINITION DEFERRED.  DATA:       gt_fieldcat                T
SAP ABAP搜索帮助F4
Li958172829的博客
01-19 1995
SAP ABAP搜索帮助F4、创建 Domain、创建 Data element、Domain Value Range、Check Table 外键、创建Search Help、F4IF_INT_TABLE_VALUE_REQUEST、
Next.js静态导出与动态路由优化
最新发布
天涯学馆
07-20 691
Next.js 是一个流行的 React 框架，它简化了构建服务端渲染（SSR）和静态站点生成（SSG）的应用。静态导出是Next.js的一项强大特性，它允许你将整个应用程序导出为静态文件，从而在无服务器环境下运行，提高加载速度和降低服务器成本。动态路由则允许你根据数据生成页面，即使在静态导出的情况下也能保持灵活性。
ABAP ALV 注册搜索帮助
07-28
回答: 在ABAP ALV中注册搜索帮助的方法如下：首先，在微调中添加参数wa_fieldcat-f4availabl = &7. wa_fieldcat-ref_table = &8. wa_fieldcat-ref_field = &9. 'KUNNR' '责任人' '' 'X' ' ' ' ' 'X' 'KNA1' 'KUNNR'。然后，在结果中，由于GUI版本不同，图标可能无法显示，只需按下F4即可。如果需要解决此问题，可以下载“GUI_740 4-10013011”。 #### 引用[.reference_title] - *1* *2* [ALV中如何添加搜索帮助](https://blog.csdn.net/beyond911/article/details/126913716)[target="_blank" data-report-click={"spm":"1018.2226.3001.9630","extra":{"utm_source":"vip_chatgpt_common_search_pc_result","utm_medium":"distribute.pc_search_result.none-task-cask-2~all~insert_cask~default-1-null.142^v91^insert_down28v1,239^v3^insert_chatgpt"}} ] [.reference_item] [ .reference_list ]

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值