[汇编语言实验] ：字符串拆分

青铜世纪

于 2022-07-20 23:03:40 发布

阅读量884

点赞数 1

分类专栏：汇编语言文章标签：算法汇编

本文链接：https://blog.csdn.net/Joker15517/article/details/125902561

版权

汇编语言专栏收录该内容

1 篇文章 0 订阅

订阅专栏

实验报告

题目描述

设计思路

题意理解

本题输入一个字符串，将三个三个为一组的十进制数，转换为二进制表达，最后一组可能不足三个

大致思路

三位字符串转化为十进制数

这个可以通过遍历这几个字符，采用累加的方法，循环多次，每次先对累加和乘 10，再加上当前字符减去 30h 的值。
十进制数转二进制

由于累加和在内存中是以二进制补码形式存储的，可以考虑通过移位的方式获得二进制表达，每次将移出的这一位放到 tmp 数组中，然后再通过处理放到答案数组res 中。

源程序

include D:\MASM\io32.inc

.data
input   byte 1000 dup(?) ; 输入字符串
res     byte '0001 ', 1000 dup(0) ; 答案字符串
len     dword ? ; 字符串长度
r       dword ? ; 最后剩余的
gp      dword ? ; 组数
t       dword ? ; 临时变量
i       dword ? ; 临时变量
tmp     byte 1000 dup(0) ; 临时变量
.code

start:
    mov eax, offset input ; 读入处理
    call readmsg
    mov len, eax
    mov i, 15
    mov esi, 15
    
;************************************
;处理字符计数指示符；转换为二进制
;通过不断将最低位加入结果，然后右移得到二进制表示，不过这是逆序的，需要倒转过来
again:
    dec esi
    cmp esi, 4
    jle endagain
    test eax, 1
    jz next1
    jmp next2
next1:
    mov res[esi], 30h
    shr eax, 1
    jmp again
next2:
    mov res[esi], 31h
    shr eax, 1
    jmp again
endagain:
;***********************************
    mov eax, len
    xor edx, edx
    mov ebx, 3
    div ebx
    mov r, edx
    mov gp, eax
    mov esi, 0
    mov edi, 0
    cmp r, 0
    je again1
    inc gp
;***********************************
;第一层循环，枚举每一个三元组，包括最后一个
again1:
    cmp esi, gp
    jae endagain1
    
    mov ecx, 3
    mov eax, esi
    mul ecx
    mov edi, eax
    xor ebx, ebx
    mov t, 10
; 第二层第一个循环，将三位字符串转换为十进制数
again11:
    cmp edi, len
    je endagain11
    mov eax, ebx
    mul t
    mov ebx, eax
    xor eax, eax
    mov al, input[edi]
    sub al, 30h
    add ebx, eax

    inc edi
    loop again11
endagain11:
    xor edi, edi
;第二层第二个循环，将得到的十进制数转换为二进制表示，和上面方法类似
again12:

    test ebx, 1
    jz ne1
    mov tmp[edi], 31h
    jmp ne2
ne1:
    mov tmp[edi], 30h
    jmp ne2
ne2:
    inc edi
    shr ebx, 1
    cmp ebx, 0
    je endagain12
    jmp again12
; 第二层第三个循环，将暂存在tmp数组中的二进制逆序表达倒转到res中
endagain12:
    mov eax, i
    mov res[eax], 32
    inc i
again13:
    dec edi
    cmp edi, -1
    jle endagain13
    mov dl, tmp[edi]
    mov eax, i
    mov res[eax], dl
    inc i
    jmp again13
endagain13:
    
    inc esi
    jmp again1
endagain1:

; 结束循环
;****************************************
; 处理显示

    mov eax, offset res
    call dispmsg
    call dispcrlf

end start