android studio使用gradle自定义导出jar文件

在android studio中导出jar文件并不像在eclipse那样简单，不过也不是太复杂。需要用到gradle脚本来导出jar文件。

我们不希望导出的jar文件带有R.class和BuildConfig.class这样的类，所以我们需要编写gradle脚本来实现自定义jar文件内容。

先打开module项目下的build.gradle文件，在android{}标签下编写task命令，如下是我的gradle文件：

apply plugin: 'com.android.application'

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.2"

    defaultConfig {
        applicationId "com.example.testapp"
        minSdkVersion 14
        targetSdkVersion 23
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

}

task buildMyJar(type: Jar, dependsOn: ['build']) {
    //导出的jar文件名称
    archiveName = 'TestApp.jar'
    //从哪个目录打包jar
    from('build/intermediates/classes/debug')
    //导出的jar文件的存放目录（未指定则默认存放在build/libs下）
    destinationDir = file('build/libs')
    //去掉不要的类
    exclude('com/example/testapp/BuildConfig.class')
    exclude('com/example/testapp/BuildConfig\$*.class')
    exclude('**/R.class')
    exclude('**/R\$*.class')
    //需要打包的类
    include('com/example/testapp/*.class')
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    testCompile 'junit:junit:4.12'
    compile 'com.android.support:appcompat-v7:23.1.1'
    compile 'com.android.support:design:23.1.1'
    compile 'com.google.android.gms:play-services-appindexing:8.1.0'
}

如果需要将assets文件夹也打包进jar文件，则可在buildMyJar 任务中加入一下两行：

from fileTree(dir: 'src/main',includes: ['assets/**'])

include('assets/**')

写好gradle脚本后点击“sync now”

打开android studio右侧的Gradle面板，选择项目名——>other——>buildMyJar（task名称）

双击后运行该脚本，就会在build/libs目录下生成jar文件。用jd-gui打开该jar文件可以看到里面的class文件没有包含R.class之类的文件

 

 

转载于:https://www.cnblogs.com/SusieBlog/p/5405265.html