堆的应用：地鼠游戏

地鼠游戏

题目描述 Description

王钢是一名学习成绩优异的学生，在平时的学习中，他总能利用一切时间认真高效地学习，他不但学习刻苦，而且善于经常总结、完善自己的学习方法，所以他总能在每次考试中得到优异的分数，这一切很大程度上是由于他是一个追求效率的人。

但王钢也是一个喜欢玩的人，平时在学校学习他努力克制自己玩，可在星期天他却会抽一定的时间让自己玩一下，他的爸爸妈妈也比较信任他的学习能力和学习习惯，所以在星期天也不会象其他家长一样对他抓紧，而是允许他在星期天上午可以自由支配时间。

地鼠游戏是一项需要反应速度和敏捷判断力的游戏。游戏开始时，会在地板上一下子冒出很多地鼠来，然后等你用榔头去敲击这些地鼠，每个地鼠被敲击后，将会增加相应的游戏分值。问题是这些地鼠不会傻傻地等你去敲击，它总会在冒出一会时间后又钻到地板下面去（而且再也不上来），每个地鼠冒出后停留的时间可能是不同的，而且每个地鼠被敲击后增加的游戏分值也可能是不同，为了胜出，游戏参与者就必须根据每个地鼠的特性，有选择地尽快敲击一些地鼠，使得总的得分最大。

这个极具挑战性的游戏王钢特别喜欢，最近他经常在星期天上午玩这个游戏，慢慢地他不但敲击速度越来越快（敲击每个地鼠所需要的耗时是1秒），而且他还发现了游戏的一些特征，那就是每次游戏重新开始后，某个地鼠冒出来后停留的时间都是固定的，而且他记录了每个地鼠被敲击后将会增加的分值。于是，他在每次游戏开始后总能有次序地选择敲击不同的地鼠，保证每次得到最大的总分值。

输入描述 Input Description

输入包含3行，第一行包含一个整数n（1<=n<=100）表示有n个地鼠从地上冒出来，第二行n个用空格分隔的整数表示每个地鼠冒出后停留的时间，第三行n个用空格分隔的整数表示每个地鼠被敲击后会增加的分值（<=100）。每行中第i个数都表示第i个地鼠的信息。

输出描述 Output Description

输出只有一行一个整数，表示王钢所能获得的最大游戏总分值。

样例输入 Sample Input

5

5 3 6 1 4

7 9 2 1 5

样例输出 Sample Output

24

---

这题我记得是安徽一道省选题，但数据比这凶猛多了，貌似是 n<=200000

然而这题我当年又是骗分的……（众：这么水写个朴素的也好啊！）然而谁叫我就是这么水呢……

我当时是把所有地鼠分加起来直接输出……骗了40分……( ╯□╰ )

再来说说正解吧。

首先贪心是不难想到的。但是这里又有一个问题：如果我们按时间顺序贪，有可能会有这种情况：一个地鼠为99分，只停留1秒，而另一个地鼠停留10秒，为100分。

这时如果我们按贪心来，会选100分的，然而有可能2~9秒全是1，2分的地鼠，这时策略显然不对。

然后思路来了：我们从后往前贪心，因为每一秒不打白不打，所以就选当前分最大的打，这样一定最优。

但是对于这题的小数据可以直接贪或DP，对于200000的规模呢？

谈到贪心的优化，很多时候是用堆的。

所以我们用堆来优化：每次把当前能打的地鼠弹进一个大根堆，每次打就选根节点的地鼠，把它出堆，再维护一下堆即可。

program heap;
var 
    n,t,i,j,ans,len:longint;

    time,value,a:array[-1..10000] of longint;

procedure sort;
var 
   i,j,p:longint;
begin 

   for i:=1 to n-1 do 
       for j:=i+1 to n do 
           if time[i]>time[j] then begin 
            p:=time[i];time[i]:=time[j];time[j]:=p;
            p:=value[i];value[i]:=value[j];value[j]:=p;
           end;

end;

procedure inser(k:longint);
var 
    dad,p:longint;
begin 

    inc(len);

    a[len]:=value[k];

    k:=len;

    repeat 

       dad:=k div 2;

       if (dad>0)and(a[dad]<a[k]) then begin 

          p:=a[dad];a[dad]:=a[k];a[k]:=p;

          k:=dad;

       end
       else 
           break;

    until false;

end;

procedure heapify(k:longint);
var 
    l,r,max,p:longint;
begin 

    repeat 

       l:=k*2;

       r:=k*2+1;

       max:=k;

       if (l<=len)and(a[l]>a[max]) then max:=l;

       if (r<=len)and(a[r]>a[max]) then max:=r;

       if k<>max then begin 

          p:=a[max];a[max]:=a[k];a[k]:=p;

          k:=max;

       end
       else 
           break;

    until false;

end;

procedure solve;
var 
   p:longint;
begin 

    if len=0 then exit;

    p:=a[1];a[1]:=a[len];a[len]:=p;

    ans:=ans+a[len];

    dec(len);

    heapify(1); //维护堆

end;

begin 

    read(n);

    t:=0; len:=0;

    fillchar(a,sizeof(a),0);


    for i:=1 to n do begin  
        read(time[i]);

        if time[i]>t then t:=time[i];
    end;

    for i:=1 to n do 
        read(value[i]);

    sort;//按时间排序

    j:=n;

    ans:=0;

    for i:=t downto 1 do begin //从后往前贪

        while (time[j]=i)and(j>0) do begin 

           inser(j); //入堆

           dec(j);

        end;

        solve; //打地鼠

    end;

    writeln(ans);

end.