装配中的颜色

作者:梁晓冬

零件的每个面都可以有自己的颜色。插入到装配中，有些用户想改变这些面的颜色。两个思路：一是直接修改零件面的实际颜色；另一种改变在装配中显示的颜色（对应API是FaceProxy）。

图表 1

 

我们知道，第一种思路，需要找到零件的实际面，例如FaceProxy.NativeObject, 或者获取零件文档，寻找到对应的面（Face）。从结果图2可以看到是零件的面颜色变了。

 

Sub changeNativeFaceColor()

 

'打开一个装配文档

Dim oAssDoc As AssemblyDocument

Set oAssDoc = ThisApplication.ActiveDocument

 

'直接拾取一个面，从API角度看是FaceProxy

Dim oFaceProxy As FaceProxy

Set oFaceProxy = oAssDoc.SelectSet(1)

 

'获取文档某个颜色

Dim oRS As RenderStyle

Set oRS = oAssDoc.RenderStyles("Pink")

 

'设置实际面的颜色

oFaceProxy.NativeObject.SetRenderStyle kOverrideRenderStyle, oRS

 

oAssDoc.Update

 

End Sub

图表 2

 

第二种思路目前只能是改变整个组件（ComponentOccurrence）的颜色，而不能修改单个FaceProxy的颜色。所以以下宏changeFaceProxyColor会失败。

 

Sub changeFaceProxyColor()

 

'打开一个装配文档

Dim oAssDoc As AssemblyDocument

Set oAssDoc = ThisApplication.ActiveDocument

 

'直接拾取一个面，从API角度看是FaceProxy

Dim oFaceProxy As FaceProxy

Set oFaceProxy = oAssDoc.SelectSet(1)

 

'获取文档某个颜色

Dim oRS As RenderStyle

Set oRS = oAssDoc.RenderStyles("Pink")

 

'设置FaceProxy的颜色 ->>>>失败！

oFaceProxy.SetRenderStyle kOverrideRenderStyle, oRS

 

oAssDoc.Update

 

End Sub

 

我们可修改整个组件颜色，如图3。零件面的实际颜色并没有变。

 

Sub changeOccurenceColor()

 

'打开一个装配文档

Dim oAssDoc As AssemblyDocument

Set oAssDoc = ThisApplication.ActiveDocument

 

'获取文档某个颜色

Dim oRS As RenderStyle

Set oRS = oAssDoc.RenderStyles("Pink")

 

'设置第一个组件的颜色

oAssDoc.ComponentDefinition.Occurrences(1).SetRenderStyle kOverrideRenderStyle, oRS

 

oAssDoc.Update

 

End Sub

 

图表 3

 

到此似乎一切都OK，但是当这个组件有了装配特征（如图4，添加一个倒角特征），你会发现修改单个面的实际颜色（changeNativeFaceColor）失败了！这是为什么呢？

 

图表 4

 

简单讲：没有装配特征，组件上的面（FaceProxy）和零件实际面（Face）一一对应，通过FaceProxy找寻到NativeObject没有问题 （图5）。

图表 5

 

但当有了装配特征，Inventor 会在装配中创建一个中间体（不可见）。 零件面和这个中间实体对应，即FaceProxy.NativeObject返回的是中间体的面，而不是零件实际面。所以，当试图去修改这个NativeObject的颜色就失败了，因为中间体就不可见（图6）。

 

图表 6

 

那这种情况下怎么办呢？可以先判断该组件是否有中间体（ComponentOccurrence. HasBodyOverride = True），如果是则用FaceProxy. GetSourceFace 获取到零件实际面。如果不是（即没有装配特征），则还是用FaceProxy.NativeObject。

 

Sub changeNativeOrSourceFaceColor()

 

'打开一个装配文档

Dim oAssDoc As AssemblyDocument

Set oAssDoc = ThisApplication.ActiveDocument

 

'直接拾取一个面，从API角度看是FaceProxy

Dim oFaceProxy As FaceProxy

Set oFaceProxy = oAssDoc.SelectSet(1)

 

'获取文档某个颜色

Dim oRS As RenderStyle

Set oRS = oAssDoc.RenderStyles("Pink")

 

'设置实际面的颜色

If oFaceProxy.ContainingOccurrence.HasBodyOverride Then '有中间体

If Not oFaceProxy.GetSourceFace Is Nothing Then ' 有对应实际面

oFaceProxy.GetSourceFace.SetRenderStyle kOverrideRenderStyle, oRS

End If

Else '无中间体

oFaceProxy.NativeObject.SetRenderStyle kOverrideRenderStyle, oRS

End If

 

oAssDoc.Update

End Sub

 

图表 7

 

不过对于装配特征生成的面，如图4中的4号面，它没有任何零件面所对应，则没有GetSourceFace。而它的NativeObject又是在中间体上，因此无法修改颜色。有人会问，那我就是想改变它的颜色，咋办？那只能是修改整个组件的颜色了。

 

以上案例分享可以让大家在定制中少走些弯路。