ORACLE导出CSV格式的数据

虽然使用一些可视化工具如navicate,plsql也可以导出CSV文件，但是对于一些场景简单的导出并不适用。如：想把表中的数据按某个字段分多个文件导出，以下为实现过程：

新建一个导出工具SP，传入查询SQL、导出目录、文件名称即可导出。

CREATE OR REPLACE PROCEDURE SQL_TO_CSV
(
 P_QUERY IN VARCHAR2, -- PLSQL文
 P_DIR IN VARCHAR2, -- 导出的文件放置目录
 P_FILENAME IN VARCHAR2 -- CSV名
 )
 IS
  L_OUTPUT UTL_FILE.FILE_TYPE;
  L_THECURSOR INTEGER DEFAULT DBMS_SQL.OPEN_CURSOR;
  L_COLUMNVALUE VARCHAR2(4000);
  L_STATUS INTEGER;
  L_COLCNT NUMBER := 0;
  L_SEPARATOR VARCHAR2(1);
  L_DESCTBL DBMS_SQL.DESC_TAB;
  P_MAX_LINESIZE NUMBER := 32000;
BEGIN
  --OPEN FILE
  L_OUTPUT := UTL_FILE.FOPEN(P_DIR, P_FILENAME, 'W', P_MAX_LINESIZE);
  --DEFINE DATE FORMAT
  EXECUTE IMMEDIATE 'ALTER SESSION SET NLS_DATE_FORMAT=''YYYY-MM-DD HH24:MI:SS''';
  --OPEN CURSOR
  DBMS_SQL.PARSE(L_THECURSOR, P_QUERY, DBMS_SQL.NATIVE);
  DBMS_SQL.DESCRIBE_COLUMNS(L_THECURSOR, L_COLCNT, L_DESCTBL);
  --DUMP TABLE COLUMN NAME
  FOR I IN 1 .. L_COLCNT LOOP
    UTL_FILE.PUT(L_OUTPUT,L_SEPARATOR || '"' || L_DESCTBL(I).COL_NAME || '"'); --输出表字段
    DBMS_SQL.DEFINE_COLUMN(L_THECURSOR, I, L_COLUMNVALUE, 4000);
    L_SEPARATOR := ',';
  END LOOP;
  UTL_FILE.NEW_LINE(L_OUTPUT); --输出表字段
  --EXECUTE THE QUERY STATEMENT
  L_STATUS := DBMS_SQL.EXECUTE(L_THECURSOR);

  --DUMP TABLE COLUMN VALUE
  WHILE (DBMS_SQL.FETCH_ROWS(L_THECURSOR) > 0) LOOP
    L_SEPARATOR := '';
    FOR I IN 1 .. L_COLCNT LOOP
      DBMS_SQL.COLUMN_VALUE(L_THECURSOR, I, L_COLUMNVALUE);
      UTL_FILE.PUT(L_OUTPUT,
                  L_SEPARATOR || '"' ||
                  TRIM(BOTH ' ' FROM REPLACE(L_COLUMNVALUE, '"', '""')) || '"');
      L_SEPARATOR := ',';
    END LOOP;
    UTL_FILE.NEW_LINE(L_OUTPUT);
  END LOOP;

  DBMS_SQL.CLOSE_CURSOR(L_THECURSOR);

  UTL_FILE.FCLOSE(L_OUTPUT);
EXCEPTION
  WHEN OTHERS THEN
    RAISE;
END;

根据需要，准备导出逻辑和导出数据

CREATE OR REPLACE 
PROCEDURE  MY_EXPORT AS

V_FILE_NAME VARCHAR2(300) := '';
BEGIN
--获取需要分类的字段
FOR A  IN (
  SELECT ID ,NAME FROM A
)
LOOP 
    --文件名
    V_FILE_NAME := A.ID|| '_'|| A.NAME||'.csv';
    EXECUTE IMMEDIATE 'TRUNCATE TABLE TEMP';
    commit;
    --TEMP为临时表，存放查询的数据
    INSERT INTO  TEMP 
	SELECT * FROM B  WHERE ID  =A.ID;
    commit;
    --调用生成文件的SP,OUT_PATH为文件存放地址，ORACLE安装机器目录下，
    --create or replace directory OUT_PATH as'/home/oracle/backup';
   SQL_TO_CSV('SELECT * FROM A','OUT_PATH',V_FILE_NAME);
END LOOP;

END;