NOIP2004普及组：合并果子

NOIP2004普及组 合并果子

---

题目描述 Description
在一个果园里，多多已经将所有的果子打了下来，而且按果子的不同种类分成了不同的堆。多多决定把所有的果子合成一堆。

每一次合并，多多可以把两堆果子合并到一起，消耗的体力等于两堆果子的重量之和。可以看出，所有的果子经过n-1次合并之后，就只剩下一堆了。多多在合并果子时总共消耗的体力等于每次合并所耗体力之和。


因为还要花大力气把这些果子搬回家，所以多多在合并果子时要尽可能地节省体力。假定每个果子重量都为1，并且已知果子的种类数和每种果子的数目，你的任务是设计出合并的次序方案，使多多耗费的体力最少，并输出这个最小的体力耗费值。


例如有3种果子，数目依次为1，2，9。可以先将1、2堆合并，新堆数目为3，耗费体力为3。接着，将新堆与原先的第三堆合并，又得到新的堆，数目为12，耗费体力为12。所以多多总共耗费体力=3+12=15。可以证明15为最小的体力耗费值。

输入描述 Input Description
输入包括两行，第一行是一个整数n(1<＝n<=10000)，表示果子的种类数。第二行包含n个整数，用空格分隔，第i个整数ai(1<＝ai<=20000)是第i种果子的数目。

输出描述 Output Description
输出包括一行，这一行只包含一个整数，也就是最小的体力耗费值。输入数据保证这个值小于231。

样例输入 Sample Input
3
1 2 9

样例输出 Sample Output
15

数据范围及提示 Data Size & Hint
对于30％的数据，保证有n<=1000：
对于50％的数据，保证有n<=5000；
对于全部的数据，保证有n<=10000。

---

根据贪心的思想，不难想到算法：每次合并当前堆中两个最小的，这样的方案一定最优。事实上，哈夫曼树（Huffman Tree）的构造也是这样的道理。

现在问题来了

我们应如何维护数组呢？

这里有多种方法，一种是用链表存储，每次产生的新数都插入到链表中去。

二是使用堆来存储，具体算法如下：

我们对于整个数组，先把它构造成一个小根堆。

然后每次合并时，先把a[n]与a[1]交换，此时a[n]为最小值。

再对a[1]做一次维护（heapfiy）此时a[1]又变成了次小值。

所以把ans加上a[1]和a[n]，a[1]加上a[n]，再做一次维护a[1]。

此时它又是一个堆了。

重复上述过程，直到合并完成即可。

program heap;
var 
   n,i,ans:longint;
   a:array[-1..20001] of longint;

procedure heapify(k:longint);  //小根堆（迭代）
var 
   l,r,min,p:longint;
begin 

   repeat 

      l:=k*2;

      r:=k*2+1;

      min:=k;

      if (l<=n)and(a[l]<a[min]) then min:=l;

      if (r<=n)and(a[r]<a[min]) then min:=r;

      if (k<>min) then begin 

        p:=a[k];a[k]:=a[min];a[min]:=p;

        k:=min;
      end 
      else 
        break;

    until false;

end;

procedure build_heap;
var 
   i:longint;
begin 

   for i:=n div 2 downto 1 do 
       heapify(i);

end;

procedure heap_solve;
var 
    i,p:longint;
begin 

    for i:=n downto 2 do begin 

       p:=a[1];a[1]:=a[n];a[n]:=p;

       ans:=ans+a[n]; //最小值

       dec(n);

       heapify(1);

       ans:=ans+a[1]; //次小值

       a[1]:=a[1]+a[n+1];

       heapify(1);

    end;

end;

begin 

   read(n);

   for i:=1 to n do 
       read(a[i]);

   ans:=0;

   build_heap; //建堆

   heap_solve; //模拟过程

   writeln(ans);

end.

时间复杂度为O(nlogn)，对于n=10000正好解决。