Poj1386 Play on Words

原题网址：http://poj.org/problem?id=1386

Play on Words

Time Limit: 1000MS Memory Limit: 10000K
Total Submissions: 11417 Accepted: 3891
Description

Some of the secret doors contain a very interesting word puzzle. The team of archaeologists has to solve it to open that doors. Because there is no other way to open the doors, the puzzle is very important for us.

There is a large number of magnetic plates on every door. Every plate has one word written on it. The plates must be arranged into a sequence in such a way that every word begins with the same letter as the previous word ends. For example, the word acm'' can be followed by the wordmotorola”. Your task is to write a computer program that will read the list of words and determine whether it is possible to arrange all of the plates in a sequence (according to the given rule) and consequently to open the door.
Input

The input consists of T test cases. The number of them (T) is given on the first line of the input file. Each test case begins with a line containing a single integer number Nthat indicates the number of plates (1 <= N <= 100000). Then exactly Nlines follow, each containing a single word. Each word contains at least two and at most 1000 lowercase characters, that means only letters ‘a’ through ‘z’ will appear in the word. The same word may appear several times in the list.
Output

Your program has to determine whether it is possible to arrange all the plates in a sequence such that the first letter of each word is equal to the last letter of the previous word. All the plates from the list must be used, each exactly once. The words mentioned several times must be used that number of times.
If there exists such an ordering of plates, your program should print the sentence “Ordering is possible.”. Otherwise, output the sentence “The door cannot be opened.”.
Sample Input

3
2
acm
ibm
3
acm
malform
mouse
2
ok
ok
Sample Output

The door cannot be opened.
Ordering is possible.
The door cannot be opened.
Source

Central Europe 1999

这题可以看作是a..z 26个字母为顶点，字符串首末字母为边的欧拉路径。先并查集判断连通性，再判断是否存在有向图欧拉路径或回路，判定方法如下：

欧拉回路存在的充要条件（在连通图中） 每个点的度为偶数（无向图） 每个点的入度出度相等（有向图） 欧拉路存在的必要条件：
有且仅有两个点的度为奇数（无向图） 总的入度和等于总的出度和，有且仅有两个点的入度、出度差为1，其他点相等（有向图）
（引用自http://hzwer.com/4987.html）

附欧拉回路与欧拉通路存在性的充要条件及其证明：http://www.cnblogs.com/xpjiang/p/4396106.html

再附上丑陋的代码

var
  a,b,fa:array[0..26] of longint;
  ex:array[0..26] of boolean;
  T,s,n,i,c1,c2,x,y:longint;
  st:ansistring;
  flag:boolean;
function find(x:longint):longint;
  begin
    if fa[x]<>x
      then fa[x]:=find(fa[x]);
    exit(fa[x]);  
  end;
begin
  readln(T);
  if T=0 then halt;
  repeat
    fillchar(a,sizeof(a),0);
    fillchar(b,sizeof(b),0);
    fillchar(ex,sizeof(ex),false);
    readln(n);dec(T);
    for i:=1 to 26 do fa[i]:=i;
    for i:=1 to n do
      begin
        readln(st);
        x:=ord(st[1])-96;
        y:=ord(st[length(st)])-96;
        inc(a[x]);
        inc(b[y]);
        fa[find(x)]:=find(y);
        ex[x]:=true;
        ex[y]:=true;
      end;
    flag:=true;
    for i:=1 to 26 do
      if (ex[i])and(find(i)<>find(x)) then
        begin
          flag:=false;
          break;
        end;
    c1:=0;c2:=0;
    for i:=1 to 26 do
      if ex[i] then
        begin
          if a[i]-b[i]=1
            then inc(c1)
            else if a[i]-b[i]=-1
                   then inc(c2)
                   else if a[i]<>b[i] then
                          begin
                            flag:=false;
                            break;
                          end;
        end;                  
    flag:=flag and ((c1=1) and (c2=1) or (c1=0) and (c2=0));
    if flag
      then writeln('Ordering is possible.')
      else writeln('The door cannot be opened.');
  until T=0;
end.