纯汇编中的头文件包含

最新推荐文章于 2024-06-08 12:54:20 发布
最新推荐文章于 2024-06-08 12:54:20 发布
阅读量4.3k 收藏 3
点赞数 1

前言

写汇编程序，如果只用一个.asm来做，维护不方便，程序的逻辑被工具函数淹没了.
可以分成多个.asm, 在主asm中include工具函数库的.inc

主程序

;////////////////////////////////////////////////////////////
; hw1j.asm

include helper.inc

;////////////////////////////////////////////////////////////
MYSEG_STACK segment stack
    db 1000h dup (0)
MYSEG_STACK ends

;////////////////////////////////////////////////////////////
MYSEG_DATA segment PARA public "data"
    STR_TITLE db '<<switch test>>', 0dh, 0ah, 24h
    STR_OVER db 'task over', 0dh, 0ah, 24h
    TAB_LETTER_REPLACE db 0eeh ; '0'
        db 081h ; '1'
        db 07fh ; '2'
        db 098h ; '3'
        db 065h ; '4'
        db 0a7h ; '5'
        db 0c3h ; '6'
        db 0e2h ; '7'
        db 0f6h ; '8'
        db 084h ; '9'
MYSEG_DATA ends

;////////////////////////////////////////////////////////////
MYSEG_CODE segment PARA public 'code'
    assume cs:MYSEG_CODE, ds:MYSEG_DATA, ss:MYSEG_STACK

MAIN:
    ; 必须重新赋值数据段寄存器
    mov ax, MYSEG_DATA
    mov ds, ax
    mov es, ax

    ; 打印标题
    mov bx, offset STR_TITLE
    push bx
    call fnPrintString

    ; 执行任务
    call fnDoTask_control_cmd

;////////////////////////////////////////////////////////////
;// 运行结果
;////////////////////////////////////////////////////////////

;////////////////////////////////////////////////////////////

    ; 退出程序
    call fnExit
    ret

;////////////////////////////////////////////////////////////
;// 函数 - 执行任务
;////////////////////////////////////////////////////////////
fnDoTask_control_cmd:
    push bp
    mov bp, sp
    push sp
    push dx
    push ax
    push bx
    push cx
    push si

    ; 输入数据, 将数字字符用字符替换表进行替换, 实现简单加密
    mov al, '9'
    push ax
    call fnPrintHexByte

    mov bx, offset STR_ENTER_KEY
    push bx
    call fnPrintString

fnDoTask_control_cmd_switch:
    ; 校验输入字符为 '0' ~ '9' 之间
    cmp al, '0'
    js fnDoTask_control_cmd_switch_end
    cmp al, '9'
    js fnDoTask_control_cmd_switch_is_0_9
    jnz fnDoTask_control_cmd_switch_end

fnDoTask_control_cmd_switch_is_0_9:    
    ;将字符变成数字
    sub al, '0'
    mov bx, offset TAB_LETTER_REPLACE
    xor ah, ah
    mov si, ax
    mov al, [bx + si]

    push ax
    call fnPrintHexByte

    mov bx, offset STR_ENTER_KEY
    push bx
    call fnPrintString

fnDoTask_control_cmd_switch_end:    

    pop si
    pop cx
    pop bx
    pop cx
    pop dx
    pop sp
    pop bp
    ret

;////////////////////////////////////////////////////////////
MYSEG_CODE ends
end MAIN

子函数库头文件

; helper.inc
; imp on helper.asm

extern STR_EQU:BYTE
extern STR_ENTER_KEY:BYTE
extern CHAR_1:BYTE
extern CHAR_0:BYTE

extern fnExit:near

extern fnHalfCharAsBinaryData:near
extern fnCharAsBinaryData:near

extern fnPrintString:near
extern fnPrintChar:near
extern fnPrintBufferAsHexByte:near
extern fnPrintHexByte:near

extern fn_memset:near
extern fn_memmove:near
extern fn_memcpy:near
extern fn_memcmp:near
extern fn_memchr:near

子函数库实现文件

; helper.asm

public STR_EQU
public STR_ENTER_KEY
public CHAR_1
public CHAR_0

public fnExit
public fnPrintString
public fnPrintChar
public fnHalfCharAsBinaryData
public fnPrintHexByte
public fnCharAsBinaryData
public fn_memset
public fnPrintBufferAsHexByte
public fn_memcpy
public fn_memmove
public fn_memcmp
public fn_memchr

MYSEG_DATA segment PARA public "data"
    STR_EQU db ' = ', 24h
    STR_ENTER_KEY db 0dh, 0ah, 24h
    CHAR_1 db '1'
    CHAR_0 db '0'
MYSEG_DATA ends

MYSEG_CODE segment PARA public 'code'
assume cs:MYSEG_CODE, ds:MYSEG_DATA

;
;// 函数名称 - fn_memchr
;// 功能 - void *memchr( const void *buf, int c, size_t count );
;// 调用示例
;// mov ax, 4
;// push ax
;// mov ax, 55h
;// push ax
;// mov ax, offset BUFDST ; dest buffer
;// push ax
;// call fn_memchr
;
fn_memchr:
    push bp
    mov bp, sp
    push sp
    push dx
    push cx
    push si
    push di

    ; 取出参数
    ; 参数1 [bp + 4]
    ; 参数2 [bp + 6]
    ; 参数3 [bp + 8]

    cld
    xor ax, ax
    mov si, [bp + 4] ; buf
    mov dx, [bp + 6] ; c
    mov cx, [bp + 8] ; count

fn_memchr_find_next:
    cmp [si], dl
    jnz fn_memchr_continue
    jmp fn_memchr_end

fn_memchr_continue:    
    inc si
    inc ax
    loop fn_memchr_find_next

    ; can't find
    mov ax, -1
fn_memchr_end:    
    pop di
    pop si
    pop cx
    pop dx
    pop sp
    pop bp
    ret 6 ; 栈平衡, 3个word

;
;// 函数名称 - fn_memmove
;// 功能 - int *memcmp( void *dest, const void *src, size_t count );
;// ax < 0, dest < Src
;// ax == 0, dest == Src
;// ax > 0, dest > Src
;// 调用示例
;// mov ax, 4
;// push ax
;// mov ax, offset BUFSRC ; dest buffer
;// push ax
;// mov ax, offset BUFDST ; dest buffer
;// push ax
;// call fn_memcmp
;
fn_memcmp:
    push bp
    mov bp, sp
    push sp
    push dx
    push cx
    push si
    push di

    ; 取出参数
    ; 参数1 [bp + 4]
    ; 参数2 [bp + 6]
    ; 参数3 [bp + 8]

    cld
    mov di, [bp + 4]
    mov si, [bp + 6]
    mov cx, [bp + 8]
    repz cmpsb

    jnz fn_memcmp_is_less
    mov ax, 0
    jmp fn_memcmp_end

fn_memcmp_is_less:
    jnc fn_memcmp_is_greate
    mov ax, -1
    jmp fn_memcmp_end

fn_memcmp_is_greate:
    mov ax, 1

fn_memcmp_end:    
    pop di
    pop si
    pop cx
    pop dx
    pop sp
    pop bp
    ret 6 ; 栈平衡, 3个word

;
;// 函数名称 - fn_memmove
;// 功能 - void *memmove( void *dest, const void *src, size_t count );
;// 备注 - fn_memcpy 和 fn_memmove 是一个实现, 在MFC中 memcpy 和 memmove 也是一个实现
;// 调用示例
;// mov ax, 4
;// push ax
;// mov ax, offset BUFSRC ; dest buffer
;// push ax
;// mov ax, offset BUFDST ; dest buffer
;// push ax
;// call fn_memmove
;
fn_memcpy:
fn_memmove:
    push bp
    mov bp, sp
    push sp
    push dx
    push cx
    push ax
    push si
    push di

    ; 取出参数
    ; 参数1 [bp + 4]
    ; 参数2 [bp + 6]
    ; 参数3 [bp + 8]

    cld
    mov di, [bp + 4]
    mov si, [bp + 6]
    mov cx, [bp + 8]
    rep movsb

    pop di
    pop si
    pop ax
    pop cx
    pop dx
    pop sp
    pop bp
    ret 6 ; 栈平衡, 3个word

;
;// 函数名称 - fn_memset
;// 功能 - void *memset( void *dest, int c, size_t count );
;// 调用示例
;// mov ax, 4 ; count
;// push ax
;// mov al, 0h ; char to set
;// push ax
;// mov ax, offset BufDst ; dest buffer
;// push ax
;// call fn_memset
;
fn_memset:
    push bp
    mov bp, sp
    push sp
    push dx
    push cx
    push ax

    ; 取出参数
    ; 参数1 [bp + 4]
    ; 参数2 [bp + 6]
    ; 参数3 [bp + 8]

    cld
    mov cx, [bp + 8]
    mov ax, [bp + 6]
    mov di, [bp + 4]
    rep stosb

    pop ax
    pop cx
    pop dx
    pop sp
    pop bp
    ret 6 ; 栈平衡, 3个word

;
fnCharAsBinaryData:
    push bp
    mov bp, sp
    push sp
    push dx
    push cx

    mov cx, 8
fnCharAsBinaryData_RCL:    
    RCL dl, 1
    jnc fnCharAsBinaryData_RCL_is_0
    mov al, CHAR_1
    jmp fnCharAsBinaryData_RCL_loop
fnCharAsBinaryData_RCL_is_0:
    mov al, CHAR_0
fnCharAsBinaryData_RCL_loop:
    push ax
    call fnPrintChar
    loop fnCharAsBinaryData_RCL

    pop cx
    pop dx
    pop sp
    pop bp
    ret 2

;
;// 函数 - 按照16进制字节打印缓冲区
;// 参数 - fnPrintBufferAsHexByte(char* dest, WORD len)
;// 调用示例
;// mov ax, 4
;// push ax
;// mov ax, offset BUF_TO_PRT
;// push ax
;// call fnPrintBufferAsHexByte
;
fnPrintBufferAsHexByte:
    push bp
    mov bp, sp
    push sp
    push dx
    push si
    push cx
    push ax

    ; 取出参数
    mov si, [bp + 4]
    mov cx, [bp + 6]

fnPrintBufferAsHexByte_next:
    mov ax, [si]
    push ax
    call fnPrintHexByte

    inc si
    loop fnPrintBufferAsHexByte_next

    pop ax
    pop cx
    pop si
    pop dx
    pop sp
    pop bp
    ret 4

;
;// 函数 - 打印16进制字节
;// 参数 - 入栈的16进制数据
;
fnPrintHexByte:
    push bp
    mov bp, sp
    push sp
    push dx
    push ax
    push cx

    ; 取出参数
    mov dx, [bp + 4]

    ; 显示字节的高4位为16进制字符
    mov ax, dx
    mov cl, 4
    shr ax, cl
    and ax, 0fh
    push ax
    call fnHalfCharAsBinaryData

    ; 显示字节的低4位为16进制字符
    mov ax, dx
    and ax, 0fh
    push ax
    call fnHalfCharAsBinaryData

    pop cx
    pop ax
    pop dx
    pop sp
    pop bp
    ret 2

;
fnHalfCharAsBinaryData:
    push bp
    mov bp, sp
    push sp
    push ax

    mov ax, [bp + 4]
    cmp al, 9
    jc fnHalfCharAsBinaryData_0_9
    jnz fnHalfCharAsBinaryData_a_f
fnHalfCharAsBinaryData_0_9:
    ; 0 ~ 9
    add al, '0'
    jmp fnHalfCharAsBinaryData_show
fnHalfCharAsBinaryData_a_f:
    sub al, 0ah
    add al, 'A'

fnHalfCharAsBinaryData_show:    
    push ax
    call fnPrintChar

    pop ax
    pop sp
    pop bp
    ret 2

;
;// 函数 - 打印字符
;// 参数 - 入栈的字符
;
fnPrintChar:
    push bp
    mov bp, sp
    push sp
    push dx
    push ax

    mov dx, [bp + 4]
    mov ah, 2
    int 21h

    pop ax
    pop dx
    pop sp
    pop bp
    ret 2

;
;// 函数 - 退出程序
;// 参数 - 无
;// 调用示例
;// call fnExit
;
fnExit:
    mov ax, 4c00h
    int 21h
    ret

;
;// 函数 - 打印字符串
;// 参数 - 入栈的字符串地址
;// 调用示例
;// mov bx, offset STR_TITLE
;// push bx
;// call fnPrintString
;
fnPrintString:
    push bp
    mov bp, sp
    push sp
    push dx
    push ax

    mov dx, [bp + 4]
    mov ah, 9
    int 21h

    pop ax
    pop dx
    pop sp
    pop bp
    ret 2

MYSEG_CODE ends
END

编译脚本

rem hw1j.cmd
del *.obj
del *.exe
ml16 /c hw1j.asm
ml16 /c helper.asm
link16 hw1j.obj helper.obj
debug hw1j.exe
rem hw1j.exe
pause
call cmd

运行结果

这里写图片描述

LostSpeed
关注
超详细：实现 Swift 与 汇编（Asm）代码混编并在真机或模拟器上运行
享受开发，颠倒银河
06-11 581
在本篇博文中，我们图文并茂的详细介绍了如何在真机或模拟器上运行 Swift 和汇编混编后的代码，并通过一个实际例子来测试不同 iPhone 上汇编的执行效率。
【优化系列】汇编优化技术（七）：ARM架构Intrinsic汇编优化及demo
CSDN明星博主，认证博客专家，视频、Matlab领域优质创作者。
08-15 516
DATE: 2021.8.15 文章目录1、前言2、入门知识3、arm intrinsic头及编译方法4、arm intrinsic数据类型及函数介绍4.1 数据类型4.2 intrinsic函数4.3 intrinsic函数介绍5、指令查找手册6、Automatic vectorization7、arm neon Intrinsic demo 1、前言      在ARM汇编优化中，除了ARM纯汇编assembly优化，还有arm Intrinsic优化和arm inline内联优化。前面已经讲述了AR
汇编 头文件 依赖库文件
qq_31155883的博客
04-22 649
Irvine文件夹内容如下 添加头文件和依赖库 链接依赖库
DSP c语言经典程序外加相应的汇编语言头文件
04-13
TI DSP经典c语言程序和汇编头文件资源
汇编：头文件
最新发布
WolvenSec的博客
06-08 1582
汇编头文件（header files）在汇编语言编程中类似于高层语言中的头文件，它们通常包含宏定义、常量定义、数据结构定义、函数声明以及其他在多个汇编源文件中共享的代码；使用头文件可以提高代码的可维护性和可读性，并使代码更加模块化，最常见的汇编头文件扩展名.inc，表示包含文件（include file）。
汇编.s文件包含头文件处理
Ning的博客
06-05 3365
Error[2]: Failed to open #include file ‘FreeRTOSConfig.h’ 解决办法： IAR，在在assembler（汇编编译选项） 的preprocessor（预处理）里，填写好 引用的头文件地址
c语言制表符_C语言 — 必学的编程基础语法，入门就从这里开始！
weixin_39617470的博客
11-29 461
前言欢迎大家一起来学习C语言，小编会定期更新一些干货。要说世界上最著名的计算机语言，毫无疑问就是C语言。基本上所有的PC操作系统都有C语言的身影，学习它你可以不用学习过深，但是基础一定要有。现在来分享吧！1、头文件需要使用的函数都在这里面，因此要先声明使用头文件。头文件有两种声明形式一种是以这个符号包含<>，另一种是以“”包含的。以双引号包含的头文件，先是在当前目录下找这个头文件，然后...
C语言与汇编——宏定义，头文件重复包含，内存申请和释放
markey1的博客
01-19 778
.c文件 -> 替换 -> 编译 -> 链接 -> exe文件 typedef 只能给变量类型起别名。而#define可以给任何东西起别名。 头文件重复包含问题 #pragma once也能避免同一个头文件被包含（include）多次 一般由编译器提供保证：同一个文件不会被包含多次。注意这里所说的“同一个文件”是指物理上的一个文件，而不是指内容相同的两个文件。 你无法对一个头文件中的一段代码作pragma once声明，而只能针对文件。 内存申请和释放 ..
编译原理---C文件和头文件的关系
拾遗阁
11-29 1481
简单的说其实要理解C文件与头文件（即.h）有什么不同之处，首先需要弄明白编译器的工作过程; 一般说来编译器会做以下几个过程： 预处理阶段 词法与语法分析阶段 编译阶段，首先编译成纯汇编语句，再将之汇编成跟CPU相关的二进制码，生成各个目标文件 (.obj文件) 连接阶段，将各个目标文件中的各段代码进行绝对地址定位，生成跟特定平台相关的可执行文件，当然，最后还可以用objcopy生成纯二进...
windows环境下gcc的使用（三）：自定义的头文件路径和make的使用
unclejin_的博客
06-08 4960
上一篇已经验证了一个.c文件是如何通过预编译、编译、汇编、链接四个步骤来一步步变为计算机上的可执行文件的。 当然这只是一个.c文件，如果存在大量的.c文件，以及一些不存在于root路径里的头文件，也就是我们自己定义的文件夹中的.h文件，甚至是.lib或.a的库文件路径，又应该怎么在这些复杂的路径里经过层层筛选，编译连接成一个可执行文件呢？ GCC自然也提供了这样的命令，通过这些命令和参数的结合，就可以将多个路径下的多个.c和.h文件编译链接成一个可执行文件。 那么显然，每一个.c文件都需要执行一次编译命令，
汇编程序中引用头文件
Aruko的博客
03-06 700
汇编程序中也是可以使用头文件的，因为头文件实际上就是预处理中的一环，使用预处理器也对汇编程序中的头文件进行预处理；本文使用的汇编例程：x86版AT&T汇编hello world，ARM版ARM汇编hello world
头文件
flyzer的博客
03-01 635
#include<bits/stdc++.h> #define mem(a,b) memset((a),b,sizeof(a)) #define de cout<<endl<<endl<<endl typedef long long ll; const int inf=0x3f3f3f3f; const int maxn=1e5+10; us...
语言转汇编头文件_C语言程序设计（新生笔记）
weixin_39998795的博客
01-14 113
大一新生报到，大家可以一起学习，一起进步！加油！不定时更新哟编译软件为 VC 6.0，这软件学c没太大问题，虽然有些拉胯；但是学c++就。。。。编译环境为 Win 32 Console Application.编译语言为C++ Source File注：C和C++其实没有太大的区别，只不过可以认为C++是C的优化，C++具有比C更加全面的功能实现。C特点： C语言的独特之处在于，作为一个...
关于.h 与 汇编中的.inc文件
sddi1989的专栏
05-17 7882
<br />      .h文件是C、C++语言需要的“头”文件，一般是对函数、变量等的声明。汇编语言并不能直接引用C、C++语言格式的.h文件。类似功能，对过程（子程序等）、变量、宏等的声明，在汇编语言中常用.inc包含文件，当然需要使用汇编语言的语法格式。
添加汇编缺少的INCLUDE floatio.inc头文件
Cyy246的博客
06-08 630
文章目录一、下载汇编INCLUDE floatio.inc包二、使用步骤 一、下载汇编INCLUDE floatio.inc包 点击获得汇编INCLUDE floatio.inc包https://pan.baidu.com/s/1LwgwDWNcJ82q0ByyBwUzCw 提取码 ：cyy6 二、使用步骤 将floatio.inc放入 Masm615/INCLUDE 目录下 将floatio.obj放入 Masm615/LIB 目录下 进入 Masm615/make32.bat , 点开编辑将flo
汇编函数
qq_41232519的博客
07-26 129
c语言使用汇编语言的头文件,ADS中汇编与C头文件的杂碎事
weixin_42378094的博客
05-24 874
在C语言*.h头文件中使用#define定义一个常量或符号，在汇编语言中如何引用？例如在testheader.h中： #define init_MDREFR 0x0011e018尝试(1)：在要使用该符号或常量的汇编源程序中使用IMPORT init_MDREFR，不行。尝试(2)：在要使用该符号或常量的汇编源程序中使用INCLUDE testheader.h，报错：Unknown opco...
mpg123 version 1.13.0 头文件inc定义
G_Spider的专栏
03-18 2469
;;◎ ◎ mpg123.h->mpg123.inc  use to asm By G-Spider @2011;; Begin of file mpg123.h; ;  libmpg123:MPEG Audio Decoder library (version 1.13.0); ;  copyright 1995-2010 by the mpg123 project - free software under the terms of the LGPL 2.1;  see COPYING and AUTH
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值