实验三 获取传感数据（二）

实验时间：2012-12-25

实验内容：获取温湿度和光照强度传感数据，并通过串口上传到PC，并进行数据分析

实现功能：根据Telsob节点提供的温湿度传感器（SHT11）和光照强度传感器（S1087），采集环境参数（温度、湿度和光照强度）。

系统上电后，1秒定时器启动，分别依此采集温度、湿度和光照强度，并通过串口将数据上传到上位机。

【实验数据及解析】程序调试成功后，串口接收到的数据如下：

7E 45 00 00 00 00 00 06 00 0617 DF04 9200 2F 11 6D 7E

7E 45 00 00 FF 00 00 06 00 0617 DB04 9000 6A 59 C9 7E

7E 45 00 00 FF 00 00 06 00 0617 DF04 9200 68 59 C9 7E

 

……

上面涂彩色底纹的数据本别表示温度、湿度和光照强度。

查阅SHT11的datasheet，得到如下转换关系：

温度=-39.60+0.01*val

相对湿度=-4+0.0405*val+（-2.8*10^-6）*(val^2)

 

注意：

1）为方便调试，在程序中加入了printf函数。要试验该功能，需要添加#include “prinrtf.h”，并且需要再Makefile中添加：

CFLAGS += -I$(TOSDIR)/lib/printf

2）使用printf函数，是由节点通过串口向终端输送数据，因此，针对本实验（有串口通信），在调试完毕后，需要将printf函数屏蔽掉，否则会出新另外一些不关心的数据。在实际应用系统中，特别要注意该问题，否则影响串口数据的接收，增加数据干扰！

 

3）在实验过程中，还对传感数据的读取速率进行了粗糙的测试。从程序可以看出，采样周期约为1秒，同时通过LED0可以看出的确为1秒。但是，修改该定时参数，例如：

改为100ms：LED0灯闪烁频率为0.5秒左右

改为10ms：也为0.5秒左右

改为5000ms：5秒

……

可知，传感数据读取时间是大于100ms小于500ms。小于500ms的定时参数均失效。

 

【完整代码】
EnvironmentSenseC.nc文件
/*
author:dickychen
function:to realize the function collecting the environment parameters,such as humidity,temperature and light intensity
date:2012-12-25
*/

#include "printf.h"

module EnvironmentSenseC
{
  uses
    {
      interface Boot;
      interface Leds;
      interface SplitControl as UartControl;
      interface Timer<TMilli> as Timer0;
      interface Read<uint16_t> as ReadTemperature;
      interface Read<uint16_t> as ReadHumidity;
      interface Read<uint16_t> as Light;
      interface Packet;
      interface AMSend as UartSend;
    }
}
   implementation
  {
      //uint_16 Tem,Hum,Lig;
      typedef nx_struct RealMsg
     {
       nx_uint16_t Tem;
       nx_uint16_t Hum;
       nx_uint16_t Lig;
     }RealMsg;
     uint16_t wendu,shidu,liangdu;
    message_t ToUartMsg;
    task void SendMsg2Uart();
      event void Boot.booted()
       {
          call UartControl.start();
       }
       event void UartControl.startDone(error_t error)
        {
          if(error == SUCCESS)
             {
               call Timer0.startPeriodic(1000);
             }
        }
      
       event void UartControl.stopDone(error_t error){}
       
       event void Timer0.fired()
         {
           call ReadTemperature.read();           
          }
        event void ReadTemperature.readDone(error_t result,uint16_t temp)
          {
            if(result == SUCCESS)
              {
                wendu =temp;
               //   printf("the local Temperature is :");
                //  printf("%d -->",temp);
                 temp = -39.60 + 0.01*temp;
                 // printf("%d C" ,temp);
              }
             else
                wendu = 0xFFFF; 
             call ReadHumidity.read();
          }
        event void ReadHumidity.readDone(error_t result,uint16_t temp)
          {
             if(result == SUCCESS)
                shidu =temp;
             else
                shidu = 0xFFFF; 
             call Light.read();
          }
        event void Light.readDone(error_t result,uint16_t temp)
          {
             if(result == SUCCESS)
                liangdu = temp;
             else
                liangdu = 0xFFFF; 
            post SendMsg2Uart();
          }
         
       task void SendMsg2Uart()
          {
             
            //piont to payload
            RealMsg *btrpkt = (RealMsg *)(call Packet.getPayload(&ToUartMsg,sizeof(RealMsg)));
            
            btrpkt->Tem = wendu;
          //  printf("-->%d \n\n",wendu);
            btrpkt->Hum = shidu;
            btrpkt->Lig = liangdu;
            call UartSend.send(0x00,&ToUartMsg,sizeof(RealMsg));
            call Leds.led2Toggle();
            
          }
         event void UartSend.sendDone(message_t *msg,error_t error)
           {
              if(error == SUCCESS)
                  call Leds.led0Toggle();
              else
                 call Leds.led1Toggle();
           }
  }
EnvironmentSenseAppC.nc文件
/*
author:dickychen
function:to realize the function collecting the environment parameters,such as humidity,temperature and light intensity
date:2012-12-25
*/

configuration EnvironmentSenseAppC
{}

implementation
{
  components EnvironmentSenseC,MainC,LedsC;
  components new TimerMilliC() as TimerC0;
  components new SensirionSht11C() as Temp_HumiC;
  components new HamamatsuS1087ParC() as LightIntensityC;
  components SerialActiveMessageC as SerialAcMsgC;
  components new SerialAMSenderC(6);

  EnvironmentSenseC.Boot -> MainC;
  EnvironmentSenseC.Timer0 -> TimerC0;
  EnvironmentSenseC.Leds -> LedsC;
  EnvironmentSenseC.UartControl -> SerialAcMsgC;
  EnvironmentSenseC.ReadTemperature -> Temp_HumiC.Temperature;
  EnvironmentSenseC.ReadHumidity -> Temp_HumiC.Humidity;
  EnvironmentSenseC.Light -> LightIntensityC;
  EnvironmentSenseC.Packet -> SerialAMSenderC;
  EnvironmentSenseC.UartSend -> SerialAMSenderC;
}