ADR指令的理解

    先看一下LDR指令。

LDR指令
LDR指令的格式为：
LDR{条件} 目的寄存器，<存储器地址>
LDR指令用于从存储器中将一个32位的字数据传送到目的寄存器中。该指令通常用于从存储器中读取32位的字数据到通用寄存器，然后对数据进行处理。当程序计数器PC作为目的寄存器时，指令从存储器中读取的字数据被当作目的地址，从而可以实现程序流程的跳转。该指令在程序设计中比较常用，且寻址方式灵活多样，请读者认真掌握。
指令示例：
LDR R0，[R1] ；将存储器地址为R1的字数据读入寄存器R0。
LDR R0，[R1，R2] ；将存储器地址为R1+R2的字数据读入寄存器R0。
LDR R0，[R1，＃8] ；将存储器地址为R1+8的字数据读入寄存器R0。
LDR R0，[R1，R2] ！ ；将存储器地址为R1+R2的字数据读入寄存器R0，并将新地址R1＋R2写入R1。
LDR R0，[R1，＃8] ！ ；将存储器地址为R1+8的字数据读入寄存器R0，并将新地址R1＋8写入R1。
LDR R0，[R1]，R2 ；将存储器地址为R1的字数据读入寄存器R0，并将新地址R1＋R2写入R1。
LDR R0，[R1，R2，LSL＃2]！ ；将存储器地址为R1＋R2×4的字数据读入寄存器R0，并将新地址R1＋R2×4写入R1。
LDR R0，[R1]，R2，LSL＃2 ；将存储器地址为R1的字数据读入寄存器R0，并将新地址R1＋R2×4写入R1。

ADR（小范围的地址读取伪指令）：该指令是将基于PC的地址值或基于寄存器的地址值读取到寄存器中，它是基于PC值进行地址运算的。

LDR指令和ADR指令简要对比一下：

		  LDR reg, ={lab}或={num}是用于加载标号地址和立即数的伪指令，
		不加"="号时，表示内存寻址。
		  ADR是将基于PC相对偏移的地址值或基于寄存器相对地址值读取的
		伪指令

     其实这两个都是伪指令：adr是小范围的地址读取伪指令，ldr是大范围的读取地址伪指令。可实际上adr是将基于PC相对偏移的地址值或基于寄存器相对地址值读取的为指令，而ldr用于加载32为立即数或一个地址到指定的寄存器中。到这儿就会看到其中的区别了。如果在程序中想加载某个函数或者某个在联接时候指定的地址时请使用adr，例如在lds中需要重新定位的地址。当加载32为的立即数或外部地址时请用ldr。

    

  一个网上的例子：

AREA test,CODE,READONLY
        ENTRY

START     
        ldr r0,_start
        adr r0,_start
        ldr r0,=_start
        nop

        
_start
        nop
        END

这段代码并无实际意义，只是为了方便说明。我们反汇编一下看看：

START
    $a
    test
        0x00000000:    e59f0008    ....    LDR      r0,_start     ; [0x10] = 0xe1a00000
        0x00000004:    e28f0004    ....    ADR      r0,{pc}+0xc ; 0x10
        0x00000008:    e59f0004    ....    LDR      r0,[pc,#4]    ; [_start = 0x14] = 0
        0x0000000c:    e1a00000    ....    MOV      r0,r0
    _start
        0x00000010:    e1a00000    ....    MOV      r0,r0
    $d
        0x00000014:    00000000    ....    DCD    0 ; _start

/***********************************

AXD仿真 确定RO段地址为：0x50200000

反编译

********************************/

ldr           r0, _start

从内存地址 _start 的地方把值读入。执行这个后，r0 = 0xe1a00000

adr         r0, _start

取得 _start 的地址到 r0，但是请看反编译的结果，它是与位置无关的，其实取得的是相对的位置。例如这段代码在 0x00000000 运行，那么 adr r0, _start 得到 r0 = 0x00000010；

ldr          r0, =_start

这个取得标号 _start 的绝对地址。这个绝对地址是在 link 的时候确定的。看上去这只是一个指令，但是它要占用 2 个 32bit 的空间，一条是指令，另一条是 _start 的数据（因为在编译的时候不能确定 _start 的值，而且也不能用 mov 指令来给 r0 赋一个 32bit 的常量，所以需要多出一个空间存放 _start 的真正数据，在这里就是 0x0000000c）。

因此可以看出，这个是绝对的寻址，不管这段代码在什么地方运行，它的结果都是 r0 = 0x0000000c。

再看一段代码：

        ldr     r0, _start
        adr     r0, _start
        ldr     r0, =_start
_start:
        b  _start

下面是反汇编的结果：

START
    $a
    $v0
    test
        0x00000000:    e59f0004    ....    LDR      r0,_start     ; [0xc] = 0xeafffffe
        0x00000004:    e28f0000    ....    ADR      r0,{pc}+8 ; 0xc
        0x00000008:    e59f0000    ....    LDR      r0,[pc,#0]    ; [_start = 0x10] = 0
    _start
        0x0000000c:    eafffffe    ....    B        {pc}  ; 0xc
    $d
        0x00000010:    00000000    ....    DCD    0 ; _start

设置RO为0X50200000  AXD仿真反编译为：

1．ldr     r0, _start
    这是一条指令，从内存地址 _start 的位置把值读入。
在这里_start是一个标号（是一个相对程序的表达式），汇编程序计算相对于 PC 的偏移量，并生成相对于 PC的前索引的指令：ldr r0, [0xc]。执行指令后，r0 = 0xeafffffe。

2．adr     r0, _start
    这是一条伪指令，总是会被汇编程序汇编为一个指令。汇编程序尝试产生单个 ADD 或 SUB 指令来装载该地址。如果不能在一个指令中构造该地址，则生成一个错误，并且汇编失败。
    在这里是取得标号_start 的地址到 r0，因为地址是相对程序的，因此ADR产生依赖于位置的代码，在此例中被汇编成：add r0, pc, #0。因此该代码可以在和标号相对位置不变的情况下移动；执行后r0=0x5020000c
    假如这段代码在 0x50200000 运行，那么 adr r0, _start 得到 r0 = 0x5020000c；如果在地址 0 运行，就是 0x0000000c 了。
    通过这一点可以判断程序在什么地方运行。U-boot中那段relocate代码就是通过adr实现当前程序是在RAM中还是flash中，下面进行简要分析。

3．ldr     r0, =_start
    这是一条伪指令，是一个相对程序的或外部的表达式。汇编程序将相对程序的标号表达式 label-expr 的值放在一个文字池中，并生成一个相对程序的 LDR 指令来从文字池中装载该值，在此例中生成的指令为：ldr r0, [pc, #0]，对应文字池中的地址以及值为：0x50200010: 5020000c。如果 label-expr 是一个外部表达式，或者未包含于当前段内，则汇编程序在目标文件中放置一个链接程序重定位命令。链接程序在链接时生成地址。
    因此取得的是标号 _start 的绝对地址，这个绝对地址（运行地址）是在连接的时候确定的。它要占用 2 个 32bit 的空间，一条是指令，另一条是文字池中存放_start 的绝对地址。因此可以看出，不管这段代码将来在什么地方运行，它的结果都是 r0 = 0x5020000c。由于ldr r0, =_start取得的是_start的绝对地址，这句代码可以在_start标号的绝对位置不变的情况下移动；如果使用寄存器pc在程序中可以实现绝对转移。