lingo-运输问题的数学模型

建模

变量

ai表示第i个工厂的加工量
bj表示第j个门市部的销量
cij表示运价，从第i个加工厂到第j个门市部运送一吨糖果的价格
决策变量:xij 从第i个加工厂到第j个门市部的糖果数量

一般形式

$$\begin{gathered} minz=\sum \sum cij\ast xij \\ s.t.\{\begin{array}{c}{\sum }_{j}xij=ai\\ {\sum }_{i}xij=bj\\ xij\ge 0\end{array} \end{gathered}$$

矩阵形式

$$\begin{gathered} A=[\begin{array}{ccc}7& 4& 9\end{array}] \\ B=[\begin{array}{cccc}3& 6& 5& 6\end{array}] \\ C=\left[\begin{array}{cccc}3& 11& 3& 10\\ 1& 8& 2& 8\\ 7& 4& 10& 5\end{array}\right] \\ X=\left[\begin{array}{cccc}{x}_{11}& x_{12}& x_{13}& x_{14}\\ x_{21}& x_{22}& x_{23}& x_{24}\\ x_{31}& x_{32}& x_{33}& x_{34}\end{array}\right] \end{gathered}$$

Lingo 建立模型

方法

定义集合
给常量赋值
目标函数的表达
约束条件的表达
模型求解

定义集合

! 建立加工厂集合及产量;
factory/1..3/:A；
! 建立门市部集合及产量；
shop/1..4/:B;
!建立联系集合及运价和运量,派生集合，双下标变量；
LINK(factory,shop):C,X;

给常量赋值

DATA:
	A = 7 4 9;
	B = 3 6 5 6;
	C = 
	3 11 3 10
	1 9 2 8
	7 4 10 5;
ENDDATA

目标函数的表达

$minz=\sum \sum cij\ast xij$

MIN = @SUM (LINK(i,j): C(i,j) * X(i,j));

约束条件的表达

1.产量约束
${\sum }_{j}xij=ai$

@for(factory(i): @sum(shop(j): x(i,j)) = A(i));

2.销量约束
${\sum }_{i}xij=bj$

@for(shop(j): @sum(factory(i): x(i,j)) = b(j));

3.自身约束
$xij\ge 0$
lingo 默认非负

完整代码

MODEL:
	SETS:
	factory/1..3/:A;
	shop/1..4/:B;
	LINK(factory,shop):C,X;
	ENDSETS
	
	DATA:
	A = 7 4 9;
	B = 3 6 5 6;
	C = 
	3 11 3 10
	1 9 2 8
	7 4 10 5;
	ENDDATA
	
	MIN = @SUM (LINK(i,j): C(i,j) * X(i,j));
	@for(factory(i): @sum(shop(j): x(i,j)) = A(i));
	@for(shop(j): @sum(factory(i): x(i,j)) = b(j));
END