洛谷 P1650 赛马

洛谷 P1650 赛马

---

题目

题目描述

我国历史上有个著名的故事： 那是在2300年以前。齐国的大将军田忌喜欢赛马。他经常和齐王赛马。他和齐王都有三匹马：常规马，上级马，超级马。一共赛三局，每局的胜者可以从负者这里取得200银币。每匹马只能用一次。齐王的马好，同等级的马，齐王的总是比田忌的要好一点。于是每次和齐王赛马，田忌总会输600银币。

田忌很沮丧，直到他遇到了著名的军师――孙膑。田忌采用了孙膑的计策之后，三场比赛下来，轻松而优雅地赢了齐王200银币。这实在是个很简单的计策。由于齐王总是先出最好的马，再出次好的，所以田忌用常规马对齐王的超级马，用自己的超级马对齐王的上级马，用自己的上级马对齐王的常规马，以两胜一负的战绩赢得200银币。实在很简单。

如果不止三匹马怎么办？这个问题很显然可以转化成一个二分图最佳匹配的问题。把田忌的马放左边，把齐王的马放右边。田忌的马A和齐王的B之间，如果田忌的马胜，则连一条权为200的边；如果平局，则连一条权为0的边；如果输，则连一条权为－200的边……如果你不会求最佳匹配，用最小费用最大流也可以啊。 然而，赛马问题是一种特殊的二分图最佳匹配的问题，上面的算法过于先进了，简直是杀鸡用牛刀。现在，就请你设计一个简单的算法解决这个问题。

输入输出格式

输入格式：
第一行一个整数n，表示他们各有几匹马（两人拥有的马的数目相同）。第二行n个整数，每个整数都代表田忌的某匹马的速度值(0 <= 速度值<= 100)。第三行n个整数，描述齐王的马的速度值。两马相遇，根据速度值的大小就可以知道哪匹马会胜出。如果速度值相同，则和局，谁也不拿钱。

【数据规模】

对于20%的数据，1<=N<=65；

对于40%的数据，1<=N<=250；

对于100%的数据，1<=N<=2000。

输出格式：
仅一行，一个整数，表示田忌最大能得到多少银币。

输入输出样例

输入样例#1：

3
92 83 71
95 87 74

输出样例#1：

200

---

题解

贪心（其实是可以DP的，但是DP代码写的比较长）

先排序，先比较两边最大且没参加过比赛的马的速度，再比较两边最小且没参加过比赛的马的速度，若这两种方法都不能赢，那么就用速度最小的马换对面速度最大的马

类似题目：BZOJ 1304

---

代码(Pascal)

var n,ans:longint;
    x,y:array[0..2005]of longint;
 procedure init;
  var i:longint;
   begin
     readln(n);
     for i:=1 to n do read(x[i]);
     for i:=1 to n do read(y[i]);
    end;
 procedure qsort(l,r:longint);
  var i,j,mid,t:longint;
   begin
     i:=l;j:=r;
     mid:=x[random(r-l+1)+l];
     repeat
       while x[i]<mid do inc(i);
       while x[j]>mid do dec(j);
       if i<=j then begin
                      t:=x[i];x[i]:=x[j];x[j]:=t;
                      inc(i);dec(j);
                     end;
      until i>j;
     if i<r then qsort(i,r);
     if l<j then qsort(l,j);
    end;
 procedure qsort1(l,r:longint);
  var i,j,mid,t:longint;
   begin
     i:=l;j:=r;
     mid:=y[random(r-l+1)+l];
     repeat
       while y[i]<mid do inc(i);
       while y[j]>mid do dec(j);
       if i<=j then begin
                      t:=y[i];y[i]:=y[j];y[j]:=t;
                      inc(i);dec(j);
                     end;
      until i>j;
     if i<r then qsort1(i,r);
     if l<j then qsort1(l,j);
    end;
 procedure main;
  var l1,l2,r1,r2:longint;
   begin
     qsort(1,n);
     qsort1(1,n);
     l1:=1;l2:=1;
     r1:=n;r2:=n;
     while (l1<=r1)and(l2<=r2) do
      begin
        if x[l1]>y[l2] then begin
                              inc(ans);
                              inc(l1);inc(l2);
                             end else
        if x[r1]>y[r2] then begin
                              inc(ans);
                              dec(r1);dec(r2);
                             end
                       else begin
                              if x[l1]<>y[r2] then dec(ans);
                              inc(l1);dec(r2);
                             end;
       end;
    end;
 procedure print;
  begin
    writeln(ans*200);
   end;
 begin
   init;
   main;
   print;
 end.