先贴一份代码
public class Main {
public static void main(String[] args) {
int j = 0;
for (int i = 0; i < 100; i++) {
j = j++;
}
System.out.println(j);
}
}
今天无意中看到了Java中间缓存变量机制这个概念,然后百度了一把相关文章还是挺多的,不过10篇文章9篇都是一样的,你懂的,综合起来说就是当执行 j = j++; 时,其实与以下三句代码等效
int temp = j;
j = j+1;
j = temp;
上面的解释很直接,可是为什么会有这样的一个等价呢?没找到解释…
我查看了以下上面代码的字节码(javap -c Main.class),结果如下:
D:\>javac Main.java
D:\>javap -c Main.class
Compiled from "Main.java"
public class Main {
public Main();
Code:
0: aload_0
1: invokespecial #1 // Method java/lang/Object."<init>":()V
4: return
public static void main(java.lang.String[]);
Code:
0: iconst_0
1: istore_1
2: iconst_0
3: istore_2
4: iload_2
5: bipush 100
7: if_icmpge 21
10: iload_1
11: iinc 1, 1
14: istore_1
15: iinc 2, 1
18: goto 4
21: getstatic #2 // Field java/lang/System.out:Ljava/io/PrintStream;
24: iload_1
25: invokevirtual #3 // Method java/io/PrintStream.println:(I)V
28: return
}
下面简单说一下第10到15条指令:
10. iload_1 将索引号为1的常量(j)压至栈顶
11. iinc 1, 1 将索引号位1的常量(j)自增1
14. istore_1 将栈顶数据保存到索引号为1的位置
15. iinc 2, 1 将索引号位2的常量(i)自增1
很显然,iinc 指令,是对本地变量的操作,并没有对栈顶的数据进行自增,当再次将栈顶值保存到 j 中时,自然而然就覆盖了之前的自增操作。那么最后j=0
对比来看一下下面的代码
public class Main {
public static void main(String[] args) {
int j = 0;
for (int i = 0; i < 100; i++) {
j = j+1;
}
System.out.println(j);
}
}
字节码如下
D:\>javac Main.java
D:\>javap -c Main.class
Compiled from "Main.java"
public class Main {
public Main();
Code:
0: aload_0
1: invokespecial #1 // Method java/lang/Object."<init>":()V
4: return
public static void main(java.lang.String[]);
Code:
0: iconst_0
1: istore_1
2: iconst_0
3: istore_2
4: iload_2
5: bipush 100
7: if_icmpge 20
10: iload_1
11: iconst_1
12: iadd
13: istore_1
14: iinc 2, 1
17: goto 4
20: getstatic #2 // Field java/lang/System.out:Ljava/io/PrintStream;
23: iload_1
24: invokevirtual #3 // Method java/io/PrintStream.println:(I)V
27: return
}
修改之后,第10条指令将 j 的值压栈,然后常量1压栈,执行栈顶两个数相加,将相加的结果保存到 j 中,这样最后 j 的值就是100.
PS:如有说的不对的地方请批评,有不懂得请留言.