本文详细解析了STM32启动文件startup_stm32f10x_hd.s的内容及作用，包括初始化堆栈指针SP、程序计数器PC、设置堆栈大小等关键步骤。介绍了汇编指令如EQU、AREA、SPACE等的应用，并深入分析了向量表、复位程序及用户堆栈初始化的过程。
STM32启动文件——startup_stm32f10x_hd.s
宗旨：技术的学习是有限的，分享的精神是无限的。
一、启动文件的作用
（关于启动代码的作用，前面已经提到过了，这里再啰嗦一下）
（1）初始化堆栈指针 SP；
（2）初始化程序计数器指针 PC；
（3）设置堆、栈的大小；
（4）设置异常向量表的入口地址；
（5）配置外部 SRAM作为数据存储器（这个由用户配置，一般的开发板可没有外部 SRAM）；
（6）设置 C库的分支入口__main（最终用来调用 main函数）；
（7）在 3.5版的启动文件还调用了在 system_stm32f10x.c文件中的SystemIni()函数配置系统时钟。
二、启动文件中提到的汇编指令
| 指令 | 作用 |
| EQU | 给数字常量取一个符号名，相当于 C 语言中的 define |
| AREA | 汇编一个新的代码段或者数据段 |
| SPACE | 分配内存空间 |
| PRESERVE8 | 当前文件堆栈需按照 8 字节对齐 |
| EXPORT | 声明一个标号具有全局属性，可被外部的文件使用 |
| DCD | 以字为单位分配内存，要求 4 字节对齐，并要求初始化这些内存 |
| PROC | 定义子程序，与 ENDP 成对使用，表示子程序结束 |
| WEAK | 弱定义，如果外部文件声明了一个标号，则优先使用外部文件定义的标号，如果外部文件没有定义也不出错。 |
| IMPORT | 声明标号来自外部文件，跟 C 语言中的 EXTERN 关键字类似 |
| B | 跳转到一个标号 |
| ALIGN | 编译器对指令或者数据的存放地址进行对齐，一般需要跟一个立即 |
| END | 到达文件的末尾，文件结束 |
| IF,ELSE,ENDIF | 汇编条件分支语句，跟 C 语言的类似 |
| LDR | 从存储器中加载字到一个寄存器中 |
| BL | 跳转到由寄存器/标号给出的地址，并把跳转前的下条指令地址保存到 LR |
| BLX | 跳转到由寄存器给出的地址，并根据寄存器的 LSE 确定处理器的状态，还要把跳转前的下条指令地址保存到 LR |
| BX | 跳转到由寄存器/标号给出的地址，不用返回 |
三、启动代码详解
1、stack——栈
Stack_Size EQU 0x00000400
AREA STACK, NOINIT, READWRITE,ALIGN=3
Stack_Mem SPACE Stack_Size
__initial_sp分配名为STACK，不初始化，可读可写，8（2^3）字节对齐的1KB空间。
栈：局部变量，函数形参等。栈的大小不能超过内部SRAM大小。
AREA：汇编一个新的代码段或者数据段。STACK段名，任意命名；NOINIT表示不初始化；READWRITE可读可写；ALIGN=3（2^3= 8字节对齐）。
__initial_sp紧挨了SPACE放置，表示栈的结束地址，栈是从高往低生长，结束地址就是栈顶地址。
2、heap——堆
Heap_Size EQU 0x00000200
AREA HEAP, NOINIT, READWRITE,ALIGN=3
__heap_base
Heap_Mem SPACE Heap_Size
__heap_limit分配名为HEAP，不初始化，可读可写，8（2^3）字节对齐的512字节空间。__heap_base堆的起始地址，__heap_limit堆的结束地址。堆由低向生长。动态分配内存用到堆。
PRESERVE8 //指定当前文件的堆栈按照 8 字节对齐。
THUMB //表示后面指令兼容 THUMB 指令。THUBM 是ARM 以前的指令集，16bit，现在 Cortex-M 系列的都使用 THUMB-2 指令集，THUMB-2 是32 位的，兼容 16 位和 32 位的指令，是 THUMB 的超级。
3、向量表
AREA RESET, DATA, READONLY
EXPORT __Vectors
EXPORT __Vectors_End
EXPORT __Vectors_Size定义一个名为RESET，可读的数据段。并声明 __Vectors、__Vectors_End 和__Vectors_Size 这三个标号可被外部的文件使用。
__Vectors DCD __initial_sp ; Top of Stack
DCD Reset_Handler ; Reset Handler
DCD NMI_Handler ; NMI Handler
DCD HardFault_Handler ; Hard Fault Handler
DCD MemManage_Handler ; MPU Fault Handler
DCD BusFault_Handler ; Bus Fault Handler
DCD UsageFault_Handler ; Usage Fault Handler
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD SVC_Handler ; SVCall Handler
DCD DebugMon_Handler ; Debug Monitor Handler
DCD 0 ; Reserved
DCD PendSV_Handler ; PendSV Handler
DCD SysTick_Handler ; SysTick Handler
; External Interrupts
DCD WWDG_IRQHandler ; Window Watchdog
DCD PVD_IRQHandler ; PVD through EXTI Line detect
DCD TAMPER_IRQHandler ; Tamper
DCD RTC_IRQHandler ; RTC
DCD FLASH_IRQHandler ; Flash
DCD RCC_IRQHandler ; RCC
DCD EXTI0_IRQHandler ; EXTI Line 0
DCD EXTI1_IRQHandler ; EXTI Line 1
DCD EXTI2_IRQHandler ; EXTI Line 2
DCD EXTI3_IRQHandler ; EXTI Line 3
DCD EXTI4_IRQHandler ; EXTI Line 4
DCD DMA1_Channel1_IRQHandler ; DMA1Channel 1
DCD DMA1_Channel2_IRQHandler ; DMA1Channel 2
DCD DMA1_Channel3_IRQHandler ; DMA1Channel 3
DCD DMA1_Channel4_IRQHandler ; DMA1Channel 4
DCD DMA1_Channel5_IRQHandler ; DMA1Channel 5
DCD DMA1_Channel6_IRQHandler ; DMA1Channel 6
DCD DMA1_Channel7_IRQHandler ; DMA1 Channel 7
DCD ADC1_2_IRQHandler ; ADC1 & ADC2
DCD USB_HP_CAN1_TX_IRQHandler ; USBHigh Priority or CAN1 TX
DCD USB_LP_CAN1_RX0_IRQHandler; USB Low Priority or CAN1 RX0
DCD CAN1_RX1_IRQHandler ; CAN1 RX1
DCD CAN1_SCE_IRQHandler ; CAN1 SCE
DCD EXTI9_5_IRQHandler ; EXTI Line 9..5
DCD TIM1_BRK_IRQHandler ; TIM1 Break
DCD TIM1_UP_IRQHandler ; TIM1 Update
DCD TIM1_TRG_COM_IRQHandler ; TIM1Trigger and Commutation
DCD TIM1_CC_IRQHandler ; TIM1 Capture Compare
DCD TIM2_IRQHandler ; TIM2
DCD TIM3_IRQHandler ; TIM3
DCD TIM4_IRQHandler ; TIM4
DCD I2C1_EV_IRQHandler ; I2C1 Event
DCD I2C1_ER_IRQHandler ; I2C1 Error
DCD I2C2_EV_IRQHandler ; I2C2 Event
DCD I2C2_ER_IRQHandler ; I2C2 Error
DCD SPI1_IRQHandler ; SPI1
DCD SPI2_IRQHandler ; SPI2
DCD USART1_IRQHandler ; USART1
DCD USART2_IRQHandler ; USART2
DCD USART3_IRQHandler ; USART3
DCD EXTI15_10_IRQHandler ; EXTI Line 15..10
DCD RTCAlarm_IRQHandler ; RTC Alarm through EXTI Line
DCD USBWakeUp_IRQHandler ; USB Wakeup from suspend
DCD TIM8_BRK_IRQHandler ; TIM8 Break
DCD TIM8_UP_IRQHandler ; TIM8 Update
DCD TIM8_TRG_COM_IRQHandler ; TIM8Trigger and Commutation
DCD TIM8_CC_IRQHandler ; TIM8 Capture Compare
DCD ADC3_IRQHandler ; ADC3
DCD FSMC_IRQHandler ; FSMC
DCD SDIO_IRQHandler ; SDIO
DCD TIM5_IRQHandler ; TIM5
DCD SPI3_IRQHandler ; SPI3
DCD UART4_IRQHandler ; UART4
DCD UART5_IRQHandler ; UART5
DCD TIM6_IRQHandler ; TIM6
DCD TIM7_IRQHandler ; TIM7
DCD DMA2_Channel1_IRQHandler ; DMA2Channel1
DCD DMA2_Channel2_IRQHandler ; DMA2Channel2
DCD DMA2_Channel3_IRQHandler ; DMA2Channel3
DCD DMA2_Channel4_5_IRQHandler; DMA2 Channel4 & Channel5
__Vectors_End__Vectors_Size EQU __Vectors_End - __Vectors
__Vectors 为向量表起始地址，__Vectors_End 为向量表结束地址，两个相减即可算出向量表大小。
向量表从 FLASH 的 0 地址开始放置，以 4 个字节为一个单位，地址 0 存放的是栈顶地址，0X04 存放的是复位程序的地址，以此类推。从代码上看，向量表中存放的都是中断服务函数的函数名，可我们知道 C 语言中的函数名就是一个地址。
4、复位程序
AREA |.text|, CODE, READONLY定义一个名为.text,可读的代码段
Reset_Handler PROC
EXPORT Reset_Handler [WEAK]
IMPORT __main
IMPORT SystemInit
LDR R0, =SystemInit
BLX R0
LDR R0, =__main
BX R0
ENDP复位子程序是系统上电后第一个执行的程序，调用 SystemInit ()函数初始化系统时钟，然后调用 C 库函数_main。
5、终端服务子程序
NMI_Handler PROC
EXPORT NMI_Handler [WEAK]
B .
ENDP
HardFault_Handler\
PROC
EXPORT HardFault_Handler [WEAK]
B .
ENDP
MemManage_Handler\
PROC
EXPORT MemManage_Handler [WEAK]
B .
ENDP此处省略部分……
启动文件里面已经帮我们写好所有中断的中断服务函数，跟我们平时写的中断服务函数不一样的就是这些函数都是空的，真正的中断复服务程序需要我们在外部的 C 文件里面重新实现，这里只是提前占了一个位置而已。
如果我们在使用某个外设的时候，开启了某个中断，但是又忘记编写配套的中断服务程序或者函数名写错，那当中断来临的时，程序就会跳转到启动文件预先写好的空的中断服务程序中，并且在这个空函数中无线循环，即程序就死在这里。
B：跳到一个“.”，表示无限循环。
6、用户堆栈初始化
ALIGN
ALIGN：对指令或者数据存放的地址进行对齐，后面会跟一个立即数。缺省表示 4 字节对齐。
IF :DEF:__MICROLIB
EXPORT __initial_sp
EXPORT __heap_base
EXPORT __heap_limit
ELSE
IMPORT __use_two_region_memory
EXPORT __user_initial_stackheap
__user_initial_stackheap
LDR R0, = Heap_Mem
LDR R1, =(Stack_Mem +Stack_Size)
LDR R2, = (Heap_Mem + Heap_Size)
LDR R3, = Stack_Mem
BX LR
ALIGN
ENDIF
END 判断是否定义了__MICROLIB ，如果定义了则赋予标号__initial_sp（栈顶地址）、__heap_base（堆起始地址）、__heap_limit（堆结束地址）全局属性，可供外部文件调用。如果没有定义（实际的情况就是我们没定义__MICROLIB）则使用默认的 C 库，然后初始化用户堆栈大小，这部分有 C 库函数__main 来完成。
扫一扫
1623
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
