函数栈帧的创建与销毁

什么是函数栈帧呢？

在写代码的时候经常会把一个独立的功能抽象成函数，C程序是以函数为基本单位的。

局部变量是如何创建的呢？为什么局部变量不初始化内容是随机的呢？函数如何调用呢？函数返回值如何返回呢？传参的底层逻辑又是什么呢？

学会了函数栈帧，这些问题都将迎刃而解。

函数栈帧（stack frame）

函数栈帧是函数调用过程中在程序的调用栈（call stack）所开辟的空间。

这些空间是用来存放：

1.函数参数和函数返回值

2.临时变量（包括函数的非静态的局部变量以及编译器自动生产的其他临时变量）

3.保存上下文信息（包括在函数调用前后需要保持不变的寄存器）。

栈的解释

栈（stack）是现代计算机程序里最为重要的概念之一，几乎每一个程序都使用了栈，没有栈就没有函数，没有局部变量，就没有我们如今看到的计算机语言。

在经典的计算机科学中，栈被定义为一种特殊的容器，用户可以将数据压入栈中（入栈:push），也可以将已经压入栈中的数据弹出（出栈:pop）。

程序栈实例

栈保存了一个函数调用所需要的维护信息（常被称作堆栈帧或活动记录） 

栈这个容器必须遵守一条规则：先入栈的数据后出栈（First In Last Out， FIFO）。

在计算机系统中，栈则是一个具有以上属性的动态内存区域。程序可以将数据压入栈中，也可以将数据从栈顶弹出。压栈操作使得栈增大，而弹出操作使得栈减小。

在经典的操作系统中，栈总是向下增长（由高地址向低地址）的。 在我们常见的i386或者x86-64下，栈顶由成为 esp 的寄存器进行定位的。

寄存器

eax：通用寄存器，保留临时数据，常用于返回值

ebx：通用寄存器，保留临时数据

ebp：栈底寄存器

esp：栈顶寄存器

eip：指令寄存器，保存当前指令的下一条指令的地址

汇编命令

mov：数据转移指令

push：数据入栈，同时esp栈顶寄存器也要发生改变

pop：数据弹出至指定位置，同时esp栈顶寄存器也要发生改变

sub：减法命令

add：加法命令

call：函数调用：1. 压入返回地址 2. 转入目标函数

jump：通过修改eip，转入目标函数，进行调用

ret：恢复返回地址，压入eip，类似pop eip命令

初识函数栈帧

每一次函数调用，都要为本次函数调用在栈区上申请一块内存空间来保存函数调用期间的各种变量的值，这块空间被称为运行时堆栈（函数栈帧）。

这块空间的维护是使用了2个寄存器： esp 和 ebp， ebp 记录的是栈底的地址（指向函数活动记录的一个固定位置）， esp 记录的是栈顶 的地址。

ebp寄存器又被称为帧指针

活动记录实例

在参数之后的数据（包括参数）就是当前函数的活动记录，ebp固定在固定位置，不随函数执行的变化而变化。esp始终指向栈顶，随着函数的执行会不断变化。

 固定不变的ebp可以用来定位函数活动记录中的各种数据：在ebp之前是这个函数的返回地址（它的地址是ebp-4），再往前是压入栈中的参数（它们的地址分别是ebp-8，ebp-12等，视参数数量和大小而定）ebp所直接指向的数据是调用该函数之前ebp的值，这样在函数返回时，ebp可以通过读取这个值恢复到调用前的值。

函数调用过程

把所有或一部分参数压入栈中，如果有其他参数没有入栈，那么使用某些特定寄存器传递

把当前指令的下一条指令压入栈中

跳转到函数体执行

ebp入栈

ebp=esp（这时ebp指向栈顶，此时栈顶为old ebp）

sub esp，xxx（在栈上分配xx字节的临时空间）

push xxx（保存名为xxx寄存器，可重复）

把ebp入栈是为了函数返回时便于恢复以前的ebp值。之所以保存一些寄存器，在于编译器可能要求某些寄存器在调用前后保持不变，函数就可以在调用开始时将这些寄存器的值压入栈中，结束后取出。在函数返回时，所进行的“标准”结尾和“标准”开头正好相反

pop xxx 如有必要，恢复保存过的寄存器（可重复）

pop ebp 从栈中恢复保存的ebp的值

ret 从栈中取得返回地址，并跳转到该位置

tips：GCC编译器有一个参数叫做-fomit-frame-pointer可以取消帧指针（不用任何帧指针，通过esp直接计算帧变量的位置），这样做喜忧参半：好处是多出一个ebp可供使用，坏处是帧上寻址速度会变慢，而且没有帧指针后，无法准确定位函数的调用的轨迹。 

在栈上压入数据导致esp减小，弹出数据使esp增大。

直接减小esp的值相当于在栈上开辟空间，直接增大esp相当于在栈上回收空间。

函数不返回，对应栈帧空间就一直被占用，当递归调用时，会开辟属于自己的栈帧空间，直到开始回归才逐层释放栈帧空间，递归层次太深会浪费太多栈帧空间，可能导致栈溢出。

函数栈帧的创建和销毁过程，在不同的编译器上实现的方法大同小异，下面以VS2019为例演示这个过程。

实现

示例代码

#include <stdio.h>
int Add(int x, int y)
{
	int z = 0;
	z = x + y;
	return z;
}
int main()
{
	int a = 3;
	int b = 5;
	int ret = 0;
	ret = Add(a, b);
	printf("%d\n", ret);
	return 0;
}

操作

在VS上点击调试，找到窗口中的调用堆栈： 

可以看到这样的内容：

 函数调用堆栈是反馈函数调用逻辑的，我们可以清晰的观察到，main 函数调用之前，是由 invoke_main 函数来调用main函数。

在 invoke_main 函数之前的函数调用先不考虑，我们可以确定的是，invoke_main 函数会有自己的栈帧，main 函数和 Add 函数也会维护自己的栈帧，每个函数栈帧都有自己的 ebp 和 esp 来维护栈帧空间。

那么main函数的栈帧是如何创建的呢？下面开始说明：

tips：为了方便我们观察函数栈帧创建及销毁的过程，提前进行一些操作方便观察

调试到main函数开始执行的第一行，右击鼠标转到反汇编。

tips：VS编译器每次调试都会为程序重新分配内存，反汇编代码是一次调试代码过程中数据，每 次调试略有差异。 

main函数

栈帧创建

int main()
{
//函数栈帧的创建
00BE1820 push ebp
00BE1821 mov ebp,esp
00BE1823 sub esp,0E4h
00BE1829 push ebx
00BE182A push esi
00BE182B push edi
00BE182C lea edi,[ebp-24h]
00BE182F mov ecx,9
00BE1834 mov eax,0CCCCCCCCh
00BE1839 rep stos dword ptr es:[edi]
//main函数中的核心代码
int a = 3;
00BE183B mov dword ptr [ebp-8],3
int b = 5;
00BE1842 mov dword ptr [ebp-14h],5
int ret = 0;
00BE1849 mov dword ptr [ebp-20h],0
ret = Add(a, b);
00BE1850 mov eax,dword ptr [ebp-14h]
00BE1853 push eax
00BE1854 mov ecx,dword ptr [ebp-8]
00BE1857 push ecx
00BE1858 call 00BE10B4
00BE185D add esp,8
00BE1860 mov dword ptr [ebp-20h],eax
printf("%d\n", ret);
00BE1863 mov eax,dword ptr [ebp-20h]
00BE1866 push eax
00BE1867 push 0BE7B30h
00BE186C call 00BE10D2
00BE1871 add esp,8
return 0;
00BE1874 xor eax,eax
}

main函数转换来的汇编代码如上所示。

那么每一行代码都是什么含义呢？

00BE1820 push ebp

 这行是在把ebp寄存器中的值进行压栈，此时的ebp中存放的是 invoke_main函数栈帧的ebp，esp-4（由高地址向低地址使用）

00BE1821 mov ebp,esp 

move指令会把esp的值存放到ebp中，相当于产生了main函数的ebp，这个值就是invoke_main函数栈帧的esp 

00BE1823 sub esp,0E4h 

 sub会让esp中的地址减去一个16进制数字0xe4,产生新的esp，此时的esp是main函数栈帧的esp，此时结合上一条指令的ebp和当前的esp，ebp和esp之间维护了一 个块栈空间，这块栈空间就是为main函数开辟的，即main函数的栈帧空间，这一段空间中将存储main函数中的局部变量，临时数据以及调试信息等。

00BE1829 push ebx //将寄存器ebx的值压栈，esp-4
00BE182A push esi //将寄存器esi的值压栈，esp-4
00BE182B push edi //将寄存器edi的值压栈，esp-4

上面3条指令保存了3个寄存器的值在栈区，这3个寄存器的在函数随后执行中可能会被修改，所以先保存寄存器原来的值，以便在退出函数时恢复。

栈帧初始化

00BE182C lea edi,[ebp-24h]            //把ebp-24h的地址放在edi中
00BE182F mov ecx,9                    //把9放在ecx中
00BE1834 mov eax,0CCCCCCCCh           //把0xCCCCCCCC放在eax中
00BE1839 rep stos dword ptr es:[edi]  //将从edp-0x2h到ebp这一段的内存的每个字节都初始化为0xCC

上面的这四行代码等价于下面的伪代码：

edi = ebp-0x24;
ecx = 9;
eax = 0xCCCCCCCC;
for(; ecx = 0; --ecx,edi+=4)
{
*(int*)edi = eax;
}

示意图： 

tips：烫烫烫~

#include<stdio.h>
int main()
{
  char arr[20];
  printf("%s\n",arr);
  return 0;
}

为什么这段代码输出的结果是烫烫烫呢？是因为main函数在被调用时，在栈区开辟的空间的其中么一个字节都被初始化成0xCC，而arr数组就是一个未初始化的数组，恰好就在这块空间上创建，0xCCCC（两个连续排列的0xCC）的汉字编码就为“烫”，所以0xCCCC被当作文本就是“烫”（并不是电脑觉得自己烫，手动狗头）

局部变量创建和初始化

int a = 3;
00BE183B mov dword ptr [ebp-8],3   //将3存储到ebp-8的地址处，ebp-8的位置是a变量
int b = 5;
00BE1842 mov dword ptr [ebp-14h],5 //将5存储到ebp-14h的地址处，ebp-14h的位置是b变量
int ret = 0;
00BE1849 mov dword ptr [ebp-20h],0 //将0存储到ebp-20h的地址处，ebp-20h的位置是ret变量

以上汇编代码表示变量a，b，ret的创建和初始化，即局部的变量的创建和初始化

局部变量是在局部变量所在函数的栈帧空间中创建的

 Add函数

 函数调用

ret = Add(a, b);  //调用Add函数

传参

传参就是把参数push到栈帧空间中

00BE1850 mov eax,dword ptr [ebp-14h] //传递b，将ebp-14h处放的5放在eax寄存器中
00BE1853 push eax                    //将eax的值压栈，esp-4
00BE1854 mov ecx,dword ptr [ebp-8]   //传递a，将ebp-8处放的3放在ecx寄存器中
00BE1857 push ecx                    //将ecx的值压栈，esp-4

跳转调用函数

00BE1858 call 00BE10B4
00BE185D add esp,8
00BE1860 mov dword ptr [ebp-20h],eax

这里是展示函数调用的过程 ，call 指令执行函数调用逻辑，在执行call指令之前先会把call指令的下一条指令的地址进行压栈操作，这个操作是为了完成当函数调用结束后要回到call指令的下一条指令的地方，继续往后执行的操作。

Add的反汇编代码

int Add(int x, int y)
{
00BE1760 push ebp
00BE1761 mov ebp, esp
00BE1763 sub esp, 0CCh
00BE1769 push ebx
00BE176A push esi
00BE176B push edi
int z = 0;
00BE176C mov dword ptr[ebp - 8], 0
z = x + y;
00BE1773 mov eax, dword ptr[ebp + 8]
00BE1776 add eax, dword ptr[ebp + 0Ch]
00BE1779 mov dword ptr[ebp - 8], eax
return z;
00BE177C mov eax, dword ptr[ebp - 8]
}
00BE177F pop edi
00BE1780 pop esi
00BE1781 pop ebx
00BE1782 mov esp, ebp
00BE1784 pop ebp
00BE1785 ret

代码执行到Add函数的时候，就要开始创建Add函数的栈帧空间了。

在Add函数中创建栈帧的方法和在main函数中是相似的，在栈帧空间的大小上略有差异而已。

1. 将main函数的 ebp 压栈

2. 计算新的 ebp 和 esp

3. 将 ebx，esi，edi 寄存器的值保存

4. 计算求和，通过ebp中的地址进行偏移访问到了函数调用前压栈进去的参数，即形参访问。

5. 将求出的和放在eax寄存器尊准备带回

逐行解析代码：

维护函数栈帧

00BE1760 push ebp     //将main函数栈帧的ebp保存,esp-4
00BE1761 mov ebp,esp  //将main函数的esp赋值给新的ebp，ebp现在是Add函数的ebp
00BE1763 sub esp,0CCh //给esp-0xCC，求出Add函数的esp

压栈

00BE1769 push ebx //将ebx的值压栈,esp-4
00BE176A push esi //将esi的值压栈,esp-4
00BE176B push edi //将edi的值压栈,esp-4

 创建变量

int z = 0;
00BE176C mov dword ptr [ebp-8],0 //将0放在ebp-8的地址处，即创建z

 计算

z = x + y;                           //接下来计算的是x+y，结果保存到z中
00BE1773 mov eax,dword ptr [ebp+8]   //将ebp+8地址处的数字存储到eax中
00BE1776 add eax,dword ptr [ebp+0Ch] //将ebp+12地址处的数字加到eax寄存中
00BE1779 mov dword ptr [ebp-8],eax   //将eax的结果保存到ebp-8的地址处，即放到z中

返回值 

return z;
00BE177C mov eax,dword ptr [ebp-8] //将ebp-8地址处的值放在eax中，其实就是
把z的值存储到eax寄存器中，这里是想通过eax寄存器带回计算的结果，做函数的返回值。
}

 

 

图片中的 a' 和 b' 其实就是 Add 函数的形参 x , y 。这里的分析很好的说明了函数的传参过程，以及函数 在进行值传递调用的时候，形参其实是实参的一份拷贝。对形参的修改不会影响实参。 

函数栈帧的销毁

当函数调用要结束返回的时候，前面创建的函数栈帧也开始销毁。那具体是怎么销毁的呢？

00BE177F pop edi     //在栈顶弹出一个值，存放到edi中，esp+4
00BE1780 pop esi     //在栈顶弹出一个值，存放到esi中，esp+4
00BE1781 pop ebx     //在栈顶弹出一个值，存放到ebx中，esp+4
00BE1782 mov esp,ebp //再将Add函数的ebp的值赋值给esp，相当于回收了Add函数的栈帧空间
00BE1784 pop ebp     //弹出栈顶的值存放到ebp，栈顶此时的值恰好就是main函数的ebp，esp+4，此时恢复了main函数的栈帧维护，esp指向main函数栈帧的栈顶，ebp指向了main函数栈帧的栈底。
00BE1785 ret         //ret指令的执行，首先是从栈顶弹出一个值，此时栈顶的值就是call指令下一条指令的地址，此时esp+4，然后直接跳转到call指令下一条指令的地址处，继续往下执行。

 回到call指令的下一条指令的地方：

调用完Add函数，回到main函数的时候，继续往下执行，可以看到： 

00BE185D add esp,8                   //esp直接+8，相当于跳过了main函数中压栈的a'和b'
00BE1860 mov dword ptr [ebp-20h],eax //将eax中值存档到ebp-0x20的地址处，即存储到main函数中ret变量中，而此时eax中就是Add函数中计算的x和y的和，本次函数的返回值由eax寄存器带回来。程序是在函数调用返回之后，在eax中去读取返回值的

 返回对象内置类型时，一般都是通过寄存器来带回返回值的，返回对象如果是较大的对象，一般会在主调函数的栈帧中开辟一块空间，然后把这块空间的地址，隐式传递给被调函数，在被调函数中通过地址找到主调函数中预留的空间，将返回值直接保存到主调函数的。