多处最优服务次序问题（waits）

算法：贪心

分析：此题是最优服务次序的升级版，由一个服务点改成了多个，我们可以采用这样一种思路，即如果服务点没超的话就分配一个服务点，否则选一个等待时间最短的服务点服务。然后再按照一个服务点的做就可以了。

program waits;

const
 maxn=10000;
 maxm=1000;

var
 n,m:longint;
 a:array [0..maxn] of longint;
 s:array [0..maxm] of longint;
 window:array [0..maxm,0..maxm] of longint;

procedure init;
var
 i:longint;
begin
 readln(n,m);
 for i:=1 to n do read(a[i]);
end;

procedure qsort(l,r:longint);
var
 i,j,m,t:longint;
begin
 i:=l;
 j:=r;
 m:=a[(l+r) shr 1];
 repeat
  while a[i]<m do inc(i);
  while a[j]>m do dec(j);
  if i<=j then
   begin
    t:=a[i];
    a[i]:=a[j];
    a[j]:=t;
    inc(i);
    dec(j);
   end;
 until i>j;
 if i<r then qsort(i,r);
 if l<j then qsort(l,j);
end;

procedure main;
var
 i,j,ans,tot,min,minp:longint;
begin
 min:=maxlongint;
 tot:=0;
 ans:=0;
 for i:=1 to n do
  begin
   if tot<m then
    begin
     inc(tot);
     inc(window[tot,0]);
     window[tot,window[tot,0]]:=a[i];
     s[tot]:=a[i];
    end
   else
    begin
     min:=maxlongint;
     for j:=1 to tot do
      begin
       if s[j]<min then
        begin
         min:=s[j];
         minp:=j;
        end;
      end;
     inc(s[minp],a[i]);
     inc(window[minp,0]);
     window[minp,window[minp,0]]:=a[i];
    end;
  end;
 for i:=1 to tot do for j:=1 to window[i,0] do inc(ans,window[i,j]*(window[i,0]-j+1));
 writeln(ans/n:0:2);
end;

begin
 assign(input,'waits.in'); reset(input);
 assign(output,'waits.out'); rewrite(output);

 init;
 qsort(1,n);
 main;

 close(input); close(output);
end.