MASM win32汇编 《获取所有进程信息》修改版

知识点：
1）对win32 API加深理解与运用能力。
2）了解了window资源的脚本与二进制资源的使用。
3）编译环境:MASM.

此为第二稿，解决了很多新手常犯的错误。以此稿以记之，以备后查。

只修改汇编源文件部分，资源部分没有错误，不修改。

 

-------------汇编源文件部分 pe2.asm-------------------------

.386
.model flat, stdcall
option casemap:none

include /masm32/include/windows.inc
include /masm32/include/kernel32.inc
include /masm32/include/user32.inc

includelib /masm32/lib/kernel32.lib
includelib /masm32/lib/user32.lib

; 等值定义，宏定义
IDD_MAIN           equ             1
IDC_PROCESS_LIST   equ             100
IDC_BTN_PROCESS    equ             101

IDD_PROCESS        equ             2
IDC_BTN_OPEN       equ             200
IDC_LB_PROCESS     equ             201

; 函数声明
_ProDlgProc    proto stdcall hWnd:dword, uMsg:dword, wParam:dword, lParam:dword
_PrintProcess  proto hWndLB:dword

; 数据段
.data
szX db 'ddddddd', 0

; 常量
.const
szProcessFormat db '%08X -- %s', 0

; 代码段
.code

;------------------------------------------------------------------
; 主对话框窗口过程函数(类似普通窗口过程函数，只是返回值的意义不同)
; _MainDlgProc    hWnd:dword, uMsg:dword, wParam:dword, lParam:dword
;------------------------------------------------------------------
_MainDlgProc proc hWnd:dword, uMsg:dword, wParam:dword, lParam:dword
    .if uMsg == WM_CLOSE
        invoke EndDialog, hWnd, 0
    .elseif uMsg == WM_COMMAND
            mov eax, wParam
            .if ax == IDC_BTN_PROCESS   
                 invoke GetModuleHandle, NULL
                 mov ecx, eax
                 invoke DialogBoxParam, ecx, IDD_PROCESS, NULL, addr _ProDlgProc, 0
            .endif
    .else
        mov eax, FALSE ;//不感兴趣，交给系统处理。
        ret
    .endif
        mov eax, TRUE ;//我们自己处理了，系统不用再处理了。 
        ret  
_MainDlgProc endp

;------------------------------------------------------------------
; 显示进程对话框窗口过程函数(类似普通窗口过程函数，只是返回值的意义不同)
; _ProDlgProc    hWnd:dword, uMsg:dword, wParam:dword, lParam:dword
;------------------------------------------------------------------
_ProDlgProc proc hWnd:dword, uMsg:dword, wParam:dword, lParam:dword
    .if uMsg == WM_CLOSE
        invoke EndDialog, hWnd, 0
    .elseif uMsg == WM_COMMAND
        mov eax, wParam
        .if ax == IDC_BTN_OPEN

        .endif
    .elseif uMsg == WM_INITDIALOG
            invoke GetDlgItem, hWnd, IDC_LB_PROCESS
            invoke _PrintProcess, eax
    .else
        mov eax, FALSE ;//不感兴趣，交给系统处理。
        ret
    .endif
        mov eax, TRUE ;//我们自己处理了，系统不用再处理了。 
        ret  
_ProDlgProc endp

;------------------------------------------------------------------
; 打印进程清单
; _PrintProcess 
;------------------------------------------------------------------
_PrintProcess proc hWndLB:dword

    local @stPe:PROCESSENTRY32
    local @szProcessInfo[MAX_PATH]:byte
    local @hSnap:dword   

    invoke RtlZeroMemory, addr @stPe, sizeof PROCESSENTRY32
    mov @stPe.dwSize, sizeof PROCESSENTRY32
  
    invoke CreateToolhelp32Snapshot, TH32CS_SNAPALL, 0
    mov @hSnap, eax
   
    invoke Process32First, @hSnap, addr @stPe
   
    .while eax
        invoke RtlZeroMemory, addr @szProcessInfo, MAX_PATH
        invoke wsprintf, addr @szProcessInfo, addr szProcessFormat, @stPe.th32ProcessID, addr @stPe.szExeFile
        invoke SendMessage, hWndLB, LB_ADDSTRING, 0, addr @szProcessInfo
        invoke Process32Next, @hSnap, addr @stPe
    .endw
   
    ret
_PrintProcess endp

;--------------------------------------------------------------------
; 程序入口
;--------------------------------------------------------------------
start:
    ; 程序实例
    invoke GetModuleHandle, NULL
    mov ecx, eax
    invoke DialogBoxParam, ecx, IDD_MAIN, NULL, addr _MainDlgProc, 0
    invoke ExitProcess, 0
end start

;-------------------------------------------------------------------
; 修改历史
;-------------------------------------------------------------------