1.显示字符串
问题
显示字符串是现实工作中经常要用到的功能,应该编写一个通用的子程序来实现这个功能。我们应该提供灵活的调用接口,使调用者可以决定显示的位置(行、列)、内容和颜色。
子程序描述
名称:show_str
功能:功能:在指定的位置,用指定的颜色,显示一个用0结束的字符串。
参数:(dh)=行号(取值范围0 ~ 24),(dl)=列号(取值范围0 ~ 79),(cl)颜色,ds:si指向字符串首地址
返回:无
应用举例:在屏幕的8行3列,用绿色显示data段中的字符串
提示
(1)子程序的入口参数是屏幕上的行号和列号,注意在子程序内部要将它们转化为显存中的地址,首先要分析一下屏幕上的行列位置和显存地址的对应关系;
(2)注意保存子程序中用到的相关寄存器;
(3)这个子程序的内部处理和显存的结构密切相关,但是向外提供了与显存结构无关的接口。通过调用这个子程序,进行字符串的显示时可以不必了解显存的结构,为编程提供了方便。在实验中,注意体会这种设计思想。
实现代码
assume cs:code
data segment
db 'welcome to masm!',0
data ends
code segment
start: mov dh,8
mov dl,3
mov cl,2
mov ax,data
mov ds,ax
mov si,0
call show_str
mov ax,4c00h
int 21h
show_str: mov al,0ah
mul dh
add ax,0b800h
mov es,ax ;获取具体行的段地址
mov bh,0
mov bl,dl
add bl,dl ;es:bx定位地址显示字符
mov si,0
mov dl,cl ;dl存储要显示的color
s: mov cl,ds:[si]
mov ch,0
jcxz ok ;如果cx == 0退出循环
mov al,ds:[si]
mov es:[bx],al ;设置字符
mov es:[bx+1],dl ;设置color
inc si
add bx,2
jmp short s
ok: ret
code ends
end start
运行结果
2.解决除法溢出问题
问题
前面讲过,div指令可以做除法。当进行8位除法的时候,用al存储结果的商,ah存储结果的余数;进行16位除法的时候,用ax存储结果的商,dx存储结果的余数。可是,现在有一个问题,如果结果的商大于al 或 ax所能存储的最大值,那么将如何?
比如下面的程序段:
mov bh,1
mov ax,1000
div bh
进行的是8位除法,结果的商为1000,而1000在al中放不下。
又比如,下面的程序段:
mov ax,1000h
mov dx,1
mov bx,1
div bx
进行的是16位除法,结果的商为11000H,而 11000H在ax 中存放不下。
我们在用div指令做除法的时候,很可能发生上面的情况:结果的商过大,超出了寄存器所能存储的范围。当CPU执行 div等除法指令的时候,如果发生这样的情况,将引发CPU的一个内部错误,这个错误被称为:除法溢出。我们可以通过特殊的程序来处理这个错误,但在这里我们不讨论这个错误的处理,这是后面的课程中要涉及的内容。下面我们仅仅来看一下除法溢出发生时的一些现象,如图所示:
好了,我们已经清楚了问题的所在:用div指令做除法的时候可能产生除法溢出。由于有这样的问题,在进行除法运算的时候要注意除数和被除数的值,比如1000000/10 就不能用div指令来计算。那么怎么办呢?我们用下面的子程序divdw解决。
子程序描述
名称:divdw
功能:进行不会产生溢出的除法运算,被除数为 dword型,除数为word 型,结果为dword型。
参数:(ax)=dword型数据的低16位,(dx)=dword型数据的高16位,(cx)=除数
返回:(dx)=结果的高16位,(ax)=结果的低16位,(cx)=余数
应用举例:计算1000000/10(F4240H/0AH)
mov ax,4240h
mov dx,000fh
mov cx,0ah
call divdw
结果:(dx)=0001h,(ax)=86a0h,(cx)=0
提示
给出一个公式:
X:被除数,范围:[0, FFFFFFFF]
N:除数,范围:[0, FFFF]
H:X高16位,范围:[0, FFFF]
L:X低16位,范围:[0, FFFF]
int():描述性运算符,取商,比如,int(38/10)=3
rem():描述性运算符,取余数,比如,rem(38/10)=8
公式: X / N = int(H / N) * 65536 + [rem(H / N) * 65536 + L] / N
这个公式将可能产生溢出的除法运算:X/N,转变为多个不会产生溢出的除法运算。公式中,等号右边的所有除法运算都可以用div指令来做,肯定不会导致除法溢出。
实现代码
assume cs:code
stack segment
dw 8 dup (0)
stack ends
code segment
start: mov ax,4240h
mov dx,000fh
mov cx,0ah
call divdw
mov ax,4c00h
int 21h
;*65536相当于左移4位
;X/N = H/N*65536 + (H%N*65536+L)/N
divdw: push ax ;先将低16位入栈保存
mov ax,dx
sub dx,dx
div cx ;计算H/N以及H%N, 得到的H/N(ax)就是最终结果的高16位
pop bx ;取出L
push ax ;最终结果的高16位入栈
mov ax,bx
div cx ;计算结果的低16位商放在ax
mov cx,dx ;将结果的余数放在cx
pop dx ;将结果的高16位放在dx
ret
code ends
end start
运行结果
3.数值显示
问题
编程,将data段中的数据以十进制的形式显示出来
data segment
dw 123,12666,1,8,3,38
data ends
这些数据在内存中都是二进制信息,标记了数值的大小。要把它们显示到屏幕上,成为我们能够读懂的信息,需要进行信息的转化。比如,数值12666,在机器中存储为二进制信息:0011000101111010B(317AH),计算机可以理解它。而要在显示器上读到可以理解的数值12666,我们看到的应该是一串字符:“12666”。由于显卡遵循的是 ASCII编码,为了让我们能在显示器上看到这串字符,它在机器中应以ASCII码的形式存储为:31H、32H、36H、36H、36H(字符“0” ~ “9”对应的ASCII码为30H ~ 39H)。
通过上面的分析可以看到,在概念世界中,有一个抽象的数据12666,它表示了一个数值的大小。在现实世界中它可以有多种表示形式,可以在电子机器中以高低电平(二进制)的形式存储,也可以在纸上、黑板上、屏幕上以人类的语言“12666”来书写。现在,我们面临的问题就是,要将同一抽象的数据,从一种表示形式转化为另一种表示形式。
可见,要将数据用十进制形式显示到屏幕上,要进行两步工作:
(1)将用二进制信息存储的数据转变为十进制形式的字符串;
(2)显示十进制形式的字符串。
第二步我们在本次实验的第一个子程序中已经实现,在这里只要调用一下show_str即可。我们来讨论第一步,因为将二进制信息转变为十进制形式的字符串也是经常要用到的功能,我们应该为它编写一个通用的子程序。
子程序描述
名称:dtoc
功能:将word型数据转变为表示十进制数的字符串,字符串以0为结尾符。
参数:(ax)=word型数据,ds:si指向字符串的首地址
返回:无
应用举例:编程,将数据12666以十进制的形式在屏幕的8行3列,用绿色显示出来。在显示时我们调用本次实验中的第一个子程序show_str。
提示
需要取得每位数值可采用num对10取余的方式然后num/=10,一直到num==0为止
实现代码
assume cs:code
data segment
db 10 dup (0)
data ends
code segment
start:
mov ax,12666
mov bx,data
mov ds,bx
mov si,0
call dtoc
mov dh,8
mov dl,3
mov cl,2
call show_str
mov ax,4c00h
int 21h
dtoc:
mov bx,10
s0: mov dx,0
div bx
push dx
inc si
mov cx,ax ;商传递给cx判断是否为0
jcxz d_ok
jmp short s0
d_ok:
mov cx,si
sub si,si
s1: pop bx
add bx,'0'
mov ds:[si],bl
inc si
loop s1
ret
show_str:
mov al,0ah
mul dh
add ax,0b800h
mov es,ax ;获取具体行的段地址
mov bh,0
mov bl,dl
add bl,dl ;es:bx定位地址显示字符
mov si,0
mov dl,cl ;dl存储要显示的color
s: mov cl,ds:[si]
mov ch,0
jcxz s_ok ;如果cx == 0退出循环
mov al,ds:[si]
mov es:[bx],al ;设置字符
mov es:[bx+1],dl ;设置color
inc si
add bx,2
jmp short s
s_ok: ret
code ends
end start