CMake中string的使用

最新推荐文章于 2024-04-12 14:24:04 发布
最新推荐文章于 2024-04-12 14:24:04 发布
阅读量4.5k 收藏 18
点赞数 4
分类专栏： CMake/Makefile 文章标签： CMake string
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/fengbingchun/article/details/127714819
版权

      CMake中的string命令用于字符串操作,其格式如下：

Search and Replace
  string(FIND <string> <substring> <out-var> [...])
  string(REPLACE <match-string> <replace-string> <out-var> <input>...)
  string(REGEX MATCH <match-regex> <out-var> <input>...)
  string(REGEX MATCHALL <match-regex> <out-var> <input>...)
  string(REGEX REPLACE <match-regex> <replace-expr> <out-var> <input>...)

Manipulation
  string(APPEND <string-var> [<input>...])
  string(PREPEND <string-var> [<input>...])
  string(CONCAT <out-var> [<input>...])
  string(JOIN <glue> <out-var> [<input>...])
  string(TOLOWER <string> <out-var>)
  string(TOUPPER <string> <out-var>)
  string(LENGTH <string> <out-var>)
  string(SUBSTRING <string> <begin> <length> <out-var>)
  string(STRIP <string> <out-var>)
  string(GENEX_STRIP <string> <out-var>)
  string(REPEAT <string> <count> <out-var>)

Comparison
  string(COMPARE <op> <string1> <string2> <out-var>)

Hashing
  string(<HASH> <out-var> <input>)

Generation
  string(ASCII <number>... <out-var>)
  string(HEX <string> <out-var>)
  string(CONFIGURE <string> <out-var> [...])
  string(MAKE_C_IDENTIFIER <string> <out-var>)
  string(RANDOM [<option>...] <out-var>)
  string(TIMESTAMP <out-var> [<format string>] [UTC])
  string(UUID <out-var> ...)

JSON
  string(JSON <out-var> [ERROR_VARIABLE <error-var>]
         {GET | TYPE | LENGTH | REMOVE}
         <json-string> <member|index> [<member|index> ...])
  string(JSON <out-var> [ERROR_VARIABLE <error-var>]
         MEMBER <json-string>
         [<member|index> ...] <index>)
  string(JSON <out-var> [ERROR_VARIABLE <error-var>]
         SET <json-string>
         <member|index> [<member|index> ...] <value>)
  string(JSON <out-var> [ERROR_VARIABLE <error-var>]
         EQUAL <json-string1> <json-string2>)

      1.Search and Replace：
      (1).FIND:在提供的<string>中查找给定的<substring>，若找到则返回其位置；如果使用了REVERSE标志，该命令将搜索<substring>在<string>中最后出现的位置；若未找到则返回-1。string(FIND)子命令将所有字符串视为纯ASCII字符。变量<out-var>中存储的索引也会以字节为单位计算，因此包含多字节字符的字符串(strings containing multi-byte characters)可能会导致意外结果(unexpected results)。

set(str beijing//beijing//beijing)

string(FIND ${str} "jing" var)
message("var: ${var}") # var: 3
string(FIND ${str} "jing" var REVERSE)
message("var: ${var}") # var: 21
string(FIND ${str} "\\" var)
message("var: ${var}") # var: -1

      (2).REPLACE:将<input>中所有出现的<match_string>替换为<replace_string>，并将结果存储在<out-var>中。若<match_string>在<input>中未出现，<out-var>的值将为<input>。

set(str https://blog.csdn.net/fengbingchun)
string(REPLACE "blog.csdn.net" "github.com" var ${str})
message("var: ${var}") # var: https://github.com/fengbingchun

string(REPLACE "xxxx" "yyyy" var ${str}) 
message("var: ${var}") # var: https://blog.csdn.net/fengbingchun

      (3).CMake中的正则表达式(Regular Expression):以下字符在正则表达式中具有特殊含义
      ^:匹配输入字符串的开始位置；
      $:匹配输入字符串结尾的位置；
      .:匹配任何单个字符；
      \<char>:匹配<char>指定的单个字符。使用它来匹配特殊的正则表达式字符。将下一个字符标记为特殊字符。转义非特殊字符(non-special character)是不必要但允许的,例如\a匹配a；
      []:匹配括号内的任何字符；
      [^]：匹配不在括号内的任何字符；
      -:在括号内，指定两边字符之间的包含范围；
      *:零次或多次匹配前面的字符；
      +：一次或多次匹配前面的字符；
      ?：零次或一次匹配前面的字符；
      |:匹配"|"两边的字符;
      ():保存匹配的子表达式；
      *、+和?具有比串联(concatenation)更高的优先级。|的优先级低于concatenation。这意味着正则表达式^ab+d$匹配abbd但不匹配ababd，正则表达式^(ab|cd)$匹配ab但不匹配abd。
      CMake语言转义序列(Escape Sequences)，例如\t、\r、\n和\\可用于构造文字制表符、回车符、换行符和反斜杠(literal tabs, carriage returns, newlines, and backslashes)以传入正则表达式。例如：
      带引号的参数"[ \t\r\n]"指定匹配任何单个空白字符的正则表达式；
      带引号的参数"[/\\]"指定匹配单个正斜杠/或反斜杠\的正则表达式；
      带引号的参数"[A-Za-z0-9_]"指定匹配C语言环境中任何单个"word"字符的正则表达式；
      带引号的参数"\\(\\a\\+b\\)"指定匹配确切字符串(a+b)的正则表达式。每个\\在带引号的参数中被解析为只是\，因此正则表达式本身实际上是\(\a\+\b\)。这也可以在括号参数中指定，而不必转义反斜杠，例如[[\(\a\+\b\)]]。
      REGEX MATCH：匹配一次<match-regex>并将匹配存储在<out-var>中。所有<input>参数在匹配之前连接(concatenated)。

set(str "123abc123abc")
string(REGEX MATCH "[a-z]" var ${str})
message("var: ${var}") # var: a
string(REGEX MATCH "[1-9]" var ${str})
message("var: ${var}") # var: 1
string(REGEX MATCH "[^1-9]" var ${str})
message("var: ${var}") # var: a

      REGEX MATCHALL:尽可能多地匹配<match-regex>并将匹配项作为列表(list)存储在<out-var>中。所有<input>参数在匹配之前连接(concatenated)。

set(str "123abc123abc")
string(REGEX MATCHALL "[a-z]" var ${str})
message("var: ${var}") # var: a;b;c;a;b;c
string(REGEX MATCHALL "[1-9]" var ${str})
message("var: ${var}") # var: 1;2;3;1;2;3
string(REGEX MATCHALL "[^1-9]" var ${str})
message("var: ${var}") # var: a;b;c;a;b;c

      REGEX REPLACE:尽可能多地匹配<match-regex>并将<replace-expr>替换为输出中的匹配项。所有<input>参数在匹配之前连接(concatenated)。

set(str "123abc123abc")
set(substr "@#")

string(REGEX REPLACE "[a-z]" ${substr} var ${str})
message("var: ${var}") # var: 123@#@#@#123@#@#@#
string(REGEX REPLACE "[1-9]" ${substr} var ${str})
message("var: ${var}") # var: @#@#@#abc@#@#@#abc
string(REGEX REPLACE "[^1-9]" ${substr} var ${str})
message("var: ${var}") # var: 123@#@#@#123@#@#@#
string(REGEX REPLACE "^a" ${substr} var ${str}) # 若没有找到可replace的,则var=str
message("var: ${var}") # var: 123abc123abc

      2.Manipulation：
      (1).APPEND:将所有<input>参数追加到<string-var>

set(str1 "csdn addr:")
string(APPEND var ${str1})

set(str2 "https://blog.csdn.net/fengbingchun")
string(APPEND var ${str2})
message("var: ${var}") # var: csdn addr:https://blog.csdn.net/fengbingchun

      (2).PREPEND:将所有<input>参数前置(prepend)到<string-var>

set(str1 "https://blog.csdn.net/fengbingchun")
string(PREPEND var ${str1})

set(str2 "csdn addr:")
string(PREPEND var ${str2})
message("var: ${var}") # var: csdn addr:https://blog.csdn.net/fengbingchun

      (3).CONCAT:将所有<input>参数连接在一起，并将结果存储在<out-var>中

set(str1 "csdn addr:")
set(str2 "https://blog.csdn.net/fengbingchun")
string(CONCAT var ${str1} ${str2})
message("var: ${var}") # var: csdn addr:https://blog.csdn.net/fengbingchun

      (4).JOIN:使用<glue>字符串将所有<input>参数连接在一起，并将结果存储在<out-var>中

set(str1 "csdn addr")
set(str2 "https://blog.csdn.net/fengbingchun")
string(JOIN ": " var ${str1} ${str2})
message("var: ${var}") # var: csdn addr: https://blog.csdn.net/fengbingchun

      (5).TOLOWER:将<string>转换为小写字符

set(str "ABC123dEF")
string(TOLOWER ${str} var)
message("var: ${var}") # var: abc123def

      (6).TOUPPER:将<string>转换为大写字符

set(str "AbC123dEf")
string(TOUPPER ${str} var)
message("var: ${var}") # var: ABC123DEF

      (7).LENGTH:将给定<string>的长度(以字节为单位)存储在<out-var>中。注意：这意味着如果<string>包含多字节字符，则存储在<out-var>中的结果将不是字符数

set(str "https://blog.csdn.net/fengbingchun")
string(LENGTH ${str} var)
message("var: ${var}") # var: 34

      (8).SUBSTRING:在<out-var>中存储给定<string>的子字符串。如果<length>为-1，则将返回从<begin>开始的字符串的其余部分。如果<string>比<length>短，则使用字符串的结尾。<begin>和<length>都以字节为单位，因此如果<string>包含多字节字符，则必须小心

set(str "https://blog.csdn.net/fengbingchun")

string(SUBSTRING ${str} 8 13 var)
message("var: ${var}") # var: blog.csdn.net

string(SUBSTRING ${str} 8 100 var)
message("var: ${var}") # var: blog.csdn.net/fengbingchun

string(SUBSTRING ${str} 8 -1 var)
message("var: ${var}") # var: blog.csdn.net/fengbingchun

      (9).STRIP:将除去前后空格(leading and trailing spaces removed)的<string>的子字符串存储在<out-var>中

set(str "  https://blog.csdn.net/fengbingchun  ")
string(STRIP ${str} var)
message("str: ${str}") # str:   https://blog.csdn.net/fengbingchun  
message("var: ${var}") # var: https://blog.csdn.net/fengbingchun

      (10).GENEX_STRIP:从输入<string>中去除"generator expressions"并将结果存储在<out-var>中

set(str "one;$<1:two;three>;four;$<TARGET_OBJECTS:some_target>")
string(GENEX_STRIP "${str}" var) # string(GENEX_STRIP "one;$<1:two;three>;four;$<TARGET_OBJECTS:some_target>" var)
message("var: ${var}") # var: one;four

      (11).REPEAT:输出字符串作为输入<string>重复<count>次

set(str "abcd1234")
string(REPEAT ${str} 3 var)
message("var: ${var}") # var: abcd1234abcd1234abcd1234

      3.Comparison：比较字符串并将true或false存储在<out-var>中，op有LESS、GREATER、EQUAL、NOTEQUAL、LESS_EQUAL、GREATER_EQUAL

set(str1 "abc")
set(str2 "acd")

string(COMPARE LESS ${str1} ${str2} var)
message("var: ${var}") # var: 1
string(COMPARE GREATER ${str1} ${str2} var)
message("var: ${var}") # var: 0

string(COMPARE EQUAL ${str1} ${str1} var)
message("var: ${var}") # var: 1
string(COMPARE NOTEQUAL ${str1} ${str1} var)
message("var: ${var}") # var: 0

string(COMPARE LESS_EQUAL ${str1} ${str1} var)
message("var: ${var}") # var: 1
string(COMPARE GREATER_EQUAL ${str1} ${str1} var)
message("var: ${var}") # var: 1

      4.Hashing：计算<input>字符串的加密哈希(cryptographic hash)。支持的<HASH>算法包括：MD5、SHA1、SHA224、SHA256、SHA384、SHA512、SHA3_224、SHA3_256、SHA3_384、SHA3_512

set(str "https://blog.csdn.net/fengbingchun")
string(MD5 var ${str})
message("var: ${var}") # var: 347626e4d6ac64d0d193e4f7c9a527b1
string(SHA1 var ${str})
message("var: ${var}") # var: d0e47459e1e8115c11f5640e2595c7d35dfa5d4f
string(SHA224 var ${str})
message("var: ${var}") # var: e31ec2e82107a7acee703ea0ef08ea98d68aabad41725e80faf5795e
string(SHA256 var ${str})
message("var: ${var}") # var: 0220d436e044b408464a2d59a06a1af98ced88b17b4dffe7bdfd22420a2703ef
string(SHA384 var ${str})
message("var: ${var}") # var: 510f2226e793a2ef50aff6a7da133489b0f588b67e090f7a131d7f6d098855e22a917867222d0eea53d225689751dda4
string(SHA512 var ${str})
message("var: ${var}") # var: e301205b475e6288b8844d147cf28083f1dc847ea78c332a93061ccc950625acab5e857b76dbf95b5990ee387d935e7b5206f78a05be403bac83b1c0110acbcc
string(SHA3_224 var ${str})
message("var: ${var}") # var: 62f51871f691fb594f70f5e353f98e310f98c0e7f1030ed49e01747e
string(SHA3_256 var ${str})
message("var: ${var}") # var: 442a3127fd33cf6b89427b819dfb69c64f7805214fd1ff4c77bd33e85deebd99
string(SHA3_384 var ${str})
message("var: ${var}") # var: af8c8e24e984eee9874336401d3140b971074dcf94be3b7955350a8845143c09d318773e6d34da7347295af52308eec6
string(SHA3_512 var ${str})
message("var: ${var}") # var: ef3c281c1745c06c113f3e8d92acdc006a1f665f7fbc48b58f6fb871cb31bdb3f28e81c7f6e268b75d5861cf160720072f475f94f75335d7492ca14e1f0963a7

      5.Generation：
      (1).ASCII:将所有数字转换为对应的ASCII字符

set(num 33)
string(ASCII ${num} var)
message("var: ${var}") # var: !

string(ASCII 33 34 var)
message("var: ${var}") # var: !"

string(ASCII 256 var) # CMake Error at test_string.cmake:159 (string):
                        #   string Character with code 256 does not exist.

      (2).HEX:将输入的<string>中的每个字节转换为十六进制表示，并将连接后的十六进制数字存储在<out-var>中。输出中的字母(a到f)是小写的

set(str "!#$<=>Zz")
string(HEX ${str} var)
message("var: ${var}") # var: 2123243c3d3e5a7a

      (3).CONFIGURE:像configure_file命令一样的规则转换<string>

set(csdn_addr "https://blog.csdn.net/fengbingchun")
string(CONFIGURE "#cmakedefine csdn_addr @csdn_addr@" var)
message("var: ${var}") # var: #define csdn_addr https://blog.csdn.net/fengbingchun

      (4).MAKE_C_IDENTIFIER:将<string>中的每个非字母数字字符(each non-alphanumeric character)转换为下划线并将结果存储在<out-var>中。如果<string>的第一个字符是数字，则下划线也将被添加到结果前

set(str "123^$abc*()ABC")
string(MAKE_C_IDENTIFIER ${str} var)
message("var: ${var}") # var: _123__abc___ABC

      (5).RANDOM:返回由<alphabet>中的字符组成的长度为<length>的随机字符串。默认长度为5个字符，默认字母为所有数字和大小写字母。如果给定一个整数<seed>，它的值将用于为随机数生成器提供种子(seed)

string(RANDOM [LENGTH <length>] [ALPHABET <alphabet>] [RANDOM_SEED <seed>] <output_variable>)
string(RANDOM LENGTH 20 ALPHABET abc123ABC RANDOM_SEED 5 var)
message("var: ${var}") # var: caCabac22CacCb1c1c1c

      (6).TIMESTAMP:将当前日期/或时间的字符串表示形式写入<out-var>。如果命令无法获取时间戳，<out-var>将设置为空字符串。
      可选的UTC标志请求当前日期/时间表示为协调世界时(UTC)而不是本地时间。
      可选的<format string>可能包含以下格式说明符：%%、%d、%H、%I、%j、%m、%b、%B、%M、%s、%S、%f、%U、%w、%a、%A、%y、%Y

string(TIMESTAMP var) # %Y-%m-%dT%H:%M:%S for local time
message("var: ${var}") # var: 2022-11-05T09:23:29
string(TIMESTAMP var UTC) # %Y-%m-%dT%H:%M:%SZ for UTC
message("var: ${var}") # var: 2022-11-05T01:23:29Z

string(TIMESTAMP var %B:%U)
message("var: ${var}") # var: November:44

      (7).UUID:基于<namespace>(其本身必须是有效的UUID)和<name>的组合值的哈希创建一个通用唯一标识符(GUID)。哈希算法可以是MD5或SHA1。UUID的格式为：xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxxxxxx，其中每个x代表一个小写十六进制字符。如果需要，可以使用可选的UPPER标志请求大写表示。

string(UUID <output_variable> NAMESPACE <namespace> NAME <name> TYPE <MD5|SHA1> [UPPER])
string(UUID var NAMESPACE 34795e00-5a50-11ed-9b6a-0242ac120002 NAME beijing TYPE SHA1 UPPER)
message("var: ${var}") # var: B4383795-34FD-5079-BFC8-38E44E159A5D

string(UUID var NAMESPACE 34795e00-5a50-11ed-9b6a-0242ac120002 NAME beijing TYPE MD5)
message("var: ${var}") # var: fe7b8cbc-9a61-333e-aaad-b7acb502e9ac

      6.JSON：查询JSON字符串。如果给出了可选的ERROR_VARIABLE参数，则会在<error-var>中报告错误;并且<out-var>将设置为<member|index>-[<member|index>...]-NOTFOUND，或者如果没有相关path,则仅设置为NOTFOUND。如果发生error但ERROR_VARIABLE选项不存在，则会触发fatal error。如果没有发生error，<error-var>将设置为NOTFOUND。
      GET：通过给定的<member|index>从<json-string>获取元素。array和object元素将作为JSON字符串返回。boolean元素将作为ON或OFF返回。null元素将作为空字符串返回。number和string类型将作为字符串返回。
      TYPE:通过给定的<member|index>从<json-string>获取元素的类型。<out-var>将设置为NULL, NUMBER, STRING, BOOLEAN, ARRAY或OBJECT。
      LENGTH:通过给定的<member|index>从<json-string>获取元素的长度。需要元素为array或object类型。
      REMOVE:通过给定的<member|index>从<json-string>中删除一个元素。没有移除元素的JSON字符串将存储在<out-var>中。
      MEMBER:通过给定的<member|index>从<json-string>中获取第<index>成员的名称。需要元素为object类型。
      SET:设置<json-string>中的元素，将<member|index>设置为<value>。<value>应该是有效的JSON。
      EQUAL:比较<json-string1>和<json-string2>给出的两个JSON objects是否相等。<json-string1>和<json-string2>的内容应该是有效的JSON。如果认为JSON objects相等，则<out-var>将设置为true，否则设置为false。

set(str 
        "{
            \"name1\": \"csdn\",
            \"url1\": \"https://blog.csdn.net/fengbingchun\",
            \"name2\": \"github\",
            \"url2\": \"https://github.com/fengbingchun\"
        }"
)

string(JSON var ERROR_VARIABLE error_var GET ${str} "url1") # GET
message("var: ${var}") # var: https://blog.csdn.net/fengbingchun

string(JSON var ERROR_VARIABLE error_var TYPE ${str} "name1") # TYPE
message("var: ${var}") # var: STRING

string(JSON var ERROR_VARIABLE error_var LENGTH ${str} "name1") # LENGTH
message("var: ${var}, err: ${error_var}") # var: name1-NOTFOUND, err: LENGTH needs to be called with an element of type ARRAY or OBJECT, got STRING

string(JSON var ERROR_VARIABLE error_var REMOVE ${str} "name1") # REMOVE
message("var: ${var}") # var: {
                        # "name2" : "github",
                        # "url1" : "https://blog.csdn.net/fengbingchun",
                        # "url2" : "https://github.com/fengbingchun"
                        # }

string(JSON var ERROR_VARIABLE error_var MEMBER ${str} "name1") # MEMBER
message("var: ${var}, err: ${error_var}") # var: name1-NOTFOUND, err: expected an array index, got: 'name1'

string(JSON var ERROR_VARIABLE error_var SET ${str} "name1" ${str}) # SET
message("var: ${var}") # var: {
                        # "name1" : 
                        # {
                        # "name1" : "csdn",
                        # "name2" : "github",
                        # "url1" : "https://blog.csdn.net/fengbingchun",
                        # "url2" : "https://github.com/fengbingchun"
                        # },
                        # "name2" : "github",
                        # "url1" : "https://blog.csdn.net/fengbingchun",
                        # "url2" : "https://github.com/fengbingchun"
                        # }

string(JSON var ERROR_VARIABLE error_var EQUAL ${str} ${str}) # EQUAL
message("var: ${var}") # var: ON
string(JSON var ERROR_VARIABLE error_var EQUAL ${str} "{}") # EQUAL
message("var: ${var}") # var: OFF

      执行上述测试代码需要3个文件：build.sh, CMakeLists.txt, test_string.cmake

      build.sh内容如下：

#! /bin/bash

# supported input parameters(cmake commands)
params=(function macro cmake_parse_arguments \
		find_library find_path find_file find_program find_package \
		cmake_policy cmake_minimum_required project include \
		string list set)

usage()
{
	echo "Error: $0 needs to have an input parameter"

	echo "supported input parameters:"
	for param in ${params[@]}; do
		echo "  $0 ${param}"
	done

	exit -1
}

if [ $# != 1 ]; then
	usage
fi

flag=0
for param in ${params[@]}; do
	if [ $1 == ${param} ]; then
		flag=1
		break
	fi
done

if [ ${flag} == 0 ]; then
	echo "Error: parameter \"$1\" is not supported"
	usage
	exit -1
fi

if [[ ! -d "build" ]]; then
	mkdir build
	cd build
else
	cd build
fi

echo "==== test $1 ===="
cmake -DTEST_CMAKE_FEATURE=$1 ..

      CMakeLists.txt内容如下：

cmake_minimum_required(VERSION 3.22)
project(cmake_feature_usage)

message("#### current cmake version: ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION}")
include(test_${TEST_CMAKE_FEATURE}.cmake)
message("==== test finish ====")

      test_string.cmake:为上面所有示例代码

      可能的执行结果如下图所示：

      GitHub： https://github.com/fengbingchun/Linux_Code_Test

fengbingchun
关注
  • 4
    点赞
  • 踩
  • 18
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
CMake使用手册
11-26
主要介绍CMake使用方法，对立面每个方法做了简要说明。
cmake之string命令解析
zhanghl的博客
12-26 9917
在中查找，返回值存放于，找到则返回在中的下标，找不到返回-1。默认为首次出现的匹配，如果使用了则为最后一次匹配。注：下标从0开始，以字节做为单位，因此遇到中文时下标表示字符编码第一字节的位置。 从所有中查找并使用替换，替换后的字符串存放于。多个输入时，先将所有输入连接后，再做查找替换。 从所有中查找匹配到的字符串，并存放于，查不到输出为空字符串。多个输入时先连接再做操作。只匹配第一次。 和类似，区别是会查找所有符合的匹配，并将他们连接起来输出。 根据正则表达式查找，并替换。找不到则输出为输入字符串。可以使用
【CMake】CMake从入门到实战系列（九）——CMake中的字符串处理指令和运算符
最新发布
【骠姚校尉】的博客
04-12 1228
一、字符串处理指令string 基本语法 参数含义 二、字符串运算符 字符串比较 字符串连接 字符串替换 字符串长度 字符串截取 字符串转换大小写 字符串正则表达式匹配和替换 字符串查找子字符串 字符串中查找正则表达式匹配的内容 字符串附加 三 、示例
cmake：string
OceanStar的博客
07-01 2694
字符串操作。 概要 Search and Replace string(FIND <string> <substring> <out-var> [...]) string(REPLACE <match-string> <replace-string> <out-var> <input>...) string(REGEX MATCH <match-regex> <out-var> <i
cmake字符串
m0_38036750的博客
07-08 667
cmake字符串操作
CMake String函数：如何巧妙地在cmake中操作字符串
探索C++编程的奥秘，分享深入的技术见解和实践，旨在激发读者创造力与解决问题的思维。
06-02 3311
CMake String函数：如何巧妙地在cmake中操作字符串
Android stduio使用cmake开发jni
11-20
本文将详细介绍如何使用Android Studio和CMake进行JNI开发。 首先，我们需要了解Android Studio中的CMake。CMake是一个跨平台的开源自动化构建系统，能够管理编译过程。在Android Studio中，CMake用于管理原生代码...
CMake从入门到实战系列（九）-CMake中的字符串处理指令和运算符
04-12
在CMake中，我们可以使用`set`命令来给变量赋值。例如： ```cmake set(MY_STRING "Hello, CMake!") ``` 引用变量时，直接使用变量名即可，如`${MY_STRING}`。 2. **字符串拼接** CMake提供了`CONCATENATE`...
cmake 学习笔记
01-20
最近接触到一些工程上的代码，都是用cmake来编译的，每次看着CMakeLists.txt 就各种懵逼，决定从0 开始学习 1 set set(var hello) message(${var}) 输出 hello 其实并不是单单输出hello，还有很多其他信息，会...
CMake导入so文件
07-12
当需要在Java代码中使用C或C++编写的库时，就需要使用JNI。而CMake是跨平台的构建工具，它使得在Android Studio中管理C/C++代码变得更加方便。本文将详细介绍如何使用CMake在Android项目中导入so（共享对象）文件，...
cmake 返回当前路径的上层路径 string(REGEX REPLACE...)
叶落随风
10-25 6613
返回当前路径的上层路径 先上实现代码 string(REGEX REPLACE "(.+)\\learn/basic.*" "\\1" PROJECT_INIT_PATH ${PROJECT_SOURCE_DIR}) 说明 CMakeLists.txt 所在路径，可由cmake的宏得到，即PROJECT_SOURCE_DIR，如下 /home/sxy/Personal/github/op...
正则表达式之Regex.Match()用法
weixin_30770495的博客
04-01 1060
//匹配字符串中的连续数字 string txt = "AAA12345678AAAA"; string m = Regex.Match(txt, @"\d+").Value; Console.WriteLine(m); 正则表达式中()是代表分组 例如：(\d{1})(\d{1}) 整个表达式是第一组，第一个括号是第二组，第二个括号是第三组。提取方式跟数组一样 获取...
使用Regex.Replace()进行字符串的替换
冰封的落叶的博客
01-15 7323
//将正则表达式匹配的不同部分，用同一字符串替换，并返回替换后的结果public static string Replace(string input, string pattern, string replacement);//将正则表达式匹配的不同部分，用MatchEvaluator委托返回值依次替换，并返回替换后的结果public static string Replace(string i
RegExp 正则表达式test和string的match方法
alxe46144的博客
12-03 268
var exp = new RegExp(pattern,modifier) //pattern为正则的条件或者是字符串； modifier为修饰符g :表示全局匹配；i：忽略大小写；m：忽略大小写；^：以什么开头；$：以什么结尾 var exp = new RegExp("h",g); var str = 'hello word'; exp.test(str) //返回的...
【CMake 语法】(4) CMake 命令、命令参数、转义序列
m0_57845572的博客
07-06 1800
1. 命令 CMake 源码文件基本上由命令组成。 2. 命令参数 命令调用中由三种类型的参数: 括号参数 带引号的参数 不带引号的参数 括号参数 括号参数内容，是左括号 [ 跟零个或多个 = 以右括号 ] 结束。 括号参数，不执行 转义序列 或 变量引用。 例如: message([=[ This is the first line in a bracket argument with bracket length 1. No \-escape sequences or ${variable} r
cmake字符串处理，获取文件名并去除文件扩展名
baidu_31137467的博客
04-04 2516
文章目录前言一、cmake字符串处理命令二、一个具体的例子总结 前言 cmake字符串处理，从路径中获取文件的名称，并且去除文件的扩展名 一、cmake字符串处理命令 string(REGEX MATCHALL (regular_expression) (output variable) (input) [(input)...]) string(REGEX REPLACE (regular_expression) (replace_expression) (output variable) (input
CMake - list
搬砖
11-01 860
命令格式 list (subcommand <list> [args...]) subcommand为具体的列表操作子命令，例如读取、查找、修改、排序等。<list>为待操作的列表变量，[args...]为对列表变量操作需要使用的参数表，不同的子命令对应的参数也不一致。 list命令即对列表的一系列操作，cmake中的列表变量是用分号;分隔的一组字符串，创建列表可以使用set命令（参考set命令），例如：set (var a b c d)创建了一个列表 "a;b;c;d"，而..
CMakeListx.txt 编辑语法学习
weixin_34306593的博客
07-12 212
2019独角兽企业重金招聘Python工程师标准>>> ...
cmake string
05-11
在CMake中，字符串可以使用多种方式表示和操作。下面是一些常见的用法： 1. 字符串变量声明和赋值： ```cmake set(str "hello cmake") ``` 2. 字符串连接： ```cmake set(str1 "hello") set(str2 "cmake") set(str3 "${str1} ${str2}") ``` 3. 字符串截取： ```cmake string(SUBSTRING "hello cmake" 0 5 sub_str) # 截取 "hello" ``` 4. 字符串查找： ```cmake string(FIND "hello cmake" "cmake" index) # 查找 "cmake" 出现的位置，返回值为 6 ``` 5. 字符串替换： ```cmake string(REPLACE "cmake" "world" new_str "hello cmake") # 将 "cmake" 替换成 "world"， new_str 的值为 "hello world" ``` 这些都是常见的字符串操作，CMake还提供了更多的字符串处理函数，可以根据需要使用。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值