vb.net 图像锐化代码

  锐化的原理：

某点的颜色可以表示为：红、绿、蓝，即R/G/B。对于每个分量，

计算该点周围8个点的颜色均值与该点的差值，记为delta，设定锐化度为alpha。

则，该点的的颜色值为   原值+delta*alpha。

以下代码可以将原图像sourceimg进行锐化，并输出为Bitmap类型图像。

在该代码前应加引用如下：（如有多余的可自行调节）

Imports System.Drawing
Imports System.Drawing.Imaging
Imports System.Runtime.InteropServices
Imports Microsoft.VisualBasic
Imports System
Imports System.Windows.Forms

Public Function mysharp(ByVal sourceImg As Bitmap) As Bitmap '锐化效果,效果取0.4，取右、下、右下三个点计算
        '定义目标图片
        Dim destImg As New Bitmap(sourceImg.Width, sourceImg.Height)
        '定义源BitmapData,锁定区域是整个图片，只需要读取模式，采用24位RGB
        Dim sourceData As BitmapData = sourceImg.LockBits(New Rectangle(0, 0, sourceImg.Width, sourceImg.Height), ImageLockMode.ReadOnly, PixelFormat.Format24bppRgb)
        '定义目标BitmapData,锁定区域是整个图片，只需要写入模式，采用24位RGB
        Dim destData As BitmapData = destImg.LockBits(New Rectangle(0, 0, sourceImg.Width, sourceImg.Height), ImageLockMode.WriteOnly, PixelFormat.Format24bppRgb)
        '获得源BitmapData的起始指针位置
        Dim pSource As System.IntPtr = sourceData.Scan0
        '获得源BitmapData占用内存空间的总的字节数
        Dim allBytes As Integer = sourceData.Stride * sourceData.Height
        '定义数组，用来放置源BitmapData的数据
        Dim rgbvalues() As Byte
        ReDim rgbvalues(allBytes - 1)
        '把指针位置开始allBytes个字节数据拷贝到rgbvalues()数组中
        Marshal.Copy(pSource, rgbvalues, 0, allBytes)
        '数组中第一个字节的序号
        Dim pos As Integer = 0
        Dim R, G, B As Integer
        Dim delta As Single = 0, alpha As Single = 0.4 ''''''效果取0.4
        '先高度，后宽度
        For j As Integer = 0 To sourceData.Height - 2
            For i As Integer = 0 To sourceData.Width - 2
                '图片上(i,j)像素对应的蓝色分量值
                delta = rgbvalues(pos) - (CInt(rgbvalues(pos + 3)) + rgbvalues(pos + sourceData.Stride) + rgbvalues(pos + sourceData.Stride + 3)) / 3
                B = rgbvalues(pos) + delta * alpha
                '图片上(i,j)像素对应的绿色分量值
                delta = rgbvalues(pos + 1) - (CInt(rgbvalues(pos + 4)) + rgbvalues(pos + 1 + sourceData.Stride) + rgbvalues(pos + sourceData.Stride + 4)) / 3
                G = rgbvalues(pos + 1) + delta * alpha
                '图片上(i,j)像素对应的红色分量值
                delta = rgbvalues(pos + 2) - (CInt(rgbvalues(pos + 5)) + rgbvalues(pos + 2 + sourceData.Stride) + rgbvalues(pos + sourceData.Stride + 5)) / 3
                R = rgbvalues(pos + 2) + delta * alpha
                If B > 255 Then B = 255
                If B < 0 Then B = 0
                If G > 255 Then G = 255
                If G < 0 Then G = 0
                If R > 255 Then R = 255
                If R < 0 Then R = 0
                rgbvalues(pos) = B
                rgbvalues(pos + 1) = G
                rgbvalues(pos + 2) = R
                '终归是在一维数组里面取数据，向前推进3个字节
                pos = pos + 3
            Next
            '一行数据取完了，继续推进到下一行
            ' pos = pos + sourceData.Stride - sourceData.Width * 3
            pos = j * sourceData.Stride
        Next
        '获得目标BitmapData的起始指针位置
        Dim pDest As System.IntPtr = destData.Scan0
        '将数组的内容拷到pDest指针开始的内存
        Marshal.Copy(rgbvalues, 0, pDest, allBytes)
        '不要忘了解锁
        sourceImg.UnlockBits(sourceData)
        destImg.UnlockBits(destData)
        Return destImg
    End Function

以上代码只计算某点的右、下、右下3个点的颜色均值，同时，为加快速度，图像第一步先转为一维字节数组。（注意RGB顺序）