bzoj 1208 [HNOI2004]宠物收养所

Description

最近，阿Q开了一间宠物收养所。收养所提供两种服务：收养被主人遗弃的宠物和让新的主人领养这些宠物。每个领养者都希望领养到自己满意的宠物，阿Q根据领养者的要求通过他自己发明的一个特殊的公式，得出该领养者希望领养的宠物的特点值a（a是一个正整数，a<2^31），而他也给每个处在收养所的宠物一个特点值。这样他就能够很方便的处理整个领养宠物的过程了，宠物收养所总是会有两种情况发生：被遗弃的宠物过多或者是想要收养宠物的人太多，而宠物太少。 1． 被遗弃的宠物过多时，假若到来一个领养者，这个领养者希望领养的宠物的特点值为a，那么它将会领养一只目前未被领养的宠物中特点值最接近a的一只宠物。（任何两只宠物的特点值都不可能是相同的，任何两个领养者的希望领养宠物的特点值也不可能是一样的）如果有两只满足要求的宠物，即存在两只宠物他们的特点值分别为a-b和a+b，那么领养者将会领养特点值为a-b的那只宠物。 2． 收养宠物的人过多，假若到来一只被收养的宠物，那么哪个领养者能够领养它呢？能够领养它的领养者，是那个希望被领养宠物的特点值最接近该宠物特点值的领养者，如果该宠物的特点值为a，存在两个领养者他们希望领养宠物的特点值分别为a-b和a+b，那么特点值为a-b的那个领养者将成功领养该宠物。 一个领养者领养了一个特点值为a的宠物，而它本身希望领养的宠物的特点值为b，那么这个领养者的不满意程度为abs(a-b)。【任务描述】你得到了一年当中，领养者和被收养宠物到来收养所的情况，希望你计算所有收养了宠物的领养者的不满意程度的总和。这一年初始时，收养所里面既没有宠物，也没有领养者。

Input

第一行为一个正整数n，n<=80000，表示一年当中来到收养所的宠物和领养者的总数。接下来的n行，按到来时间的先后顺序描述了一年当中来到收养所的宠物和领养者的情况。每行有两个正整数a, b，其中a=0表示宠物，a=1表示领养者，b表示宠物的特点值或是领养者希望领养宠物的特点值。（同一时间呆在收养所中的，要么全是宠物，要么全是领养者，这些宠物和领养者的个数不会超过10000个）

Output

仅有一个正整数，表示一年当中所有收养了宠物的领养者的不满意程度的总和mod 1000000以后的结果。

Sample Input

5
0 2
0 4
1 3
1 2
1 5

Sample Output

3
(abs(3-2) + abs(2-4)=3，最后一个领养者没有宠物可以领养)

首先简化下两种操作：

1.找到一串数中最接近读入值的那个数，把差值加入答案，删掉。

2.加入一个数。

 

对于第一个操作我们当然期望数列是有序的。可是加入的数是无序的。所以考虑用伸展树。

然后就是伸展树的基本操作了。

1.把不大于读入值的最大的数伸展到根。

2.把大于读入值的最小的数伸展到根的右儿子。

//以上两步还要考虑读入值比树中的所有值都大或都小的情况。

3.比较根和它的右儿子哪个更优，就加入答案并删除。

//删除的时候因为根的右儿子没有左儿子，所以直接更改指针就可以了。

 

一开始死循环了。。没考虑读入的值与树中某节点相同的情况。。。在splay的时候一直跳不出，因为要伸展到的地方比所给的目的地更远。。。

 

还有一点，题目规定了树中的节点最多只有10000个，所以可以把删除的节点压入栈中重复使用。（虽然没有卡空间。。）

 

AC CODE

//不得不说这回的代码敲地其丑无比。。。

program bzoj_1208;
var c:array[0..10000,0..1] of longint;    //记录左右儿子。
    a,fa,stack:array[0..10000] of longint;    //记录特点值，父亲和删掉的单元。
    ans,tot,top,root,mark:longint;
//============================================================================
procedure rotate(var root:longint; x:longint);
var y,z,p,q:longint;
begin
  y:=fa[x]; z:=fa[y];
  if c[y,0]=x then p:=0 else p:=1;
  q:=p xor 1;
  if y=root then root:=x else
    if c[z,0]=y then c[z,0]:=x else c[z,1]:=x;
  fa[x]:=z; fa[y]:=x; fa[c[x,q]]:=y;
  c[y,p]:=c[x,q]; c[x,q]:=y;
end;
//============================================================================
procedure splay(var root:longint; x:longint);
var y,z:longint;
begin
  while x<>root do
  begin
    y:=fa[x]; z:=fa[y];
    if y<>root then
      if (c[y,0]=x) xor (c[z,0]=y) then
        rotate(root,x) else rotate(root,y);
    rotate(root,x);
  end;
end;
//============================================================================
procedure ins(x:longint);
var z,now:longint;
begin
  if root=0 then
  begin
    if top=0 then    //栈里有元素就先用栈里的元素。
    begin
      inc(tot); root:=tot;
      a[tot]:=x;
    end else
    begin
      root:=stack[top]; dec(top);
      a[root]:=x;
    end; exit;
  end;
  if top>0 then    //栈里有元素就先用栈里的元素。
  begin
    z:=stack[top];
    dec(top);
  end else
  begin
    inc(tot);
    z:=tot;
  end; now:=root;
  while true do
  begin
    if a[now]>x then
    begin
      if c[now,0]=0 then
      begin
        c[now,0]:=z; fa[z]:=now;
        a[z]:=x; break;
      end else now:=c[now,0];
    end else
    begin
      if c[now,1]=0 then
      begin
        c[now,1]:=z; fa[z]:=now;
        a[z]:=x; break;
      end else now:=c[now,1];
    end;
  end; splay(root,z);
end;
//============================================================================
function search_left(x:longint):longint;    //第一步。
var now:longint;
begin search_left:=-1;
  now:=root;
  while true do
  begin
    if a[now]>x then
    begin
      if c[now,0]=0 then break else
        now:=c[now,0];
    end else
    begin
      search_left:=now;
      if c[now,1]=0 then break else
        now:=c[now,1];
    end;
  end; splay(root,now);    //每次顺着伸展树走都要记得splay操作、、
end;
//============================================================================
function search_right(x:longint):longint;    //第二步。
var now:longint;
begin search_right:=-1;
  now:=root;
  while true do
  begin
    if a[now]<=x then
    begin
      if c[now,1]=0 then break else
        now:=c[now,1];
    end else
    begin
      search_right:=now;
      if c[now,0]=0 then break else
        now:=c[now,0];
    end;
  end; splay(root,now);
end;
//============================================================================
procedure deal(x:longint);
var l,r,g,h,tmp,tt:longint;
begin
  l:=search_left(x); r:=search_right(x);
  if l<>-1 then splay(root,l);    //考虑读入值时极值的情况。
  if r<>-1 then
    if l<>-1 then splay(c[root,1],r) else
      splay(root,r);
  if l=-1 then    //考虑读入值时极值的情况。
  begin
    ans:=(ans+abs(a[root]-x)) mod 1000000;
    tmp:=c[root,1]; c[root,1]:=0;    //删除的时候把指针也清干净以免乱跳、、
    inc(top); stack[top]:=root;    //入栈。
    fa[tmp]:=0; root:=tmp;
  end else
  if r=-1 then
  begin
    ans:=(ans+abs(a[root]-x)) mod 1000000;
    tmp:=c[root,0]; c[root,0]:=0;
    inc(top); stack[top]:=root;
    fa[tmp]:=0; root:=tmp;
  end else
  begin
    g:=a[root]; h:=a[c[root,1]];
    if x-g<=h-x then
    begin
      ans:=(ans+abs(x-g)) mod 1000000;
      if c[root,0]=0 then
      begin
        tmp:=c[root,1]; c[root,1]:=0;
        inc(top); stack[top]:=root;
        fa[tmp]:=0; root:=tmp;
      end else
      begin
        tmp:=c[root,1]; c[tmp,0]:=c[root,0];
        fa[c[root,0]]:=tmp; fa[tmp]:=0;
        inc(top); stack[top]:=root;
        fa[root]:=0; c[root,0]:=0; c[root,1]:=0;
        root:=tmp;
      end;
    end else
    begin
      ans:=(ans+abs(h-x)) mod 1000000;
      tt:=c[root,1];
      if c[tt,1]=0 then
      begin
        c[root,1]:=0; fa[tt]:=0;
        inc(top); stack[top]:=tt;
      end else
      begin
        c[root,1]:=c[tt,1]; fa[c[tt,1]]:=root;
        inc(top); stack[top]:=tt;
        fa[tt]:=0; c[tt,1]:=0;
      end;
    end;
  end;
end;
//============================================================================
procedure main;
var i,k,x,n:longint;
begin
  readln(n);
  for i:=1 to n do
  begin
    readln(k,x);
    if tot=top then
    begin
      mark:=k;    //用mark标记树中的节点是宠物还是人。
      ins(x);
    end else
      if mark<>k then
      begin
        if tot-top=1 then
        begin
          ans:=(ans+abs(a[root]-x)) mod 1000000;
          inc(top); stack[top]:=root; root:=0;
        end else deal(x);
      end else ins(x);
  end; writeln(ans);
end;
//============================================================================
begin
  main;
end.