王爽《汇编语言》第三版-实验10 编写子程序

1.显示字符串

;子程序描述
;名称: show_str
;功能:在指定的位置，用指定的颜色，显示一 个用0结束的字符串。
;参数: (dh)=行号(取值范围0~24)，(d)=列 号(取值范围0~79),
	   ;(cl)=颜色，ds:si指向字符串的首地址
;返回:无
;应用举例:在屏幕的8行3列，用绿色显示data段中的字符串。

assume cs:code,ds:data
data segment
	db 'Welcome to masm!',0
data ends

code segment
start:
	mov dh,8           ;行号
	mov dl,3           ;列号
	mov cl,2           ;颜色
	mov ax,data
	mov ds,ax
	mov si,0           ;ds：si指向字符串的首地址
	call show_str
	  
mov ah,4ch
int 21h
	  
show_str: 
	mov ax,0b800h
	mov es,ax            ;使用ds和es寄存器作为段寄存器
	mov al,160
	mul dh
	mov dh,0
	dec dx
	add ax,dx
	add ax,dx
	mov di,ax            ;将计算出的第一个字符的偏移地址存在di中
	mov al, cl
	   
s:  mov bl, [si]                  
	mov es:[di], bl      ;存入字符
	mov es:[di+1], al    ;设置属性字节
	
	inc si
	add di,2             ;每个字符占2个字节
	mov cx, [si]
	jcxz ok              ;遇0结束
	jmp short s          ;循环存入字符
ok: ret
	   
code ends
end start

2.解决除法溢出的问题

;名称: divdw
;功能:进行不会产生溢出的除法运算，被除数为dword型，除数为word型，结果为dword型。
;参数: (ax)=dword 型数据的低16位，(dx)=dword型数据的高16位，(cx)=除数
;返回: (dx)=结果的高16位，(ax)=结果的低，16位(cx)=余数
;应用举例:计算1000000/10(F420H/0AH)
;结果：(dx)=0001H，(ax)=86A0H，(cx)=0

;公式:
;X: 被除数，范围: [0，FFFFFFFF]
;N: 除数，范围: [0, FFFF]
;H: X高16位，范围: [0, FFFF]
;L: X低16位，范围: [0, FFFF]
;int():描述性运算符，取商，比如，int(38/10)=3
;rem():描述性运算符，取余数，比如，rem(38/10)=8
;公式: X/N= int(H/N)*65536 +[rem(HN)*65536+L]/N

assume cs:code
code segment
start:mov ax, 4240h
	mov dx, 000Fh
	mov cx, 0Ah          ;设置被除数与除数
	call divdw
	
mov ah,4ch
int 21h
	  
divdw:mov bp, ax         ;将被除数的低16位暂存于bp
	mov ax, dx           
	mov dx, 0            
	div cx               ;H/N，结果为(DX)=rem(H/N),(AX)=int(H/N)
	mov bx, ax           ;将int(H/N)暂存至bx
	mov ax, bp           ;rem(H/N)*65536+L，结果为32位，高位存于DX，低位存于AX
	div cx               ;[rem(H/N)*65536+L]/N，结果商存于AX，余数存于DX
	mov cx, dx           ;将余数移至CX
	mov dx, bx           ;int(H/N)*65536后高位存于DX，低位为0
ret
	   
code ends
end start

3.数值显示

;名称: dtoc
;功能: 将word型数据转变为表示十进制数的字符串，字符串以0为结尾符。
;参数: (ax)=word型数据，ds:si指向字符串的首地址
;返回: 无
;应用举例: 编程，将数据12666 以十进制的形式在屏幕的8行3列，用绿色显示出来。

assume cs:code,ds:data
data segment
	db 10 dup(0)           ;开辟内存空间存储字符串
data ends

code segment
start:
	mov ax, 12666
	mov bx, data
	mov ds, bx    
	mov si, 0
	call dtoc	
	mov dh,8               ;行号
	mov dl,3               ;列号
	mov cl,2               ;颜色
	call show_str
	
mov ah,4ch
int 21h
	  
dtoc:
	mov bx, 10
	mov dx, 0
	div bx                 ;余数存在dx
	add dl,30h             ;十进制数字加30h为其ASCII码
	mov [si], dl
	inc si
	mov cx,ax
	jcxz over              ;若ax为0则结束
	jmp short dtoc
over:
	mov ax, si
	mov dx, 0
	mov cx, 2
	div cx
	mov cx,ax
	mov bx, 0
re:                        ;翻转数字顺序
	mov al, [bx]           
	mov ah, [si-1]
	mov [bx], ah
	mov [si-1], al
	inc bx
	dec si
loop re
ret

show_str: 
	mov ax,0b800h
	mov es,ax              ;使用ds和es寄存器作为段寄存器
	mov si, 0
	mov al,160
	mul dh
	mov dh,0
	dec dx
	add ax,dx
	add ax,dx
	mov di,ax              ;将计算出的第一个字符的偏移地址存在di中
	mov al, cl  
s:  
	mov bl, [si]                  
	mov es:[di], bl            
	mov es:[di+1], al      ;设置属性字节
	
	inc si
	add di,2               ;每个字符占2个字节
	mov cx, [si]
	jcxz ok                ;遇0结束
    jmp short s 
ok: ret

code ends
end start