Groovy实现接口
在Groovy中你可以使用Map和代码块快速的实现接口.在这个部分, 首先会用Java方式来实现接口, 接着教你如何利用Groovy工具.这里是一个熟悉得不能再熟悉的Swing JButton事件处理程序. 为了调用addActionListener( )你必须实现ActionListener 接口. 因此, 你就必须得创建匿名的内部类来实现 ActionListener,而且还必须实现actionPerformed( ) 方法.
// Java code
button.addActionListener(new ActionListener() {
public void actionPerformed(ActionEvent ae){
JOptionPane.showMessageDialog(frame, " You clicked!" );
}
});
Groovy 带来了迷人而通用的方法—不需要actionPerformed( ) 方法或创建任何的匿名类
button.addActionListener(
{ JOptionPane.showMessageDialog(frame, "You clicked!" ) } as ActionListener
)
这里你只需要在addActionListener方法中提供一个代码块,通过as操作符来实现 ActionListener
就这么简单—Groovy 帮你搞定其他的一切. Groovy 拦截所有的接口调用(actionPerformed( ))
假如你想在鼠标点击或离开更新Label上的信息. 要是用Java,你必须实现 MouseListener 和MouseMotionListener 接口总共7个方法. 还好,Groovy更加容易的处理:
displayMouseLocation = {
positionLabel.setText("$it.x, $it.y" )
}
frame.addMouseListener(displayMouseLocation as MouseListener)
frame.addMouseMotionListener(displayMouseLocation as MouseMotionListener)
在这里, 你创建displayMouseLocation 变量引用一个代码块. 然后使用as来实现MouseListener 和 MouseMotionListener. 在上面的代码, 你又一次看见了 it 变量. it 代表方法的参数.现在你不必了解这个it变量,因为在后面介绍闭包的时候会详细的讲解(现在你只要记住怎么实现接口的)OK, 现在看上去感觉非常好,不过很多现实情况是: 你需要实现接口的不同方法. 不用担心, Groovy都能帮你搞定. 只要简单的创建一个Map—简单的使用(:)来分隔方法名和代码块. . 同样, 你没有必要实现所有的方法(做过Swing的人都知道,很多事件处理接口方法其实我们并不需要,我们关心的只是那些需要的,如果所有方法都实现,无疑让我们感觉浪费,也增加我们对那长串代码的厌倦). 现在让我们来看看实例:
handleFocus = [
focusGained : { msgLabel.setText("Good to see you!" ) },
focusLost : { msgLabel.setText("Come back soon!" ) }
]
button.addFocusListener(handleFocus as FocusListener)
当button获得焦点,与之关联的 Key– focusGained 被调用. 当button失去焦点, 与之关联的Key– focusLost 被调用. 这里的Key FocusListenerInterface接口中的方法,假如你想添加事件处理方式给不同的事件:WindowListener,ComponentListener, …当然这些列
表是可以动态改变的. 假设你的处理程序执行某些共同的操作,比如 logging 或者更新状态栏—有些任务是测试或调试你的应用程序.你可以使用单个代码块动态添加事件处理器给多个事件:
events = ['WindowListener' , 'ComponentListener' ]
// Above list may be dynamic and may come from some input
handler = {
msgLabel.setText("$it" )
}
for (event in events) {
handlerImpl = handler.asType(Class.forName("java.awt.event.${event}" ))
frame."add${event}" (handlerImpl)
}
你想处理的事件在一个事件列表events中. 列表是动态的;这些不同的事件的事件处理程序在变量handler所引用的代码块中. 循环 events中的每个事件,使用 asType( ) 方法创建每个接口的实现.在代码块上调用此方法 并使用 forName( )方法获得接口的Class metaobject作为参数.上面的代码, 在代码块上使用asType( ) 方法. 假如你不同的方法有不同的实现, 可以使用Map代替单一的代码块. 这样的话, 你可以用简单的方式在Map上调用asType( )方法 . 最后, 给出一个实例:
frame = new JFrame(size:[300,300],layout:new FlowLayout(), defaultCloseOperation:javax.swing.WindowConstants.EXIT_ON_CLOSE)
frame.setVisible(true)
button = new Button("click")
positionLabel = new JLabel("")
msgLabel = new JLabel("")
frame.contentPane.add button
frame.contentPane.add positionLabel
frame.contentPane.add msgLabel
button.addActionListener(
{JOptionPane.showMessageDialog(frame,"You clicked!")} as ActionListener
)
displayMouseLocation = { positionLabel.setText("$it.x, $it.y" ) }
frame.addMouseListener(displayMouseLocation as MouseListener)
frame.addMouseMotionListener(displayMouseLocation as MouseMotionListener)
handleFocus = [
focusGained : { msgLabel.setText("Good to see you!" ) },
focusLost : { msgLabel.setText("Come back soon!" ) }
]
button.addFocusListener(handleFocus as FocusListener)
events = ['WindowListener' , 'ComponentListener' ]
// Above list may be dynamic and may come from some input
handler = { msgLabel.setText("$it" ) }
for (event in events)
{
handlerImpl = handler.asType(Class.forName("java.awt.event.${event}" ))
frame."add${event}" (handlerImpl)
}
frame.show()