VBA中四种常见排序算法的实现

一、冒泡排序法

1、概念

冒泡排序（Bubble Sort），是一种计算机科学领域的较简单的排序算法。

它重复地走访过要排序的元素列，依次比较两个相邻的元素，如果顺序（如从大到小、首字母从Z到A）错误就把他们交换过来。走访元素的工作是重复地进行直到没有相邻元素需要交换，也就是说该元素列已经排序完成。

这个算法的名字由来是因为越小的元素会经由交换慢慢“浮”到数列的顶端（升序或降序排列），就如同碳酸饮料中二氧化碳的气泡最终会上浮到顶端一样，故名“冒泡排序”。

2、算法原理

比较相邻的元素。如果第一个比第二个大，就交换他们两个。

对每一对相邻元素做同样的工作，从开始第一对到结尾的最后一对。在这一点，最后的元素应该会是最大的数。

针对所有的元素重复以上的步骤，除了最后一个。

持续每次对越来越少的元素重复上面的步骤，直到没有任何一对数字需要比较。

3、vba代码

Sub 冒泡排序法()

Dim arr

Dim n As Integer, i As Integer, j As Integer

Dim temp

t = Timer

n = Range("A1").CurrentRegion.Rows.Count

arr = Range(Cells(1, 1), Cells(n, 1))

For i = 1 To n - 1 Step 1

    For j = 1 To n - i Step 1   

        If arr(j, 1) > arr(j + 1, 1) Then       

            temp = arr(j, 1)           

            arr(j, 1) = arr(j + 1, 1)           

            arr(j + 1, 1) = temp           

        End If       

    Next j   

Next i

Range("A1").Resize(n, 1) = arr

Range("E4") = Timer - t

End Sub

二、选择排序法

1、算法原理

首先在未排序序列中找到最小（大）元素，存放到排序序列的起始（末尾）位置，然后，再从剩余未排序元素中继续寻找最小（大）元素，然后放到已排序序列的后面（前面）。以此类推，直到所有元素均排序完毕。

2、VBA代码

Sub 选择排序法()

Dim arr

Dim n As Integer, i As Integer, j As Integer, k As Integer

Dim temp

t = Timer

n = Range("A65536").End(xlUp).Row

arr = Range(Cells(1, 1), Cells(n, 1))

For i = 1 To n - 1 Step 1

    k = i

    For j = i + 1 To n Step 1   

       If arr(j, 1) < arr(k, 1) Then      

            k = j           

        End If       

    Next j   

    temp = arr(i, 1)   

    arr(i, 1) = arr(k, 1)   

    arr(k, 1) = temp   

Next i

Range("A1").Resize(n, 1) = arr

Range("E6") = Timer - t

End Sub

三、插入排序法

1、原理

就是检查第i个数字，如果在它的左边的数字比它大，进行交换，这个动作一直继续下去，直到这个数字的左边数字比它还要小，就可以停止了。插入排序法主要的回圈有两个变数：i和j，每一次执行这个回圈，就会将第i个数字放到左边恰当的位置去。

将第2个数字赋值给过渡变量，从第2个数值开始向左边检查，如果其大于第2个数字，其向右移动一格，直至遇到第j个数字不大于第2个数字，第2个数字填充到第j个数字的右侧。依次类推，将第i个数字赋值给过渡变量，，从第i个数值开始向左边检查，如果其大于第i个数字，其向右移动一格，直至遇到第j个数字不大于第i个数字，第i个数字填充到第j个数字的右侧。依次类推，直至最后一个数字

2、VBA代码

Sub 插入排序法()

Dim arr

Dim n As Integer, i As Integer, j As Integer

Dim temp

t = Timer

n = Range("A65536").End(xlUp).Row

arr = Range(Cells(1, 1), Cells(n, 1))

For i = 2 To n Step 1

    temp = arr(i, 1)

    For j = i - 1 To 1 Step -1   

        If arr(j, 1) > temp Then       

            arr(j + 1, 1) = arr(j, 1)           

        Else       

            Exit For           

        End If       

    Next j   

    arr(j + 1, 1) = temp   

Next i

Range("A1").Resize(n, 1) = arr

Range("E8") = Timer - t

End Sub

四、希尔排序法

1、概念

希尔排序法(缩小增量法) 属于插入类排序，是将整个无序列分割成若干小的子序列分别进行插入排序的方法。

希尔排序法通常初次取序列的一半为增量，以后每次减半，直到增量为1。

2、VBA代码

Sub 希尔排序法()

Dim arr

Dim jg As Integer, n As Integer

t = Timer

n = Range("A65536").End(xlUp).Row

arr = Range(Cells(1, 1), Cells(n, 1))

jg = VBA.Fix(n / 2)

Do While jg > 0

    arr = 间隔插入排序法(arr, jg)   

    jg = VBA.Fix(jg / 2)   

Loop

Range("A1").Resize(n, 1) = arr

Range("E10") = Timer - t

End Sub

Function 间隔插入排序法(ByVal arr, jg As Integer) '用于某一间隔的插入排序

Dim n As Integer, i As Integer, j As Integer, k As Integer

Dim temp

n = UBound(arr, 1)

For i = 1 To jg Step 1

    For j = i + jg To n Step jg   

        temp = arr(j, 1)       

        For k = j - jg To i Step -jg       

            If arr(k, 1) > temp Then           

                arr(k + jg, 1) = arr(k, 1)               

            Else           

                Exit For               

            End If           

        Next k       

        arr(k + jg, 1) = temp       

    Next j   

Next i

间隔插入排序法 = arr

End Function